s6cdefo3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    s6cdefc3   ../engine/source/elements/thickshell/solide6c/s6cdefo3.F
!||--- called by ------------------------------------------------------
!||    s6cforc3   ../engine/source/elements/thickshell/solide6c/s6cforc3.F
!||====================================================================
      SUBROUTINE s6cdefc3(
     1   PX1,     PX2,     PX3,     PX4,
     2   PY1,     PY2,     PY3,     PY4,
     3   PZ1,     PZ2,     PZ3,     PZ4,
     4   VX1,     VX2,     VX3,     VX4,
     5   VX5,     VX6,     VY1,     VY2,
     6   VY3,     VY4,     VY5,     VY6,
     7   VZ1,     VZ2,     VZ3,     VZ4,
     8   VZ5,     VZ6,     DXX,     DXY,
     9   DXZ,     DYX,     DYY,     DYZ,
     A   DZX,     DZY,     DZZ,     D4,
     B   D5,      D6,      WXX,     WYY,
     C   WZZ,     DHXX,    DHXY,    DHXZ,
     D   DHYX,    DHYY,    DHYZ,    DHZX,
     E   DHZY,    DHZZ,    DH4,     DH5,
     F   DH6,     PX1H,    PX2H,    PX3H,
     G   PY1H,    PY2H,    PY3H,    PZ1H,
     H   PZ2H,    PZ3H,    JI33,    B1X,
     I   B1Y,     B2Y,     B2X,     B1122,
     J   B1221,   B2212,   B1121,   B1XH,
     K   B1YH,    B2XH,    B2YH,    B1122H,
     L   B1221H,  B2212H,  B1121H,  DDHV,
     M   NU,      NEL)
C   ---
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
C     REAL
      my_real
     .   VX1(*), VX2(*), VX3(*), VX4(*), VX5(*), VX6(*), 
     .   VY1(*), VY2(*), VY3(*), VY4(*), VY5(*), VY6(*), 
     .   VZ1(*), VZ2(*), VZ3(*), VZ4(*), VZ5(*), VZ6(*), 
     .   PX1(*), PX2(*), PX3(*), PX4(*),
     .   PY1(*), PY2(*), PY3(*), PY4(*),
     .   PZ1(*), PZ2(*), PZ3(*), PZ4(*), 
     .   DXX(*), DXY(*), DXZ(*),
     .   DYX(*), DYY(*), DYZ(*),
     .   DZX(*), DZY(*), DZZ(*), D4(*), D5(*), D6(*),
     .   WXX(*), WYY(*), WZZ(*),
