s6ctherm.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    s6ctherm   ../engine/source/elements/thickshell/solide6c/s6ctherm.f
!||--- called by ------------------------------------------------------
!||    s6cforc3   ../engine/source/elements/thickshell/solide6c/s6cforc3.F
!||====================================================================
      SUBROUTINE s6ctherm(
     1   PM       ,IMAT     ,VOL      ,NC1      ,
     2   NC2      ,NC3      ,NC4      ,NC5      ,
     3   NC6      ,PX1      ,PX2      ,PX3      ,
     4   PX4      ,PY1      ,PY2      ,PY3      ,
     5   PY4      ,PZ1      ,PZ2      ,PZ3      ,
     6   PZ4      ,DT1      ,TEMPNC   ,TEL      ,
     7   HEAT     ,FPHI     ,OFFG     ,OFF      ,
     8   NEL      ,THEACCFACT)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
#include      "param_c.inc"
#include      "com04_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      INTEGER, INTENT(IN) :: IMAT
      INTEGER, INTENT(IN) :: NC1(MVSIZ),NC2(MVSIZ),
     .   NC3(MVSIZ),NC4(MVSIZ),NC5(MVSIZ),NC6(MVSIZ)
      my_real, INTENT(IN) :: THEACCFACT
      my_real, INTENT(IN) :: DT1
      my_real, INTENT(IN) :: VOL(MVSIZ), PX1(MVSIZ), PY1(MVSIZ),PZ1(MVSIZ),
     .   PX2(MVSIZ), PY2(MVSIZ), PZ2(MVSIZ),
     .   px3(mvsiz), py3(mvsiz),pz3(mvsiz),
     .   px4(mvsiz), py4(mvsiz),pz4(mvsiz),
     .   tempnc(numnod), pm(npropm,nummat),
     .   heat(mvsiz), tel(mvsiz),off(mvsiz),offg(mvsiz)
      my_real, INTENT(INOUT) :: fphi(mvsiz,6)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
C     REAL
      my_real
     .  CA, CB, KC, PHIX, PHIY, PHIZ, A
C----------------------------------------------- 
      ca = pm(75,imat)
      cb = pm(76,imat)
!
      DO i=1,nel
        IF (off(i)/=zero .AND. offg(i)>zero) THEN 
c          
          ! Flux initialization 
          phix = zero
          phiy = zero
          phiz = zero
c
          ! Computing flux
          phix =  tempnc(nc1(i))*(px1(i)-px4(i)) + tempnc(nc2(i))*(px2(i)-px4(i)) +
     .            tempnc(nc3(i))*(px3(i)-px4(i)) + tempnc(nc4(i))*(px1(i)+px4(i)) +
     .            tempnc(nc5(i))*(px2(i)+px4(i)) + tempnc(nc6(i))*(px3(i)+px4(i))   
          
          phiy =  tempnc(nc1(i))*(py1(i)-py4(i)) + tempnc(nc2(i))*(py2(i)-py4(i)) +
     .            tempnc(nc3(i))*(py3(i)-py4(i)) + tempnc(nc4(i))*(py1(i)+py4(i)) +
     .            tempnc(nc5(i))*(py2(i)+py4(i)) + tempnc(nc6(i))*(py3(i)+py4(i)) 
      
          phiz =  tempnc(nc1(i))*(pz1(i)-pz4(i)) + tempnc(nc2(i))*(pz2(i)-pz4(i)) +
     .            tempnc(nc3(i))*(pz3(i)-pz4(i)) + tempnc(nc4(i))*(pz1(i)+pz4(i)) +
     .            tempnc(nc5(i))*(pz2(i)+pz4(i)) + tempnc(nc6(i))*(pz3(i)+pz4(i)) 
c
          kc = (ca + cb*tel(i))*dt1*vol(i)*theaccfact           
          phix = kc*phix
          phiy = kc*phiy
          phiz = kc*phiz 
c
          ! Computing nodal thermic forces
          a = heat(i)*one_over_6
          fphi(i,1) = fphi(i,1) +
     .        a - (phix*(px1(i)-px4(i)) + phiy*(py1(i)-py4(i)) + phiz*(pz1(i)-pz4(i)))
          fphi(i,2) = fphi(i,2) +
     .        a - (phix*(px2(i)-px4(i)) + phiy*(py2(i)-py4(i)) + phiz*(pz2(i)-pz4(i)))
          fphi(i,3) = fphi(i,3) +
     .        a - (phix*(px3(i)-px4(i)) + phiy*(py3(i)-py4(i)) + phiz*(pz3(i)-pz4(i)))
          fphi(i,4) = fphi(i,4) +
     .        a - (phix*(px1(i)+px4(i)) + phiy*(py1(i)+py4(i)) + phiz*(pz1(i)+pz4(i)))
          fphi(i,5) = fphi(i,5) +
     .        a - (phix*(px2(i)+px4(i)) + phiy*(py2(i)+py4(i)) + phiz*(pz2(i)+pz4(i)))
          fphi(i,6) = fphi(i,6) +
     .        a - (phix*(px3(i)+px4(i)) + phiy*(py3(i)+py4(i)) + phiz*(pz3(i)+pz4(i)))
        ENDIF
      ENDDO
C 
      END