s20mass3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    s20mass3   ../starter/source/elements/solid/solide20/s20mass3.F
!||--- called by ------------------------------------------------------
!||    s20init3   ../starter/source/elements/solid/solide20/s20init3.F
!||====================================================================
      SUBROUTINE s20mass3(
     1   MASS  ,MS  ,PARTSAV,IPART  ,MSS    ,VOLG,
     2   XX    ,YY  ,ZZ     ,VX     ,VY     ,VZ,  
     3   NC    ,STI ,STIFN  ,DELTAX2,RHO    ,DTX,
     4   DTELEM,MSSX,RHOCP  ,MCP     ,MCPS  ,MCPSX,
     5   FILL  )
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER IPART(*), NC(MVSIZ,20)
      my_real
     .   MASS(*), MS(*),PARTSAV(20,*), MSS(8,*),DELTAX2(*),
     .   XX(MVSIZ,20), YY(MVSIZ,20), ZZ(MVSIZ,20),
     .   VX(MVSIZ,20), VY(MVSIZ,20), VZ(MVSIZ,20),STI(*),STIFN(*), 
     .   volg(mvsiz),rho(mvsiz),dtx(mvsiz),dtelem(mvsiz),mssx(12,*),
     .   rhocp(*), mcp(*), mcps(8,*),mcpsx(12,*), fill(*)
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "vect01_c.inc"
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, IP,N1,N2, IPERM1(20),IPERM2(20),N
C     REAL
      my_real
     .   AXX,AYY,AZZ,AXY,AYZ,AZX,AM,BM,FAC,MASSCP
C
      DATA iperm1/0,0,0,0,0,0,0,0,1,2,3,4,1,2,3,4,5,6,7,8/
      DATA iperm2/0,0,0,0,0,0,0,0,2,3,4,1,5,6,7,8,6,7,8,5/
C-----------------------------------------------------------------------
C     mass init en parith pour spmd
       DO i=lft,llt
C
        mass(i)=fill(i)*rho(i)*volg(i)
        dtelem(i)=min(dtelem(i),dtx(i))
        sti(i) = fill(i) * rho(i) * volg(i) * two / sixty4 /
     .        max(em20,dtx(i)*dtx(i))
        fac=trhee_over_14
        am = mass(i)*fac/(eight*fac + twelve)
        bm = mass(i)*one/(eight*fac + twelve)
        mss(1,i)=am
        mss(2,i)=am
        mss(3,i)=am
        mss(4,i)=am
        mss(5,i)=am
        mss(6,i)=am
        mss(7,i)=am
        mss(8,i)=am
        stifn(nc(i,1))=stifn(nc(i,1))+sti(i)*deltax2(i)
        stifn(nc(i,2))=stifn(nc(i,2))+sti(i)*deltax2(i)
        stifn(nc(i,3))=stifn(nc(i,3))+sti(i)*deltax2(i)
        stifn(nc(i,4))=stifn(nc(i,4))+sti(i)*deltax2(i)
        stifn(nc(i,5))=stifn(nc(i,5))+sti(i)*deltax2(i)
        stifn(nc(i,6))=stifn(nc(i,6))+sti(i)*deltax2(i)
        stifn(nc(i,7))=stifn(nc(i,7))+sti(i)*deltax2(i)
        stifn(nc(i,8))=stifn(nc(i,8))+sti(i)*deltax2(i)
        DO n=9,20
          n1=iperm1(n)
          n2=iperm2(n)
          IF(nc(i,n) /= 0)THEN
            mssx(n-8,i)=bm
            stifn(nc(i,n))=stifn(nc(i,n))+sti(i)
          ELSE
            mss(n1,i)=mss(n1,i)+ half*bm
            mss(n2,i)=mss(n2,i)+ half*bm
            stifn(nc(i,n1))=stifn(nc(i,n1)) + half*sti(i)
            stifn(nc(i,n2))=stifn(nc(i,n2)) + half*sti(i)
          ENDIF
        ENDDO
