s20defo3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    s20defo3   ../engine/source/elements/solid/solide20/s20defo3.F
!||--- called by ------------------------------------------------------
!||    s16forc3   ../engine/source/elements/thickshell/solide16/s16forc3.F
!||    s20forc3   ../engine/source/elements/solid/solide20/s20forc3.F
!||====================================================================
      SUBROUTINE s20defo3(
     1   NPE,     PX,      PY,      PZ,
     2   VX,      VY,      VZ,      DXX,
     3   DXY,     DXZ,     DYX,     DYY,
     4   DYZ,     DZX,     DZY,     DZZ,
     5   D4,      D5,      D6,      WXX,
     6   WYY,     WZZ,     RHO,     RHOO,
     7   VOLNP,   VOLN,    NEL)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      INTEGER NPE
      my_real
     .  VX(MVSIZ,*),VY(MVSIZ,*),VZ(MVSIZ,*),
     .  PX(MVSIZ,*),PY(MVSIZ,*),PZ(MVSIZ,*),
     .   DXX(*), DXY(*), DXZ(*),
     .   DYX(*), DYY(*), DYZ(*),
     .   dzx(*), dzy(*), dzz(*), d4(*), d5(*), d6(*),
     .   wxx(*), wyy(*), wzz(*),rho(*),
     .  rhoo(*),volnp(*),voln(*)
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com08_c.inc"
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER  I,N
C     REAL
      my_real
     .   DT1D2
C-----------------------------------------------
C                                                                     12
      DO I=1,nel
        rhoo(i)=rho(i)
        voln(i)=volnp(i)
      ENDDO
      n = 1
      DO i=1,nel
        dxx(i)=px(i,n)*vx(i,n)
        dyy(i)=py(i,n)*vy(i,n)
        dzz(i)=pz(i,n)*vz(i,n)
        dxy(i)=py(i,n)*vx(i,n)
        dxz(i)=pz(i,n)*vx(i,n)
        dyx(i)=px(i,n)*vy(i,n)
        dyz(i)=pz(i,n)*vy(i,n)
        dzx(i)=px(i,n)*vz(i,n)
        dzy(i)=py(i,n)*vz(i,n)
      ENDDO
!
      DO n=2,npe
       DO i=1,nel
        dxx(i)=dxx(i)+px(i,n)*vx(i,n)
        dyy(i)=dyy(i)+py(i,n)*vy(i,n)
        dzz(i)=dzz(i)+pz(i,n)*vz(i,n)
        dxy(i)=dxy(i)+py(i,n)*vx(i,n)
        dxz(i)=dxz(i)+pz(i,n)*vx(i,n)
        dyx(i)=dyx(i)+px(i,n)*vy(i,n)
        dyz(i)=dyz(i)+pz(i,n)*vy(i,n)
        dzx(i)=dzx(i)+px(i,n)*vz(i,n)
        dzy(i)=dzy(i)+py(i,n)*vz(i,n)
       ENDDO
      ENDDO
C
      dt1d2=half*dt1
C
      DO i=1,nel
       d4(i)   =dxy(i)+dyx(i)
       d5(i)   =dyz(i)+dzy(i)
       d6(i)   =dxz(i)+dzx(i)
       wzz(i)=dt1d2*(dyx(i)-dxy(i))
       wyy(i)=dt1d2*(dxz(i)-dzx(i))
       wxx(i)=dt1d2*(dzy(i)-dyz(i))
      ENDDO
C
      RETURN
C
      END