s10fint3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    s10fint3   ../engine/source/elements/solid/solide10/s10fint3.F
!||--- called by ------------------------------------------------------
!||    s10forc3   ../engine/source/elements/solid/solide10/s10forc3.F
!||====================================================================
      SUBROUTINE s10fint3(
     1   SIG,     PX,      PY,      PZ,
     2   FX,      FY,      FZ,      VOL,
     3   QVIS,    STI,     STIG,    EINT,
     4   RHO,     Q,       EPLAS,   EPSD,
     5   EPSDG,   SIGG,    EINTG,   RHOG,
     6   QG,      EPLASG,  WIP,     G_PLA,
     7   NEL,     CONDE,   CONDEG,  G_EPSD,
     8   ISRAT,   SVIS ,   NODADT_THERM)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: ISRAT
      INTEGER, INTENT(IN) :: G_PLA,NEL,G_EPSD
      INTEGER, INTENT(IN) :: NODADT_THERM
C     REAL
      my_real
     .  PX(MVSIZ,10),PY(MVSIZ,10),PZ(MVSIZ,10),
     .  FX(MVSIZ,10), FY(MVSIZ,10), FZ(MVSIZ,10),
     .  SIG(NEL,6),VOL(*),QVIS(*),EINT(*),RHO(*),Q(*),EPLASG(*),EPLAS(*),
     .  sigg(nel,6),eintg(*),rhog(*),qg(*),wip,sti(*),stig(*),epsd(*),
     .  epsdg(*),conde(*),condeg(*)
      my_real, DIMENSION(MVSIZ,6), INTENT(INOUT) :: svis
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "scr18_c.inc"
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,N
C     REAL
      my_real
     .   S1(MVSIZ), S2(MVSIZ), S3(MVSIZ),
     .   S4(MVSIZ), S5(MVSIZ), S6(MVSIZ),
     .   FINT, QVIS_LOC, VOL_LOC
C-----------------------------------------------
      DO I=1,nel
       qvis_loc = qvis(i)
       vol_loc = vol(i)
       sigg(i,1) = sigg(i,1) + wip * sig(i,1)
       sigg(i,2) = sigg(i,2) + wip * sig(i,2)
       sigg(i,3) = sigg(i,3) + wip * sig(i,3)
       sigg(i,4) = sigg(i,4) + wip * sig(i,4)
       sigg(i,5) = sigg(i,5) + wip * sig(i,5)
       sigg(i,6) = sigg(i,6) + wip * sig(i,6)
       rhog(i)   = rhog(i)   + wip * rho(i)
       eintg(i)  = eintg(i)  + wip * eint(i)
       qg(i)     = qg(i)     + wip * q(i)
       stig(i)=stig(i)+sti(i)
       s1(i)=(sig(i,1)+svis(i,1)-qvis_loc)*vol_loc
       s2(i)=(sig(i,2)+svis(i,2)-qvis_loc)*vol_loc
       s3(i)=(sig(i,3)+svis(i,3)-qvis_loc)*vol_loc
       s4(i)=(sig(i,4)+svis(i,4))*vol_loc
       s5(i)=(sig(i,5)+svis(i,5))*vol_loc
       s6(i)=(sig(i,6)+svis(i,6))*vol_loc
      ENDDO
C
      IF(nodadt_therm == 1) THEN
        DO i=1,nel
          condeg(i)= condeg(i)+ conde(i)
        ENDDO
      ENDIF
c
      IF ((israt > 0).OR.(g_epsd > 0)) THEN                                                    
        DO i=1,nel
         epsdg(i) = epsdg(i) + wip * epsd(i)
        ENDDO
      ENDIF
      IF (g_pla > 0) THEN                                                    
        DO i=1,nel                                                          
          eplasg(i)  = eplasg(i)  + wip * eplas(i)                              
        ENDDO                                                                 
      ENDIF                                                                  
C
      DO n=1,10
        DO i=1,nel
          fx(i,n)=fx(i,n)-(s1(i)*px(i,n)+s4(i)*py(i,n)+s6(i)*pz(i,n))
          fy(i,n)=fy(i,n)-(s2(i)*py(i,n)+s5(i)*pz(i,n)+s4(i)*px(i,n))
          fz(i,n)=fz(i,n)-(s3(i)*pz(i,n)+s6(i)*px(i,n)+s5(i)*py(i,n))
        ENDDO
      ENDDO
C-----------
      RETURN
      END