C
        ip=ipart(i)
        partsav(1,ip)=partsav(1,ip) + mass(i)
        partsav(2,ip)=partsav(2,ip)
     .    + am*(xx(i,1)+xx(i,2)+xx(i,3)+xx(i,4)
     .         +xx(i,5)+xx(i,6)+xx(i,7)+xx(i,8))
     .    + bm*(xx(i,9) +xx(i,10)+xx(i,11)+xx(i,12)+xx(i,13)+xx(i,14)
     .         +xx(i,15)+xx(i,16)+xx(i,17)+xx(i,18)+xx(i,19)+xx(i,20))
        partsav(3,ip)=partsav(3,ip)
     .    + am*(yy(i,1)+yy(i,2)+yy(i,3)+yy(i,4)
     .         +yy(i,5)+yy(i,6)+yy(i,7)+yy(i,8))
     .    + bm*(yy(i,9) +yy(i,10)+yy(i,11)+yy(i,12)+yy(i,13)+yy(i,14)
     .         +yy(i,15)+yy(i,16)+yy(i,17)+yy(i,18)+yy(i,19)+yy(i,20))
        partsav(4,ip)=partsav(4,ip)
     .    + am*(zz(i,1)+zz(i,2)+zz(i,3)+zz(i,4)
     .         +zz(i,5)+zz(i,6)+zz(i,7)+zz(i,8))
     .    + bm*(zz(i,9) +zz(i,10)+zz(i,11)+zz(i,12)+zz(i,13)+zz(i,14)
     .         +zz(i,15)+zz(i,16)+zz(i,17)+zz(i,18)+zz(i,19)+zz(i,20))
        axx = am*(xx(i,1)*xx(i,1)+xx(i,2)*xx(i,2)
     .           +xx(i,3)*xx(i,3)+xx(i,4)*xx(i,4)
     .           +xx(i,5)*xx(i,5)+xx(i,6)*xx(i,6)
     .           +xx(i,7)*xx(i,7)+xx(i,8)*xx(i,8))
     .       +bm*(xx(i,9) *xx(i,9) +xx(i,10)*xx(i,10)
     .           +xx(i,11)*xx(i,11)+xx(i,12)*xx(i,12)
     .           +xx(i,13)*xx(i,13)+xx(i,14)*xx(i,14)
     .           +xx(i,15)*xx(i,15)+xx(i,16)*xx(i,16)
     .           +xx(i,17)*xx(i,17)+xx(i,18)*xx(i,18)
     .           +xx(i,19)*xx(i,19)+xx(i,20)*xx(i,20))
        ayy = am*(yy(i,1)*yy(i,1)+yy(i,2)*yy(i,2)
     .           +yy(i,3)*yy(i,3)+yy(i,4)*yy(i,4)
     .           +yy(i,5)*yy(i,5)+yy(i,6)*yy(i,6)
     .           +yy(i,7)*yy(i,7)+yy(i,8)*yy(i,8))
     .       +bm*(yy(i,9) *yy(i,9) +yy(i,10)*yy(i,10)
     .           +yy(i,11)*yy(i,11)+yy(i,12)*yy(i,12)
     .           +yy(i,13)*yy(i,13)+yy(i,14)*yy(i,14)
     .           +yy(i,15)*yy(i,15)+yy(i,16)*yy(i,16)
     .           +yy(i,17)*yy(i,17)+yy(i,18)*yy(i,18)
     .           +yy(i,19)*yy(i,19)+yy(i,20)*yy(i,20))
        azz = am*(zz(i,1)*zz(i,1)+zz(i,2)*zz(i,2)
     .           +zz(i,3)*zz(i,3)+zz(i,4)*zz(i,4)
     .           +zz(i,5)*zz(i,5)+zz(i,6)*zz(i,6)
     .           +zz(i,7)*zz(i,7)+zz(i,8)*zz(i,8))
     .       +bm*(zz(i,9) *zz(i,9) +zz(i,10)*zz(i,10)
     .           +zz(i,11)*zz(i,11)+zz(i,12)*zz(i,12)
     .           +zz(i,13)*zz(i,13)+zz(i,14)*zz(i,14)
     .           +zz(i,15)*zz(i,15)+zz(i,16)*zz(i,16)
     .           +zz(i,17)*zz(i,17)+zz(i,18)*zz(i,18)
     .           +zz(i,19)*zz(i,19)+zz(i,20)*zz(i,20))
        axy = am*(xx(i,1)*yy(i,1)+xx(i,2)*yy(i,2)
     .           +xx(i,3)*yy(i,3)+xx(i,4)*yy(i,4)
     .           +xx(i,5)*yy(i,5)+xx(i,6)*yy(i,6)
     .           +xx(i,7)*yy(i,7)+xx(i,8)*yy(i,8))
     .       +bm*(xx(i,9) *yy(i,9) +xx(i,10)*yy(i,10)
     .           +xx(i,11)*yy(i,11)+xx(i,12)*yy(i,12)
     .           +xx(i,13)*yy(i,13)+xx(i,14)*yy(i,14)
     .           +xx(i,15)*yy(i,15)+xx(i,16)*yy(i,16)
     .           +xx(i,17)*yy(i,17)+xx(i,18)*yy(i,18)
     .           +xx(i,19)*yy(i,19)+xx(i,20)*yy(i,20))
        ayz = am*(yy(i,1)*zz(i,1)+yy(i,2)*zz(i,2)
     .           +yy(i,3)*zz(i,3)+yy(i,4)*zz(i,4)
     .           +yy(i,5)*zz(i,5)+yy(i,6)*zz(i,6)
     .           +yy(i,7)*zz(i,7)+yy(i,8)*zz(i,8))
     .       +bm*(yy(i,9) *zz(i,9) +yy(i,10)*zz(i,10)
     .           +yy(i,11)*zz(i,11)+yy(i,12)*zz(i,12)
     .           +yy(i,13)*zz(i,13)+yy(i,14)*zz(i,14)
     .           +yy(i,15)*zz(i,15)+yy(i,16)*zz(i,16)
     .           +yy(i,17)*zz(i,17)+yy(i,18)*zz(i,18)
     .           +yy(i,19)*zz(i,19)+yy(i,20)*zz(i,20))
        azx = am*(zz(i,1)*xx(i,1)+zz(i,2)*xx(i,2)
     .           +zz(i,3)*xx(i,3)+zz(i,4)*xx(i,4)
     .           +zz(i,5)*xx(i,5)+zz(i,6)*xx(i,6)
     .           +zz(i,7)*xx(i,7)+zz(i,8)*xx(i,8))
     .       +bm*(zz(i,9) *xx(i,9) +zz(i,10)*xx(i,10)
     .           +zz(i,11)*xx(i,11)+zz(i,12)*xx(i,12)
     .           +zz(i,13)*xx(i,13)+zz(i,14)*xx(i,14)
     .           +zz(i,15)*xx(i,15)+zz(i,16)*xx(i,16)
     .           +zz(i,17)*xx(i,17)+zz(i,18)*xx(i,18)
     .           +zz(i,19)*xx(i,19)+zz(i,20)*xx(i,20))
        partsav(5,ip) =partsav(5,ip)  + (ayy+azz)
        partsav(6,ip) =partsav(6,ip)  + (azz+axx)
        partsav(7,ip) =partsav(7,ip)  + (axx+ayy)
        partsav(8,ip) =partsav(8,ip)  - axy
        partsav(9,ip) =partsav(9,ip)  - ayz
        partsav(10,ip)=partsav(10,ip) - azx
