rgwat3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    rgwat3         ../engine/source/interfaces/int09/rgwat3.F
!||--- called by ------------------------------------------------------
!||    rgwath         ../engine/source/interfaces/int09/rgwath.F
!||--- calls      -----------------------------------------------------
!||    initbuf        ../engine/share/resol/initbuf.F
!||    spmd_extag     ../engine/source/mpi/fluid/spmd_cfd.F
!||--- uses       -----------------------------------------------------
!||    elbufdef_mod   ../common_source/modules/mat_elem/elbufdef_mod.F90
!||    initbuf_mod    ../engine/share/resol/initbuf.F
!||====================================================================
      SUBROUTINE rgwat3(
     1               X        ,NELW ,NE      ,IXS    ,
     4               ELBUF_TAB,IPARG,PM      ,NTAG   ,TEMP   ,
     5               TSTIF    ,E    ,IAD_ELEM,FR_ELEM        )
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE initbuf_mod
      USE elbufdef_mod            
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com08_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NE
      INTEGER IPARG(NPARG,*), NELW(*) ,IXS(NIXS,*),
     .  NTAG(*), IAD_ELEM(2,*), FR_ELEM(*)
      my_real
     .  pm(npropm,*), x(3,*),e(*),
     .  temp,tstif
      TYPE(elbuf_struct_), TARGET, DIMENSION(NGROUP) :: ELBUF_TAB
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, II, N1, N2, N3, N4, IE, NG, MAT, IFA, LENR,
     .        IFACE(4,6)
      my_real
     .  x1, x2, x3, x4, y1, y2, y3, y4, z1, z2, z3, z4,
     .  nx, ny, nz, dx, dy, dz, dd, grad, phi, tempe, vol,
     .  tstife, coef,ee
      INTEGER :: LLT ,NFT ,MTN ,IAD ,ITY ,NPT ,JALE ,ISMSTR ,JEUL ,JTUR ,JTHE ,JLAG ,JMULT ,JHBE
      INTEGER :: JIVF, NVAUX, JPOR, JCVT, JCLOSE, JPLASOL, IREP, IINT, IGTYP
      INTEGER :: ISORTH, ISORTHG, ISRAT, ISROT, ICSEN, IFAILURE, JSMS
 
      TYPE(g_bufel_)  ,POINTER :: GBUF     
c---
      DATA iface/ 2, 3, 4, 5,
     .            5, 4, 8, 9,
     .            6, 9, 8, 7,
     .            3, 2, 6, 7,
     .            4, 3, 7, 8,
     .            2, 5, 9, 6/
       i = 0
C----------------------
C     DECOMPTE DES ELEMENTS PAR NOEUD
C     POUR ENERGIE DE FROTTEMENT
C----------------------
      DO 100 ie=1,ne
        ii  = nelw(ie)/10
        ifa = nelw(ie) - 10*ii
        n1  = ixs(iface(1,ifa),ii)
        n2  = ixs(iface(2,ifa),ii)
        n3  = ixs(iface(3,ifa),ii)
        n4  = ixs(iface(4,ifa),ii)
        IF(ntag(n1)>0) ntag(n1) = ntag(n1) + 1
        IF(ntag(n2)>0) ntag(n2) = ntag(n2) + 1
        IF(ntag(n3)>0) ntag(n3) = ntag(n3) + 1
        IF(ntag(n4)>0) ntag(n4) = ntag(n4) + 1
 100  CONTINUE
C
C Comm SPMD NTAG : cumul aux points frontiere + prise en compte tag initial
C
      IF(nspmd>1)THEN
        lenr = iad_elem(1,nspmd+1)-iad_elem(1,1)
        CALL spmd_extag(ntag,iad_elem,fr_elem,lenr)
      END IF
C----------------------
C     PONT THERMIQUE
C----------------------
      DO 600 ie=1,ne
        ii  = nelw(ie)/10
        ifa = nelw(ie) - 10*ii
        n1  = ixs(iface(1,ifa),ii)
        n2  = ixs(iface(2,ifa),ii)
        n3  = ixs(iface(3,ifa),ii)
        n4  = ixs(iface(4,ifa),ii)
        IF(ntag(n1)+ntag(n2)+ntag(n3)+ntag(n4)>0)THEN
