s10therm.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    s10therm   ../engine/source/elements/solid/solide10/s10therm.F
!||--- called by ------------------------------------------------------
!||    s10forc3   ../engine/source/elements/solid/solide10/s10forc3.f
!||====================================================================
      SUBROUTINE s10therm(
     1   PM,      IMAT,     NC,      VOL,
     2   PX,      PY,      PZ,      NI,
     3   DT1,     TEMPNC,  TEL,     HEAT,
     4   FPHI,    OFFG,    OFF,     NEL ,
     5   THEACCFACT)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      INTEGER, INTENT(IN) :: IMAT
      INTEGER NC(MVSIZ,10)
      my_real, INTENT(IN) :: THEACCFACT
      my_real
     .    vol(*), px(mvsiz,*), py(mvsiz,*), pz(mvsiz,*),
     .    ni(mvsiz,10), tempnc(*), fphi(mvsiz,10), pm(npropm,*), heat(*),
     .    dt1, tel(*), off(*), offg(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,N
      my_real
     .  CA, CB, KC, PHIX(MVSIZ), PHIY(MVSIZ), PHIZ(MVSIZ)
C-----------------------------------------------
      CA = pm(75,imat)
      cb = pm(76,imat)
!
      phix(1:mvsiz) = zero
      phiy(1:mvsiz) = zero
      phiz(1:mvsiz) = zero
C 
C - flux
C
      DO n=1,10
       DO i=1,nel
          IF(off(i)==zero.OR.offg(i)<=zero) cycle
          phix(i) = phix(i) +  tempnc(nc(i,n))*px(i,n)              
          phiy(i) = phiy(i) +  tempnc(nc(i,n))*py(i,n)
          phiz(i) = phiz(i) +  tempnc(nc(i,n))*pz(i,n)
       ENDDO
      ENDDO
C
      DO i=1,nel
        IF(off(i)==zero.OR.offg(i)<=zero) cycle
        kc = (ca + cb*tel(i))*dt1*vol(i)*theaccfact          
        phix(i) = kc*phix(i)
        phiy(i) = kc*phiy(i)
        phiz(i) = kc*phiz(i)
      ENDDO
C
C force thermique nodale
C
      DO n=1,10
       DO i=1,nel
          IF(off(i)==zero.OR.offg(i)<=zero) cycle
          fphi(i,n) = fphi(i,n) + heat(i)*ni(i,n) - (phix(i)*px(i,n) + phiy(i)*py(i,n) + phiz(i)*pz(i,n))
        ENDDO
      ENDDO
C 
      RETURN
      END