s16sigs3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    s16sigs3   ../engine/source/elements/thickshell/solide16/s16sigs3.F
!||--- called by ------------------------------------------------------
!||    s16forc3   ../engine/source/elements/thickshell/solide16/s16forc3.F
!||====================================================================
      SUBROUTINE s16sigs3(
     1   DXX,     DYY,     DZZ,     D4,
     2   D5,      D6,      RX,      RY,
     3   RZ,      SX,      SY,      SZ,
     4   TX,      TY,      TZ,      EINT,
     5   VOL0,    SIGS,    MXT,     PM,
     6   DT1,     VOL0DP,  NEL)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      INTEGER MXT(*) 
      my_real
     1    DXX(*) ,DYY(*) ,DZZ(*) ,D4(*) ,D5(*) ,D6(*) ,
     2    RX(*) ,RY(*) ,RZ(*) ,SX(*) ,SY(*) ,SZ(*) ,
     3    TX(*) ,TY(*) ,TZ(*) ,EINT(*),VOL0(*),SIGS(*), 
     4    pm(npropm,*), dt1   
      DOUBLE PRECISION 
     .        vol0dp(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,MX
      my_real
     .   aa, dxy, dyz, dzx, drr, dss, dtt, drs, dst, dtr,
     .   shf,a11,a12,a13,a21,a22,a23,a31,a32,a33,e,nu,d11
C-----------------------------------------------
      mx = mxt(1)
      e  = pm(20,mx)
      nu = pm(21,mx)
      DO i=1,nel
        shf = five_over_6
        aa  = em01 * sigs(i)* ((one +nu) * (one -nu-nu)) / (e * (one -nu))
 
        dxy = half * d4(i)
        dyz = half * d5(i)
        dzx = half * d6(i)
 
        a11 = dxx(i)*rx(i)+dxy*ry(i)+dzx*rz(i)
        a12 = dxx(i)*sx(i)+dxy*sy(i)+dzx*sz(i)
        a13 = dxx(i)*tx(i)+dxy*ty(i)+dzx*tz(i)
        a21 = dxy*rx(i)+dyy(i)*ry(i)+dyz*rz(i)
        a22 = dxy*sx(i)+dyy(i)*sy(i)+dyz*sz(i)
        a23 = dxy*tx(i)+dyy(i)*ty(i)+dyz*tz(i)
        a31 = dzx*rx(i)+dyz*ry(i)+dzz(i)*rz(i)
        a32 = dzx*sx(i)+dyz*sy(i)+dzz(i)*sz(i)
        a33 = dzx*tx(i)+dyz*ty(i)+dzz(i)*tz(i)
 
        drr = rx(i)*a11+ry(i)*a21+rz(i)*a31
        dss = sx(i)*a12+sy(i)*a22+sz(i)*a32
        dtt = tx(i)*a13+ty(i)*a23+tz(i)*a33
        dtr = tx(i)*a11+ty(i)*a21+tz(i)*a31
        drs = rx(i)*a12+ry(i)*a22+rz(i)*a32
        dst = sx(i)*a13+sy(i)*a23+sz(i)*a33
 
        vol0(i) = vol0(i) * (one + aa)
        vol0dp(i) = vol0dp(i) * (one + aa)
        eint(i) = eint(i) / (1. + aa)
        dss     = dss - aa/dt1
 
        drs     = drs * shf
        dst     = dst * shf
 
        a11 = drr*rx(i)+drs*sx(i)+dtr*tx(i)
        a12 = drr*ry(i)+drs*sy(i)+dtr*ty(i)
        a13 = drr*rz(i)+drs*sz(i)+dtr*tz(i)
        a21 = drs*rx(i)+dss*sx(i)+dst*tx(i)
        a22 = drs*ry(i)+dss*sy(i)+dst*ty(i)
        a23 = drs*rz(i)+dss*sz(i)+dst*tz(i)
        a31 = dtr*rx(i)+dst*sx(i)+dtt*tx(i)
        a32 = dtr*ry(i)+dst*sy(i)+dtt*ty(i)
        a33 = dtr*rz(i)+dst*sz(i)+dtt*tz(i)
 
        dxx(i)= rx(i)*a11+sx(i)*a21+tx(i)*a31
        dyy(i)= ry(i)*a12+sy(i)*a22+ty(i)*a32
        dzz(i)= rz(i)*a13+sz(i)*a23+tz(i)*a33
        dzx   = rz(i)*a11+sz(i)*a21+tz(i)*a31
        dxy   = rx(i)*a12+sx(i)*a22+tx(i)*a32
        dyz   = ry(i)*a13+sy(i)*a23+ty(i)*a33
 
        d4(i) = two * dxy 
        d5(i) = two * dyz 
        d6(i) = two * dzx
      ENDDO
C-----------
      RETURN
      END