C
        partsav(11,ip)=partsav(11,ip)
     .    + am*(vx(i,1)+vx(i,2)+vx(i,3)+vx(i,4)
     .         +vx(i,5)+vx(i,6)+vx(i,7)+vx(i,8))
     .    + bm*(vx(i,9) +vx(i,10)+vx(i,11)+vx(i,12)+vx(i,13)+vx(i,14)
     .         +vx(i,15)+vx(i,16)+vx(i,17)+vx(i,18)+vx(i,19)+vx(i,20))
        partsav(12,ip)=partsav(12,ip)
     .    + am*(vy(i,1)+vy(i,2)+vy(i,3)+vy(i,4)
     .         +vy(i,5)+vy(i,6)+vy(i,7)+vy(i,8))
     .    + bm*(vy(i,9) +vy(i,10)+vy(i,11)+vy(i,12)+vy(i,13)+vy(i,14)
     .         +vy(i,15)+vy(i,16)+vy(i,17)+vy(i,18)+vy(i,19)+vy(i,20))
        partsav(13,ip)=partsav(13,ip)
     .    + am*(vz(i,1)+vz(i,2)+vz(i,3)+vz(i,4)
     .         +vz(i,5)+vz(i,6)+vz(i,7)+vz(i,8))
     .    + bm*(vz(i,9) +vz(i,10)+vz(i,11)+vz(i,12)+vz(i,13)+vz(i,14)
     .         +vz(i,15)+vz(i,16)+vz(i,17)+vz(i,18)+vz(i,19)+vz(i,20))
        partsav(14,ip)=partsav(14,ip) + half * 
     .       (am*(vx(i,1)*vx(i,1)+vx(i,2)*vx(i,2)
     .           +vx(i,3)*vx(i,3)+vx(i,4)*vx(i,4)
     .           +vx(i,5)*vx(i,5)+vx(i,6)*vx(i,6)
     .           +vx(i,7)*vx(i,7)+vx(i,8)*vx(i,8)
     .           +vy(i,1)*vy(i,1)+vy(i,2)*vy(i,2)
     .           +vy(i,3)*vy(i,3)+vy(i,4)*vy(i,4)
     .           +vy(i,5)*vy(i,5)+vy(i,6)*vy(i,6)
     .           +vy(i,7)*vy(i,7)+vy(i,8)*vy(i,8)
     .           +vz(i,1)*vz(i,1)+vz(i,2)*vz(i,2)
     .           +vz(i,3)*vz(i,3)+vz(i,4)*vz(i,4)
     .           +vz(i,5)*vz(i,5)+vz(i,6)*vz(i,6)
     .           +vz(i,7)*vz(i,7)+vz(i,8)*vz(i,8))
     .       +bm*(vx(i,9) *vx(i,9) +vx(i,10)*vx(i,10)
     .           +vx(i,11)*vx(i,11)+vx(i,12)*vx(i,12)
     .           +vx(i,13)*vx(i,13)+vx(i,14)*vx(i,14)
     .           +vx(i,15)*vx(i,15)+vx(i,16)*vx(i,16)
     .           +vx(i,17)*vx(i,17)+vx(i,18)*vx(i,18)
     .           +vx(i,19)*vx(i,19)+vx(i,20)*vx(i,20)
     .           +vy(i,9) *vy(i,9) +vy(i,10)*vy(i,10)
     .           +vy(i,11)*vy(i,11)+vy(i,12)*vy(i,12)
     .           +vy(i,13)*vy(i,13)+vy(i,14)*vy(i,14)
     .           +vy(i,15)*vy(i,15)+vy(i,16)*vy(i,16)
     .           +vy(i,17)*vy(i,17)+vy(i,18)*vy(i,18)
     .           +vy(i,19)*vy(i,19)+vy(i,20)*vy(i,20)
     .           +vz(i,9) *vz(i,9) +vz(i,10)*vz(i,10)
     .           +vz(i,11)*vz(i,11)+vz(i,12)*vz(i,12)
     .           +vz(i,13)*vz(i,13)+vz(i,14)*vz(i,14)
     .           +vz(i,15)*vz(i,15)+vz(i,16)*vz(i,16)
     .           +vz(i,17)*vz(i,17)+vz(i,18)*vz(i,18)
     .           +vz(i,19)*vz(i,19)+vz(i,20)*vz(i,20)))
       ENDDO
