s4volnod3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    s4volnod3         ../engine/source/elements/solid/solide4_sfem/s4volnod3.F
!||--- called by ------------------------------------------------------
!||    s4alesfem         ../engine/source/elements/solid/solide4_sfem/s4alesfem.F
!||    s4lagsfem         ../engine/source/elements/solid/solide4_sfem/s4lagsfem.F
!||--- calls      -----------------------------------------------------
!||    foat_to_6_float   ../engine/source/system/parit.F
!||====================================================================
      SUBROUTINE s4volnod3(
     1   VOLNOD6, X,       NC1,     NC2,
     2   NC3,     NC4,     OFFG,    XDP,
     3   NEL,     ISMSTR)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
#include      "param_c.inc"
#include      "com04_c.inc"
#include      "scr05_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: ISMSTR
      INTEGER NC1(*),NC2(*),NC3(*),NC4(*),NEL
      DOUBLE PRECISION
     .   volnod6(6,2*numnod)
      DOUBLE PRECISION , DIMENSION(3,SXDP/3), INTENT(IN) :: XDP     
C     REAL
      my_real
     .   x(3,*),offg(*)
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "scr18_c.inc"
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, K
C     REAL
 
      my_real
     .   det(mvsiz)
      double precision
     .   x41, y41, z41, x42, y42, z42, x43, y43, z43,
     .   b1, c1, d1
      double precision
     .   x1(mvsiz), x2(mvsiz), x3(mvsiz), x4(mvsiz),
     .   y1(mvsiz), y2(mvsiz), y3(mvsiz), y4(mvsiz),
     .   z1(mvsiz), z2(mvsiz), z3(mvsiz), z4(mvsiz)
 
      double precision
     .   det6(6,mvsiz),detdp
C----------------------------
C     NODAL COORDINATES     
C----------------------------
      IF (ismstr==1.OR.ismstr==11) RETURN
      IF(iresp == 1) THEN
        IF((ismstr==2.OR.ismstr==12).AND.idtmin(1)==3)THEN
          DO i=1,nel
            IF(abs(offg(i))>one) cycle
            x1(i)=xdp(1,nc1(i))
            y1(i)=xdp(2,nc1(i))
            z1(i)=xdp(3,nc1(i))
            x2(i)=xdp(1,nc2(i))
            y2(i)=xdp(2,nc2(i))
            z2(i)=xdp(3,nc2(i))
            x3(i)=xdp(1,nc3(i))
            y3(i)=xdp(2,nc3(i))
            z3(i)=xdp(3,nc3(i))
            x4(i)=xdp(1,nc4(i))
            y4(i)=xdp(2,nc4(i))
            z4(i)=xdp(3,nc4(i))
          ENDDO
        ELSE
          DO i=1,nel
            x1(i)=xdp(1,nc1(i))
            y1(i)=xdp(2,nc1(i))
            z1(i)=xdp(3,nc1(i))
            x2(i)=xdp(1,nc2(i))
            y2(i)=xdp(2,nc2(i))
            z2(i)=xdp(3,nc2(i))
            x3(i)=xdp(1,nc3(i))
            y3(i)=xdp(2,nc3(i))
            z3(i)=xdp(3,nc3(i))
            x4(i)=xdp(1,nc4(i))
            y4(i)=xdp(2,nc4(i))
            z4(i)=xdp(3,nc4(i))
          ENDDO
        ENDIF
      ELSE
        IF((ismstr==2.OR.ismstr==12).AND.idtmin(1)==3)THEN
          DO i=1,nel
            IF(abs(offg(i))>one) cycle
            x1(i)=x(1,nc1(i))
            y1(i)=x(2,nc1(i))
            z1(i)=x(3,nc1(i))
            x2(i)=x(1,nc2(i))
            y2(i)=x(2,nc2(i))
            z2(i)=x(3,nc2(i))
            x3(i)=x(1,nc3(i))
            y3(i)=x(2,nc3(i))
            z3(i)=x(3,nc3(i))
            x4(i)=x(1,nc4(i))
            y4(i)=x(2,nc4(i))
            z4(i)=x(3,nc4(i))
          ENDDO
        ELSE
          DO i=1,nel
            x1(i)=x(1,nc1(i))
            y1(i)=x(2,nc1(i))
            z1(i)=x(3,nc1(i))
            x2(i)=x(1,nc2(i))
            y2(i)=x(2,nc2(i))
            z2(i)=x(3,nc2(i))
            x3(i)=x(1,nc3(i))
            y3(i)=x(2,nc3(i))
            z3(i)=x(3,nc3(i))
            x4(i)=x(1,nc4(i))
            y4(i)=x(2,nc4(i))
            z4(i)=x(3,nc4(i))
          ENDDO
        ENDIF
      END IF !(IRESP == 1) THEN
C----------------------------
C     TETRAHEDRON VOLUME
C----------------------------
      DO i=1,nel
       IF (offg(i) == zero .OR. abs(offg(i))>one) THEN
         det(i)= zero
       ELSE
         x43 = x4(i) - x3(i)
         y43 = y4(i) - y3(i)
         z43 = z4(i) - z3(i)
         x41 = x4(i) - x1(i)
         y41 = y4(i) - y1(i)
         z41 = z4(i) - z1(i)
         x42 = x4(i) - x2(i)
         y42 = y4(i) - y2(i)
         z42 = z4(i) - z2(i)
C
         b1 =  y43*z42 - y42*z43
         c1 =  z43*x42 - z42*x43
         d1 =  x43*y42 - x42*y43
C
         detdp= (x41*b1 + y41*c1 + z41*d1)*one_over_6
         det(i)= detdp
       ENDIF
      ENDDO
 
      !Parith-On treatment
      CALL foat_to_6_float(1  ,nel  ,det ,det6 )
 
      DO i=1,nel
C----------------------------------
C VOLUME <0 SERA TESTE DANS S4DERI3
C----------------------------------
        !Parith-On treatment
        DO k=1,6
          volnod6(k,nc1(i)) = volnod6(k,nc1(i)) + det6(k,i)
          volnod6(k,nc2(i)) = volnod6(k,nc2(i)) + det6(k,i)
          volnod6(k,nc3(i)) = volnod6(k,nc3(i)) + det6(k,i)
          volnod6(k,nc4(i)) = volnod6(k,nc4(i)) + det6(k,i)
        ENDDO
      ENDDO
C
      RETURN
      END