s4jaci3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    s4jaci3   ../starter/source/elements/solid/solide4/s4jaci3.F
!||--- called by ------------------------------------------------------
!||    s4init3   ../starter/source/elements/solid/solide4/s4init3.F
!||====================================================================
      SUBROUTINE s4jaci3(SAV   ,JAC_I, VOL, NEL  ) 
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER , INTENT(IN) :: NEL
      DOUBLE PRECISION , DIMENSION(NEL,9),INTENT(IN) :: SAV     
      my_real , DIMENSION(10,NEL),INTENT(OUT) :: jac_i     
      my_real , DIMENSION(NEL),   INTENT(OUT) :: vol     
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      double precision
     .   x1(mvsiz), x2(mvsiz), x3(mvsiz), x4(mvsiz), 
     .   y1(mvsiz), y2(mvsiz), y3(mvsiz), y4(mvsiz),
     .   z1(mvsiz), z2(mvsiz), z3(mvsiz), z4(mvsiz),voldp 
C     REAL
      my_real
     .   det(mvsiz),
     .   px1(mvsiz), px2(mvsiz), px3(mvsiz), px4(mvsiz),  
     .   py1(mvsiz), py2(mvsiz), py3(mvsiz), py4(mvsiz),  
     .   pz1(mvsiz), pz2(mvsiz), pz3(mvsiz), pz4(mvsiz)  
      INTEGER I
      my_real
     .   b1(mvsiz), b2(mvsiz), b3(mvsiz), b4(mvsiz), 
     .   c1(mvsiz), c2(mvsiz), c3(mvsiz), c4(mvsiz),
     .   d1(mvsiz), d2(mvsiz), d3(mvsiz), d4(mvsiz) 
      double precision
     .   x41, y41, z41, x42, y42, z42, x43, y43, z43,b1dp,c1dp,d1dp
      my_real
     .   d ,pxx, pyy, pzz, pxy, pyz, pxz, gfac, aa, bb, p, ld
C=======================================================================
      DO i=1,nel
       x4(i)=zero
       y4(i)=zero
       z4(i)=zero
      ENDDO
      DO i=1,nel
       x1(i)=sav(i,1)
       y1(i)=sav(i,4)
       z1(i)=sav(i,7)
       x2(i)=sav(i,2)
       y2(i)=sav(i,5)
       z2(i)=sav(i,8)
       x3(i)=sav(i,3)
       y3(i)=sav(i,6)
       z3(i)=sav(i,9)
      ENDDO
      DO i=1,nel
       x43 = x4(i) - x3(i)
       y43 = y4(i) - y3(i)
       z43 = z4(i) - z3(i)
       x41 = x4(i) - x1(i)
       y41 = y4(i) - y1(i)
       z41 = z4(i) - z1(i)
       x42 = x4(i) - x2(i)
       y42 = y4(i) - y2(i)
       z42 = z4(i) - z2(i)
C
       b1dp  =  y43*z42 - y42*z43
       b1(i) =  b1dp
       b2(i) =  y41*z43 - y43*z41
       b3(i) =  y42*z41 - y41*z42
       b4(i) =  -(b1(i) + b2(i) + b3(i))
C
       c1dp  =  z43*x42 - z42*x43
       c1(i) =  c1dp
       c2(i) =  z41*x43 - z43*x41
       c3(i) =  z42*x41 - z41*x42
       c4(i) =  -(c1(i) + c2(i) + c3(i))
C
       d1dp  =  x43*y42 - x42*y43
       d1(i) =  d1dp
       d2(i) =  x41*y43 - x43*y41
       d3(i) =  x42*y41 - x41*y42
       d4(i) =  -(d1(i) + d2(i) + d3(i))
C
       voldp = (x41*b1dp + y41*c1dp + z41*d1dp)*one_over_6
       det(i) = voldp
       vol(i) = det(i)
      ENDDO
C
      DO i=1,nel
        d = one/det(i)/six
        px1(i)=-b1(i)*d
        py1(i)=-c1(i)*d
        pz1(i)=-d1(i)*d
        px2(i)=-b2(i)*d
        py2(i)=-c2(i)*d
        pz2(i)=-d2(i)*d
        px3(i)=-b3(i)*d
        py3(i)=-c3(i)*d
        pz3(i)=-d3(i)*d
        px4(i)=-b4(i)*d
        py4(i)=-c4(i)*d
        pz4(i)=-d4(i)*d
      ENDDO
       DO i=1,nel
        jac_i(1,i) = px1(i)
        jac_i(2,i) = px2(i)
        jac_i(3,i) = px3(i)
        jac_i(4,i) = py1(i)
        jac_i(5,i) = py2(i)
        jac_i(6,i) = py3(i)
        jac_i(7,i) = pz1(i)
        jac_i(8,i) = pz2(i)
        jac_i(9,i) = pz3(i)
        jac_i(10,i) = vol(i)
       ENDDO
C-----------
      RETURN
      END