C
c --- for FEM solide heat trasnfert  
c
       IF(jthe < 0 ) THEN
        DO i=lft,llt
          masscp=fill(i)*rhocp(i)*volg(i)        
          fac=trhee_over_14
          am = masscp*fac/(eight*fac + twelve)
          bm = masscp*one/(eight*fac + twelve)
          mcps(1,i)=am
          mcps(2,i)=am
          mcps(3,i)=am
          mcps(4,i)=am
          mcps(5,i)=am
          mcps(6,i)=am
          mcps(7,i)=am
          mcps(8,i)=am
          DO n=9,20
            n1=iperm1(n)
            n2=iperm2(n)
            IF(nc(i,n) /= 0)THEN
              mcpsx(n-8,i)=bm
            ELSE
              mcps(n1,i)=mcps(n1,i)+ half*bm
              mcps(n2,i)=mcps(n2,i)+ half*bm
            ENDIF
          ENDDO
        ENDDO 
       ENDIF
C-----------      
      RETURN
      END SUBROUTINE s20mass3
C
 
!||====================================================================
!||    s20msi     ../starter/source/elements/solid/solide20/s20mass3.F
!||--- called by ------------------------------------------------------
!||    s16init3   ../starter/source/elements/thickshell/solide16/s16init3.f
!||    s20init3   ../starter/source/elements/solid/solide20/s20init3.F
!||====================================================================
      SUBROUTINE s20msi(RHO  ,MASS ,VOLU  ,DTELEM ,STI,
     .                  OFF  ,SIG  ,EINT  ,DTX    ,NEL,
     .                  OFFG ,SIGG ,EINTG ,RHOG   ,WIP)
