rotbmr.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    rotbmr       ../engine/source/tools/skew/rotbmr.F
!||--- called by ------------------------------------------------------
!||    imp_dycrb    ../engine/source/implicit/imp_dyna.f
!||    lag_gjnt     ../engine/source/tools/lagmul/lag_gjnt.F
!||    movfra2      ../engine/source/tools/skew/movfram.F
!||    movfra_imp   ../engine/source/tools/skew/movfram.F
!||    rgbodfp      ../engine/source/constraints/general/rbody/rgbodfp.F
!||    rmatpon      ../engine/source/materials/mat/mat013/rmatpon.F
!||    srfvit       ../engine/source/constraints/general/rbody/srfvit.F
!||====================================================================
      SUBROUTINE rotbmr (VR,RBY,DT)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
C     REAL
      my_real
     .   dt
C     REAL
      my_real
     .   vr(3), rby(9)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
C     REAL
      my_real
     .   rx, ry, rz, rx2, ry2, rz2, r2, r, c, cm1, s, sz, cz, e11,
     .   e22, e12, e21, e13, e23, bl11, bl21, bl31, bl12, bl22, bl32,
     .   bn
C-----------------------------------------------
       rx = dt*vr(1)
       ry = dt*vr(2)
       rz = dt*vr(3)
C
       rx2 = rx*rx
       ry2 = ry*ry
       rz2 = rz*rz
C
       r2 = max(em10,rx2+ry2+rz2)
       r  = sqrt(r2)
C
       c = cos(r)
       cm1 = (1-c)
       c = c*r2
       s = sin(r)*r
       sz = rz*s
       cz = rz*cm1
C
       e11 = rx2*cm1 + c
       e22 = ry2*cm1 + c
       e12 = rx*ry*cm1
       e21 = e12 - sz
       e12 = e12 + sz
       e13 = rx*cz - ry*s
       e23 = ry*cz + rx*s
C
       bl11 = rby(1)*e11 + rby(4)*e12 + rby(7)*e13
       bl21 = rby(2)*e11 + rby(5)*e12 + rby(8)*e13
       bl31 = rby(3)*e11 + rby(6)*e12 + rby(9)*e13
C
       bl12 = rby(1)*e21 + rby(4)*e22 + rby(7)*e23
       bl22 = rby(2)*e21 + rby(5)*e22 + rby(8)*e23
       bl32 = rby(3)*e21 + rby(6)*e22 + rby(9)*e23
C
       bn = sqrt(bl11*bl11+bl21*bl21+bl31*bl31)
       bl11=bl11/bn
       bl21=bl21/bn
       bl31=bl31/bn
       bn = sqrt(bl12*bl12+bl22*bl22+bl32*bl32)
       bl12=bl12/bn
       bl22=bl22/bn
       bl32=bl32/bn
C
       rby(1) = bl11
       rby(2) = bl21
       rby(3) = bl31
C
       rby(4) = bl12
       rby(5) = bl22
       rby(6) = bl32
C
       rby(7) = bl21*bl32 - bl31*bl22
       rby(8) = bl31*bl12 - bl11*bl32
       rby(9) = bl11*bl22 - bl21*bl12
C
C---------------------------
      RETURN
      END