C---------------------------------
C         RECHERCHE DE L'ELEMENT DANS LE BUFFER
C---------------------------------
          DO 200 ng=ii/nvsiz,ngroup
            CALL initbuf(iparg    ,ng      ,                   
     2            mtn     ,llt     ,nft     ,iad     ,ity     , 
     3            npt     ,jale    ,ismstr  ,jeul    ,jtur    , 
     4            jthe    ,jlag    ,jmult   ,jhbe    ,jivf    , 
     5            nvaux   ,jpor    ,jcvt    ,jclose  ,jplasol , 
     6            irep    ,iint    ,igtyp   ,israt   ,isrot   , 
     7            icsen   ,isorth  ,isorthg ,ifailure,jsms    )
            IF(ity/=1)          GO TO 200
            IF(ii>nft+llt)     GO TO 200
            IF(iparg(8,ng)==1)  GO TO 600
            IF(jthe/=1)         GO TO 600
            i = ii - nft
            GOTO 250
  200     CONTINUE
  250     CONTINUE
c          
          gbuf => elbuf_tab(ng)%GBUF
c
          vol  = gbuf%VOL(i)
C
          ee  = zero
          phi = zero
C----------------------
C     ENERGIE DE FROTTEMENT
C----------------------
          IF(ntag(n1)>1) ee = ee + e(n1) / (ntag(n1)-1)
          IF(ntag(n2)>1) ee = ee + e(n2) / (ntag(n2)-1)
          IF(ntag(n3)>1) ee = ee + e(n3) / (ntag(n3)-1)
          IF(ntag(n4)>1) ee = ee + e(n4) / (ntag(n4)-1)
C----------------------
C     CONDUCTION
C----------------------
C
            x1=x(1,n1)
            y1=x(2,n1)
            z1=x(3,n1)
C
            x2=x(1,n2)
            y2=x(2,n2)
            z2=x(3,n2)
C
            x3=x(1,n3)
            y3=x(2,n3)
            z3=x(3,n3)
C
            x4=x(1,n4)
            y4=x(2,n4)
            z4=x(3,n4)
C------------------------------------------
C         CALCUL DE LA SURFACE VECTORIELLE (*2.)
C------------------------------------------
            nx=(y3-y1)*(z2-z4) - (z3-z1)*(y2-y4)
            ny=(z3-z1)*(x2-x4) - (x3-x1)*(z2-z4)
            nz=(x3-x1)*(y2-y4) - (y3-y1)*(x2-x4)
C--------+---------+---------+---------+---------+---------+---------+--
C         CALCUL DE LA DISTANCE ENTRE CENTRE ET SURFACE ( * 8. )
C-------------------------------------------------------------
            dx = two*(x1 + x2 + x3 + x4)
     .          -x(1,ixs(2,ii))-x(1,ixs(3,ii))
     .          -x(1,ixs(4,ii))-x(1,ixs(5,ii))
     .          -x(1,ixs(6,ii))-x(1,ixs(7,ii))
     .          -x(1,ixs(8,ii))-x(1,ixs(9,ii))
C
            dy = two*(y1 + y2 + y3 + y4)
     .          -x(2,ixs(2,ii))-x(2,ixs(3,ii))
     .          -x(2,ixs(4,ii))-x(2,ixs(5,ii))
     .          -x(2,ixs(6,ii))-x(2,ixs(7,ii))
     .          -x(2,ixs(8,ii))-x(2,ixs(9,ii))
C
            dz = two*(z1 + z2 + z3 + z4)
     .          -x(3,ixs(2,ii))-x(3,ixs(3,ii))
     .          -x(3,ixs(4,ii))-x(3,ixs(5,ii))
     .          -x(3,ixs(6,ii))-x(3,ixs(7,ii))
     .          -x(3,ixs(8,ii))-x(3,ixs(9,ii))
C
            dd=dx**2+dy**2+dz**2
C---------------------------------
C         CALCUL DU GRADIENT * SURFACE
C---------------------------------
            grad = four*(dx*nx+dy*ny+dz*nz) / max(em15,dd)
C---------------------------------
C         CALCUL DU FLUX
C---------------------------------
            tempe=gbuf%TEMP(i)
            mat  =ixs(1,ie)
            IF(tempe<=pm(80,mat))THEN
             coef=pm(75,mat)+pm(76,mat)*tempe
            ELSE
             coef=pm(77,mat)+pm(78,mat)*tempe
            ENDIF
            tstife = coef * grad
C
            phi = tstife*tstif*(temp-tempe)
     2           / max(em20,(tstife+tstif))
            phi = phi * dt1 *
     +         ( min(ntag(n1),1) + min(ntag(n2),1)
     +         + min(ntag(n3),1) + min(ntag(n4),1) )
     +         / four   
C---------------------------------
C         ENERGIE / VOLUME
C---------------------------------
          phi = (phi + ee) / max(vol,em20)
          gbuf%EINT(i) = gbuf%EINT(i) + phi
        ENDIF
C
 600  CONTINUE
C-----------
      RETURN
      END