C
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NEL
C     REAL
      my_real
     .   RHO(*), MASS(*),VOLU(*),DTELEM(*),STI(*),
     .   SIG(NEL,6),EINT(*),OFF(*),
     .   SIGG(NEL,6),EINTG(*),RHOG(*),OFFG(*),WIP
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "vect01_c.inc"
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
      my_real
     .   DTX(MVSIZ)    
C-----------------------------------------------
      DO I=lft,llt
c        MASS(I)=RHO(I)*VOLU(I)
c        DTELEM(I)=MIN(DTELEM(I),DTX(I))
c        STI(I) = RHO(I) * VOLU(I) / 
c     .        MAX(EM20,DTX(I)*DTX(I))
        sigg(i,1) = sigg(i,1) + wip * sig(i,1)
        sigg(i,2) = sigg(i,2) + wip * sig(i,2)
        sigg(i,3) = sigg(i,3) + wip * sig(i,3)
        sigg(i,4) = sigg(i,4) + wip * sig(i,4)
        sigg(i,5) = sigg(i,5) + wip * sig(i,5)
        sigg(i,6) = sigg(i,6) + wip * sig(i,6)
        rhog(i)   = rhog(i)   + wip * rho(i)
        eintg(i)  = eintg(i)  + wip * eint(i)
        offg(i)   = off(i)
      ENDDO
C-----------
      RETURN
      END SUBROUTINE s20msi