C   +++
     .   PX1H(*), PX2H(*), PX3H(*), 
     .   PY1H(*), PY2H(*), PY3H(*), 
     .   PZ1H(*), PZ2H(*), PZ3H(*), 
     .   JI33(*),B1X(MVSIZ,2),B1Y(MVSIZ,2),B2X(MVSIZ,2),B2Y(MVSIZ,2),
     .   B1XH(MVSIZ,2),B1YH(MVSIZ,2),B2XH(MVSIZ,2),B2YH(MVSIZ,2),
     .   B1122(*),B1221(*),B2212(*),B1121(*),
     .   B1122H(*),B1221H(*),B2212H(*),B1121H(*),
     .   DHXX(*), DHXY(*), DHXZ(*),  
     .   dhyx(*), dhyy(*), dhyz(*), 
     .   dhzx(*), dhzy(*), dhzz(*),dh4(*), dh5(*), dh6(*),
     .   ddhv(*),nu(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER  I, J
C     REAL
      my_real
     .   VX14(MVSIZ), VY14(MVSIZ), VZ14(MVSIZ),
     .   VX25(MVSIZ), VY25(MVSIZ), VZ25(MVSIZ),
     .   VX36(MVSIZ), VY36(MVSIZ), VZ36(MVSIZ),
     .   VX14N(MVSIZ), VY14N(MVSIZ), VZ14N(MVSIZ),
     .   VX25N(MVSIZ), VY25N(MVSIZ), VZ25N(MVSIZ),
     .   VX36N(MVSIZ), VY36N(MVSIZ), VZ36N(MVSIZ),
     .   VX3614N(MVSIZ),VY3614N(MVSIZ),VX2514N(MVSIZ),VY2514N(MVSIZ),
     .   VXHI(MVSIZ), VYHI(MVSIZ), VZHI(MVSIZ), DT1D2, DT1D1
      my_real 
     .  NU1,PXSVX,PYSVY,PZSVZ,PXAVX,PYAVY,PZAVZ,TERMAD
C-----------------------------------------------
      DO I=1,nel
       vx14(i)=vx1(i)+vx4(i)
       vx25(i)=vx2(i)+vx5(i)
       vx36(i)=vx3(i)+vx6(i)
       vxhi(i)=vx4(i)+vx5(i)+vx6(i)-vx1(i)-vx2(i)-vx3(i)
       vy14(i)=vy1(i)+vy4(i)
       vy25(i)=vy2(i)+vy5(i)
       vy36(i)=vy3(i)+vy6(i)
       vyhi(i)=vy4(i)+vy5(i)+vy6(i)-vy1(i)-vy2(i)-vy3(i)
       vz14(i)=vz1(i)+vz4(i)
       vz25(i)=vz2(i)+vz5(i)
       vz36(i)=vz3(i)+vz6(i)
       vzhi(i)=vz4(i)+vz5(i)+vz6(i)-vz1(i)-vz2(i)-vz3(i)
      ENDDO
      DO i=1,nel
       vx14n(i)=-vx1(i)+vx4(i)
       vx25n(i)=-vx2(i)+vx5(i)
       vx36n(i)=-vx3(i)+vx6(i)
       vy14n(i)=-vy1(i)+vy4(i)
       vy25n(i)=-vy2(i)+vy5(i)
       vy36n(i)=-vy3(i)+vy6(i)
       vz14n(i)=-vz1(i)+vz4(i)
       vz25n(i)=-vz2(i)+vz5(i)
       vz36n(i)=-vz3(i)+vz6(i)
C
       vx3614n(i)=vx36n(i)-vx14n(i)
       vy3614n(i)=vy36n(i)-vy14n(i)
       vx2514n(i)=vx25n(i)-vx14n(i)
       vy2514n(i)=vy25n(i)-vy14n(i)
      ENDDO
C                                                                     12
C   ----------constant part--------------------------------------
      DO i=1,nel
        dxx(i)=px1(i)*vx14(i)+px2(i)*vx25(i)+
     .         px3(i)*vx36(i)+px4(i)*vxhi(i)
        dyy(i)=py1(i)*vy14(i)+py2(i)*vy25(i)+
     .         py3(i)*vy36(i)+py4(i)*vyhi(i)
        dzz(i)=pz1(i)*vz14(i)+pz2(i)*vz25(i)+
     .         pz3(i)*vz36(i)+pz4(i)*vzhi(i)
        dxy(i)=py1(i)*vx14(i)+py2(i)*vx25(i)+
     .         py3(i)*vx36(i)+py4(i)*vxhi(i)
        dyx(i)=px1(i)*vy14(i)+px2(i)*vy25(i)+
     .         px3(i)*vy36(i)+px4(i)*vyhi(i)
C   --------shear traitement-------
        dxz(i)=ji33(i)*two*vxhi(i)
     .         -b1122(i)*vx36n(i)+b1221(i)*vx25n(i)
     .         +b2212(i)*(vy25n(i)-vy36n(i))  
        dxz(i)= dxz(i)+ji33(i)*(vxhi(i)-vx14n(i))
     .         -b1x(i,1)*vx3614n(i)+b1x(i,2)*vx2514n(i)  
     .         -b1y(i,1)*vy3614n(i)+b1y(i,2)*vy2514n(i)  
        dyz(i)=ji33(i)*two*vyhi(i)
     .         -b1122(i)*vy25n(i)+b1221(i)*vy36n(i)
     .         +b1121(i)*(vx36n(i)-vx25n(i))  
        dyz(i)= dyz(i)+ ji33(i)*(vyhi(i)-vy14n(i))
     .         +b2x(i,1)*vx3614n(i)-b2x(i,2)*vx2514n(i)
     .         +b2y(i,1)*vy3614n(i)-b2y(i,2)*vy2514n(i)  
C
        dzx(i)=half*(px1(i)*vz14(i)+px2(i)*vz25(i)+
     .         px3(i)*vz36(i))
        dzy(i)=half*(py1(i)*vz14(i)+py2(i)*vz25(i)+
     .         py3(i)*vz36(i))
      ENDDO
C
      DO i=1,nel
        wxx(i)=zero
        wyy(i)=zero
        wzz(i)=zero
      ENDDO
C   ----------non-constant part--------------------------------------
      DO i=1,nel
        nu1 = nu(i)/(one - nu(i))
        pxavx = px1(i)*vx14n(i)+px2(i)*vx25n(i)+px3(i)*vx36n(i)
        pyavy = py1(i)*vy14n(i)+py2(i)*vy25n(i)+py3(i)*vy36n(i)
        pzavz = pz1(i)*vz14n(i)+pz2(i)*vz25n(i)+pz3(i)*vz36n(i)
        pxsvx = px1h(i)*vx14(i)+px2h(i)*vx25(i)+px3h(i)*vx36(i)
        pysvy = py1h(i)*vy14(i)+py2h(i)*vy25(i)+py3h(i)*vy36(i)
        pzsvz = pz1h(i)*vz14(i)+pz2h(i)*vz25(i)+pz3h(i)*vz36(i)
        termad=-nu(i)*pyavy-nu1*pzavz
        ddhv(i)= termad
        dhxx(i)= pxsvx+pxavx+termad
        termad=-nu(i)*pxsvx-nu1*pzsvz
        ddhv(i)= ddhv(i)+termad
        dhyy(i)= pysvy+pyavy+termad
        termad=-nu(i)*(pxsvx+pyavy)-nu1*(pxavx+pysvy)
        ddhv(i)= ddhv(i)+termad
        dhzz(i)= pzsvz+pzavz+termad
        dhxy(i)=py1(i)*vx14n(i)+py2(i)*vx25n(i)+
     .          py3(i)*vx36n(i)+
     .          py1h(i)*vx14(i)+py2h(i)*vx25(i)+
     .          py3h(i)*vx36(i)
        dhyx(i)=px1(i)*vy14n(i)+px2(i)*vy25n(i)+
     .          px3(i)*vy36n(i)+
     .          px1h(i)*vy14(i)+px2h(i)*vy25(i)+
     .          px3h(i)*vy36(i)
C   --------shear traitement-------
        dhxz(i)=-b1122h(i)*vx36n(i)+b1221h(i)*vx25n(i)
     .          +b2212h(i)*(vy25n(i)-vy36n(i))  
        dhxz(i)= dhxz(i)
     .         -b1xh(i,1)*vx3614n(i)+b1xh(i,2)*vx2514n(i)  
     .         -b1yh(i,1)*vy3614n(i)+b1yh(i,2)*vy2514n(i)  
        dhyz(i)=-b1122h(i)*vy25n(i)+b1221h(i)*vy36n(i)
     .          +b1121h(i)*(vx36n(i)-vx25n(i))  
        dhyz(i)= dhyz(i) 
     .         +b2xh(i,1)*vx3614n(i)-b2xh(i,2)*vx2514n(i)
     .         +b2yh(i,1)*vy3614n(i)-b2yh(i,2)*vy2514n(i)  
        dhzx(i)=half*(px1h(i)*vz14(i)+px2h(i)*vz25(i)+
     .          px3h(i)*vz36(i))
        dhzy(i)=half*(py1h(i)*vz14(i)+py2h(i)*vz25(i)+
     .          py3h(i)*vz36(i))
      ENDDO
C
      RETURN
      END