C.....
!||====================================================================
!||    sigin20b    ../starter/source/elements/solid/solide20/s20mass3.F
!||--- called by ------------------------------------------------------
!||    s10init3    ../starter/source/elements/solid/solide10/s10init3.F
!||    s16init3    ../starter/source/elements/thickshell/solide16/s16init3.F
!||    s20init3    ../starter/source/elements/solid/solide20/s20init3.F
!||    s6cinit3    ../starter/source/elements/thickshell/solide6c/s6cinit3.F
!||    s8cinit3    ../starter/source/elements/thickshell/solide8c/s8cinit3.F
!||    s8zinit3    ../starter/source/elements/solid/solide8z/s8zinit3.F
!||    scinit3     ../starter/source/elements/thickshell/solidec/scinit3.F
!||--- calls      -----------------------------------------------------
!||    srota6_m1   ../starter/source/output/anim/srota6_M1.F
!||====================================================================
      SUBROUTINE sigin20b(
     .           SIG     ,PM      ,VOL     ,SIGSP  ,
     .           SIGI    ,EINT    ,RHO     ,UVAR   ,EPS     ,
     .           IX      ,NIX     ,NSIGI   ,IPT    ,NUVAR   ,
     .           NEL     ,IUSER   ,IDEF    ,NSIGS  ,STRSGLOB,
     .           STRAGLOB,JHBE    ,IGTYP   ,X      ,BUFGAMA ,
     .           MAT     ,EPSP    ,L_PLA   ,PT     ,SIGB    ,
     .           L_SIGB  ,IPM     ,BUFMAT  ,VOLDP  )      
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include       "param_c.inc"
#include       "com01_c.inc"
#include       "vect01_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER IPM(NPROPMI,*)
      INTEGER NIX,N,JPS,JHBE,IGTYP,NSIGI,NUVAR,NEL,IUSER,NSIGS,
     .   IDEF,L_PLA,L_SIGB
      INTEGER IX(NIX,*),STRSGLOB(*),STRAGLOB(*),MAT(NEL),PT(*),SIGB(NEL*L_SIGB)
C     REAL
      my_real
     .   SIG(NEL,6)   , EINT(*), RHO(*), SIGSP(NSIGI,*),
     .   PM(NPROPM,*), VOL(*), UVAR(*), SIGI(NSIGS,*),
     .   EPS(NEL,6),X(3,*),BUFGAMA(*),EPSP(*),BUFMAT(*)
      DOUBLE PRECISION
     .   VOLDP(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,J,IIP,JPT, II, JJ, IPT, IPP,IUS,IPSU,JPS1,MA,IFLAGINI,
     .   nvar_tmp,iadb,nrate
      my_real
     .   gama(6),tens(6)
C=======================================================================
       DO i=lft,llt
         ma = mat(i)        
         eint(i)=pm(23,ma)
         rho(i) =pm(89,ma)
       ENDDO
C      
       IF (isigi /= 0) THEN
C         
        jps=1+ (ipt-1)*9
        jps1 = nvsolid1 + (ipt-1)*6      
        DO i=lft,llt
          iflagini = 0
          IF (straglob(i) == 1 .OR. strsglob(i) == 1) THEN
            IF(jcvt==2)THEN
              gama(1)=bufgama(i        )
              gama(2)=bufgama(i +   nel)
              gama(3)=bufgama(i + 2*nel)
              gama(4)=bufgama(i + 3*nel)
              gama(5)=bufgama(i + 4*nel)
              gama(6)=bufgama(i + 5*nel)
            ELSE
              gama(1)=one
              gama(2)=zero
              gama(3)=zero
              gama(4)=zero
              gama(5)=one
              gama(6)=zero
            END IF
          ENDIF
C         CONTRAINTES INITIALES
 
          ii=nft+i
          jj=pt(ii)
          iflagini = 1
          IF(jj==0)iflagini = 0
c
            IF (iflagini == 1) THEN   
              ipp = i  
              IF(nvsolid1 /= 0 )THEN                 
                sig(i,1)=sigsp(jps+1,jj)
                sig(i,2)=sigsp(jps+2,jj)
                sig(i,3)=sigsp(jps+3,jj)
                sig(i,4)=sigsp(jps+4,jj)
                sig(i,5)=sigsp(jps+5,jj)
                sig(i,6)=sigsp(jps+6,jj)
                IF (strsglob(i) == 1) THEN
                  tens(1)=sig(i,1)
                  tens(2)=sig(i,2)
                  tens(3)=sig(i,3)
                  tens(4)=sig(i,4)
                  tens(5)=sig(i,5)
                  tens(6)=sig(i,6)
                  CALL srota6_m1(x,ix(1,ii),jcvt,tens,gama,jhbe,igtyp)                      
                  sig(i,1)=tens(1)
                  sig(i,2)=tens(2)
                  sig(i,3)=tens(3)
                  sig(i,4)=tens(4)
                  sig(i,5)=tens(5)
                  sig(i,6)=tens(6)
                ENDIF
                IF(l_pla /= 0 .AND. sigsp(jps+7,jj) /= zero) 
     .                   epsp(i) = sigsp(jps+7,jj)       
                IF (sigsp(jps+8,jj) /= zero) eint(i)=sigsp(jps+8,jj)
                IF (sigsp(jps+9,jj) /= zero) THEN
                  voldp(i) = sigsp(jps+9,jj)*voldp(i) / rho(i)
                  vol(i) = sigsp(jps+9,jj)*vol(i) / rho(i)
                  rho(i) = sigsp(jps+9,jj)
                ENDIF
              ENDIF
c
              IF (mtn >= 28 .AND. iuser == 1) THEN
                IF (mtn == 36 .and. l_sigb == 6) THEN                       
                  iadb = ipm(7,mat(1))               
                  nrate = nint(bufmat(iadb))
                  nvar_tmp = sigsp(nvsolid1 + nvsolid2 + 3, jj)  
                  ipsu = nvsolid1 + nvsolid2 + 4 + (ipt - 1)*nvar_tmp
                  DO ius = 1,6         
                    ipp = i + (ius -1)*nel
                    sigb(ipp) = sigsp(ipsu + nrate + ius, jj)                        
                  ENDDO 
                ELSEIF (mtn == 112) THEN 
                  nvar_tmp = sigsp(nvsolid1 + nvsolid2 + 3, jj)  
                  ipsu = nvsolid1 + nvsolid2 + 4 + (ipt - 1)*nvar_tmp
                  DO ius = 1, nvar_tmp             
                    ipp = i + ius*nel
                    epsp(ipp) = sigsp(ipsu + ius, jj)          
                  ENDDO 
                ELSE IF (mtn /= 36) THEN
                  nvar_tmp = sigsp(nvsolid1 + nvsolid2 + 3, jj)  
                  ipsu = nvsolid1 + nvsolid2 + 4 + (ipt - 1)*nvar_tmp
                  DO ius = 1, nvar_tmp             
                    ipp = i + (ius -1)*nel
                    uvar(ipp) = sigsp(ipsu + ius, jj)          
                  ENDDO 
                  DO ius = nvar_tmp + 1, nuvar             
                    ipp = i + (ius -1)*nel
                    uvar(ipp) = zero        
                  ENDDO
                ENDIF
              ENDIF
c
              IF (nvsolid2 /= 0 .AND. idef /=0) THEN      
                eps(i,1) = sigsp(jps1 + 1 , jj)
                eps(i,2) = sigsp(jps1 + 2 , jj)
                eps(i,3) = sigsp(jps1 + 3 , jj)
                eps(i,4) = sigsp(jps1 + 4 , jj)
                eps(i,5) = sigsp(jps1 + 5 , jj)
                eps(i,6) = sigsp(jps1 + 6 , jj)
                IF (straglob(i) == 1) THEN
                  tens(1)=eps(i,1)
                  tens(2)=eps(i,2)
                  tens(3)=eps(i,3)
                  tens(4)=eps(i,4)
                  tens(5)=eps(i,5)
                  tens(6)=eps(i,6)
                  CALL srota6_m1(x,ix(1,ii),jcvt,tens,gama,jhbe,igtyp)
                  eps(i,1) = tens(1)
                  eps(i,2) = tens(2)
                  eps(i,3) = tens(3)
                  eps(i,4) = tens(4)
                  eps(i,5) = tens(5)
                  eps(i,6) = tens(6)
                ENDIF
              ENDIF  
            ENDIF !IF (IFLAGINI == 1)
c        
        ENDDO ! I=LFT,LLT
       ENDIF  ! ISIGI /= 0
c-----------        
      RETURN
      END SUBROUTINE sigin20b