s8zdefo3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    s8zdefo3   ../engine/source/elements/solid/solide8z/s8zdefo3.F
!||--- called by ------------------------------------------------------
!||    s8zforc3   ../engine/source/elements/solid/solide8z/s8zforc3.F
!||====================================================================
      SUBROUTINE s8zdefo3(
     1   PXC1,    PXC2,    PXC3,    PXC4,
     2   PYC1,    PYC2,    PYC3,    PYC4,
     3   PZC1,    PZC2,    PZC3,    PZC4,
     4   PX1,     PX2,     PX3,     PX4,
     5   PX5,     PX6,     PX7,     PX8,
     6   PY1,     PY2,     PY3,     PY4,
     7   PY5,     PY6,     PY7,     PY8,
     8   PZ1,     PZ2,     PZ3,     PZ4,
     9   PZ5,     PZ6,     PZ7,     PZ8,
     A   PXY1,    PXY2,    PXY3,    PXY4,
     B   PXY5,    PXY6,    PXY7,    PXY8,
     C   PYX1,    PYX2,    PYX3,    PYX4,
     D   PYX5,    PYX6,    PYX7,    PYX8,
     E   PXZ1,    PXZ2,    PXZ3,    PXZ4,
     F   PXZ5,    PXZ6,    PXZ7,    PXZ8,
     G   PZX1,    PZX2,    PZX3,    PZX4,
     H   PZX5,    PZX6,    PZX7,    PZX8,
     I   PYZ1,    PYZ2,    PYZ3,    PYZ4,
     J   PYZ5,    PYZ6,    PYZ7,    PYZ8,
     K   PZY1,    PZY2,    PZY3,    PZY4,
     L   PZY5,    PZY6,    PZY7,    PZY8,
     M   BXY1,    BXY2,    BXY3,    BXY4,
     N   BXY5,    BXY6,    BXY7,    BXY8,
     O   BYX1,    BYX2,    BYX3,    BYX4,
     P   BYX5,    BYX6,    BYX7,    BYX8,
     Q   BXZ1,    BXZ2,    BXZ3,    BXZ4,
     R   BXZ5,    BXZ6,    BXZ7,    BXZ8,
     S   BZX1,    BZX2,    BZX3,    BZX4,
     T   BZX5,    BZX6,    BZX7,    BZX8,
     U   BYZ1,    BYZ2,    BYZ3,    BYZ4,
     V   BYZ5,    BYZ6,    BYZ7,    BYZ8,
     W   BZY1,    BZY2,    BZY3,    BZY4,
     X   BZY5,    BZY6,    BZY7,    BZY8,
     Y   VX1,     VX2,     VX3,     VX4,
     Z   VX5,     VX6,     VX7,     VX8,
     1   VY1,     VY2,     VY3,     VY4,
     2   VY5,     VY6,     VY7,     VY8,
     3   VZ1,     VZ2,     VZ3,     VZ4,
     4   VZ5,     VZ6,     VZ7,     VZ8,
     5   DXX,     DXY,     DXZ,     DYX,
     6   DYY,     DYZ,     DZX,     DZY,
     7   DZZ,     D4,      D5,      D6,
     8   WXX,     WYY,     WZZ,     VOLO,
     9   OFF,     EINT,    OFFS,    DSV,
     A   ICP,     ICR,     ICS,     ICT,
     B   DTI,     DSR,     DSS,     DST,
     C   NGL,     IDEG,    VOL0DP,  NEL,
     D   ISMSTR,  JCVT)
C                                                                     12
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
#include      "comlock.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com08_c.inc"
#include      "impl1_c.inc"
#include      "scr05_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      INTEGER, INTENT(IN) :: ISMSTR
      INTEGER, INTENT(IN) :: JCVT
      INTEGER ICP,ICR,ICS,ICT,NGL(*),IDEG(*)
C     REAL
      my_real
     .   VX1(*), VX2(*), VX3(*), VX4(*), VX5(*), VX6(*), VX7(*), VX8(*),
     .   VY1(*), VY2(*), VY3(*), VY4(*), VY5(*), VY6(*), VY7(*), VY8(*),
     .   VZ1(*), VZ2(*), VZ3(*), VZ4(*), VZ5(*), VZ6(*), VZ7(*), VZ8(*),
     .   PXC1(*), PXC2(*), PXC3(*), PXC4(*),  
     .   PYC1(*), PYC2(*), PYC3(*), PYC4(*),  
     .   PZC1(*), PZC2(*), PZC3(*), PZC4(*),  
     .   PX1(*), PX2(*), PX3(*), PX4(*),
     .   PX5(*), PX6(*), PX7(*), PX8(*),
     .   PY1(*), PY2(*), PY3(*), PY4(*),
     .   PY5(*), PY6(*), PY7(*), PY8(*),
     .   PZ1(*), PZ2(*), PZ3(*), PZ4(*), 
     .   PZ5(*), PZ6(*), PZ7(*), PZ8(*),
     .   PXY1(*),PXY2(*),PXY3(*),PXY4(*),
     .   PXY5(*),PXY6(*),PXY7(*),PXY8(*),
     .   PYX1(*),PYX2(*),PYX3(*),PYX4(*),
     .   PYX5(*),PYX6(*),PYX7(*),PYX8(*),
     .   PXZ1(*),PXZ2(*),PXZ3(*),PXZ4(*),
     .   PXZ5(*),PXZ6(*),PXZ7(*),PXZ8(*),
     .   PZX1(*),PZX2(*),PZX3(*),PZX4(*),
     .   PZX5(*),PZX6(*),PZX7(*),PZX8(*),
     .   PYZ1(*),PYZ2(*),PYZ3(*),PYZ4(*),
     .   PYZ5(*),PYZ6(*),PYZ7(*),PYZ8(*),
     .   PZY1(*),PZY2(*),PZY3(*),PZY4(*),
     .   PZY5(*),PZY6(*),PZY7(*),PZY8(*),
     .   BXY1(*),BXY2(*),BXY3(*),BXY4(*),
     .   BXY5(*),BXY6(*),BXY7(*),BXY8(*),
     .   BYX1(*),BYX2(*),BYX3(*),BYX4(*),
     .   BYX5(*),BYX6(*),BYX7(*),BYX8(*),
     .   BXZ1(*),BXZ2(*),BXZ3(*),BXZ4(*),
     .   BXZ5(*),BXZ6(*),BXZ7(*),BXZ8(*),
     .   BZX1(*),BZX2(*),BZX3(*),BZX4(*),
     .   BZX5(*),BZX6(*),BZX7(*),BZX8(*),
     .   BYZ1(*),BYZ2(*),BYZ3(*),BYZ4(*),
     .   BYZ5(*),BYZ6(*),BYZ7(*),BYZ8(*),
     .   BZY1(*),BZY2(*),BZY3(*),BZY4(*),
     .   BZY5(*),BZY6(*),BZY7(*),BZY8(*),
     .   DXX(*), DXY(*), DXZ(*),
     .   DYX(*), DYY(*), DYZ(*),
     .   DZX(*), DZY(*), DZZ(*), D4(*), D5(*), D6(*),
     .   WXX(*), WYY(*), WZZ(*), OFFS(*),DSV(*),
     .   VOLO(*),OFF(*),EINT(*),DSR(*),DSS(*),DST(*),DTI
      DOUBLE PRECISION 
     .   vol0dp(mvsiz)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, ICOR
C     REAL
      my_real
     .   dvc(mvsiz),dvca(mvsiz),dt1d2,tol,dt1d
      DOUBLE PRECISION 
     .   DVP,DV,DV1
C                                                                     12
C-----------------------------------------------
       TOL = one-em20
       dxx(1:nel) =px1(1:nel)*vx1(1:nel)+px2(1:nel)*vx2(1:nel)+px3(1:nel)*vx3(1:nel)+px4(1:nel)*vx4(1:nel)
     .        +px5(1:nel)*vx5(1:nel)+px6(1:nel)*vx6(1:nel)+px7(1:nel)*vx7(1:nel)+px8(1:nel)*vx8(1:nel)
       dyy(1:nel) =py1(1:nel)*vy1(1:nel)+py2(1:nel)*vy2(1:nel)+py3(1:nel)*vy3(1:nel)+py4(1:nel)*vy4(1:nel)
     .        +py5(1:nel)*vy5(1:nel)+py6(1:nel)*vy6(1:nel)+py7(1:nel)*vy7(1:nel)+py8(1:nel)*vy8(1:nel)
       dzz(1:nel) =pz1(1:nel)*vz1(1:nel)+pz2(1:nel)*vz2(1:nel)+pz3(1:nel)*vz3(1:nel)+pz4(1:nel)*vz4(1:nel)
     .        +pz5(1:nel)*vz5(1:nel)+pz6(1:nel)*vz6(1:nel)+pz7(1:nel)*vz7(1:nel)+pz8(1:nel)*vz8(1:nel)
       dxy(1:nel) =pxy1(1:nel)*vx1(1:nel)+pxy2(1:nel)*vx2(1:nel)
     +        +pxy3(1:nel)*vx3(1:nel)+pxy4(1:nel)*vx4(1:nel)
     +        +pxy5(1:nel)*vx5(1:nel)+pxy6(1:nel)*vx6(1:nel)
     +        +pxy7(1:nel)*vx7(1:nel)+pxy8(1:nel)*vx8(1:nel)
       dxz(1:nel) =pxz1(1:nel)*vx1(1:nel)+pxz2(1:nel)*vx2(1:nel)
     +        +pxz3(1:nel)*vx3(1:nel)+pxz4(1:nel)*vx4(1:nel)
     +        +pxz5(1:nel)*vx5(1:nel)+pxz6(1:nel)*vx6(1:nel)
     +        +pxz7(1:nel)*vx7(1:nel)+pxz8(1:nel)*vx8(1:nel)
       dyx(1:nel) =pyx1(1:nel)*vy1(1:nel)+pyx2(1:nel)*vy2(1:nel)
     +        +pyx3(1:nel)*vy3(1:nel)+pyx4(1:nel)*vy4(1:nel)
     +        +pyx5(1:nel)*vy5(1:nel)+pyx6(1:nel)*vy6(1:nel)
     +        +pyx7(1:nel)*vy7(1:nel)+pyx8(1:nel)*vy8(1:nel)
       dyz(1:nel) =pyz1(1:nel)*vy1(1:nel)+pyz2(1:nel)*vy2(1:nel)
     +        +pyz3(1:nel)*vy3(1:nel)+pyz4(1:nel)*vy4(1:nel)
     +        +pyz5(1:nel)*vy5(1:nel)+pyz6(1:nel)*vy6(1:nel)
     +        +pyz7(1:nel)*vy7(1:nel)+pyz8(1:nel)*vy8(1:nel)
       dzx(1:nel) =pzx1(1:nel)*vz1(1:nel)+pzx2(1:nel)*vz2(1:nel)
     +        +pzx3(1:nel)*vz3(1:nel)+pzx4(1:nel)*vz4(1:nel)
     +        +pzx5(1:nel)*vz5(1:nel)+pzx6(1:nel)*vz6(1:nel)
     +        +pzx7(1:nel)*vz7(1:nel)+pzx8(1:nel)*vz8(1:nel)
       dzy(1:nel) =pzy1(1:nel)*vz1(1:nel)+pzy2(1:nel)*vz2(1:nel)
     +        +pzy3(1:nel)*vz3(1:nel)+pzy4(1:nel)*vz4(1:nel)
     +        +pzy5(1:nel)*vz5(1:nel)+pzy6(1:nel)*vz6(1:nel)
     +        +pzy7(1:nel)*vz7(1:nel)+pzy8(1:nel)*vz8(1:nel)
        dvc(1:nel) =(dxx(1:nel)+dyy(1:nel)+dzz(1:nel))*dt1
C  
      IF (icp ==1) THEN
        dvca(1:nel)=pxc1(1:nel)*(vx1(1:nel)-vx7(1:nel))+pxc2(1:nel)*(vx2(1:nel)-vx8(1:nel))
     .        +pxc3(1:nel)*(vx3(1:nel)-vx5(1:nel))+pxc4(1:nel)*(vx4(1:nel)-vx6(1:nel))
     .        +pyc1(1:nel)*(vy1(1:nel)-vy7(1:nel))+pyc2(1:nel)*(vy2(1:nel)-vy8(1:nel))
     .        +pyc3(1:nel)*(vy3(1:nel)-vy5(1:nel))+pyc4(1:nel)*(vy4(1:nel)-vy6(1:nel))
     .        +pzc1(1:nel)*(vz1(1:nel)-vz7(1:nel))+pzc2(1:nel)*(vz2(1:nel)-vz8(1:nel))
     .        +pzc3(1:nel)*(vz3(1:nel)-vz5(1:nel))+pzc4(1:nel)*(vz4(1:nel)-vz6(1:nel))
        dvca(1:nel)=dvca(1:nel)*dt1
      ELSE
        dyy(1:nel) =dyy(1:nel)+bxy1(1:nel)*vx1(1:nel)+bxy2(1:nel)*vx2(1:nel)
     +        +bxy3(1:nel)*vx3(1:nel)+bxy4(1:nel)*vx4(1:nel)
     +        +bxy5(1:nel)*vx5(1:nel)+bxy6(1:nel)*vx6(1:nel)
     +        +bxy7(1:nel)*vx7(1:nel)+bxy8(1:nel)*vx8(1:nel)
        dzz(1:nel) =dzz(1:nel)+bxz1(1:nel)*vx1(1:nel)+bxz2(1:nel)*vx2(1:nel)
     +        +bxz3(1:nel)*vx3(1:nel)+bxz4(1:nel)*vx4(1:nel)
     +        +bxz5(1:nel)*vx5(1:nel)+bxz6(1:nel)*vx6(1:nel)
     +        +bxz7(1:nel)*vx7(1:nel)+bxz8(1:nel)*vx8(1:nel)
        dxx(1:nel) =dxx(1:nel)+byx1(1:nel)*vy1(1:nel)+byx2(1:nel)*vy2(1:nel)
     +        +byx3(1:nel)*vy3(1:nel)+byx4(1:nel)*vy4(1:nel)
     +        +byx5(1:nel)*vy5(1:nel)+byx6(1:nel)*vy6(1:nel)
     +        +byx7(1:nel)*vy7(1:nel)+byx8(1:nel)*vy8(1:nel)
        dzz(1:nel) =dzz(1:nel)+byz1(1:nel)*vy1(1:nel)+byz2(1:nel)*vy2(1:nel)
     +        +byz3(1:nel)*vy3(1:nel)+byz4(1:nel)*vy4(1:nel)
     +        +byz5(1:nel)*vy5(1:nel)+byz6(1:nel)*vy6(1:nel)
     +        +byz7(1:nel)*vy7(1:nel)+byz8(1:nel)*vy8(1:nel)
        dxx(1:nel) =dxx(1:nel)+bzx1(1:nel)*vz1(1:nel)+bzx2(1:nel)*vz2(1:nel)
     +        +bzx3(1:nel)*vz3(1:nel)+bzx4(1:nel)*vz4(1:nel)
     +        +bzx5(1:nel)*vz5(1:nel)+bzx6(1:nel)*vz6(1:nel)
     +        +bzx7(1:nel)*vz7(1:nel)+bzx8(1:nel)*vz8(1:nel)
        dyy(1:nel) =dyy(1:nel)+bzy1(1:nel)*vz1(1:nel)+bzy2(1:nel)*vz2(1:nel)
     +        +bzy3(1:nel)*vz3(1:nel)+bzy4(1:nel)*vz4(1:nel)
     +        +bzy5(1:nel)*vz5(1:nel)+bzy6(1:nel)*vz6(1:nel)
     +        +bzy7(1:nel)*vz7(1:nel)+bzy8(1:nel)*vz8(1:nel)
        dvca(1:nel) =(dxx(1:nel)+dyy(1:nel)+dzz(1:nel))*dt1
      ENDIF
C-------------Constant stress traitement------
C-------------R--direction------
      IF (icr==1) THEN
       DO i=1,nel
        dxx(i)= dxx(i)-dsr(i)*dti
        IF(ismdisp==0.AND.offs(i)/=two)dvca(i)= dvca(i)-dsr(i)
       ENDDO
      ENDIF 
C--------------S--direction--
      IF (ics==1) THEN
       DO i=1,nel
        dyy(i)= dyy(i)-dss(i)*dti
        IF(ismdisp==0.AND.offs(i)/=two)dvca(i)= dvca(i)-dss(i)
       ENDDO
      ENDIF 
C--------------T--direction
      IF (ict==1) THEN
       DO i=1,nel
        dzz(i)= dzz(i)-dst(i)*dti
        IF(ismdisp==0.AND.offs(i)/=two)dvca(i)= dvca(i)-dst(i)
       ENDDO
      ENDIF 
C-------------Volume traitement------
      DO i=1,nel
        dvp=dvca(i)-dvc(i)
        dv =dvp*off(i)
        IF(ideg(i)>10) dv = zero
        dsv(i) = dv
      ENDDO
      IF (ismdisp>0.AND.(icr+ics+ict)==0.AND.icp/=1) THEN
       DO i=1,nel
        dsv(i) = zero
       ENDDO
      ELSEIF (ismstr==10.AND.icp==1) THEN
       DO i=1,nel
        dsv(i) = zero
       ENDDO
      ELSEIF (ismstr==12.AND.icp==1) THEN
       DO i=1,nel
        IF(offs(i)<=one) dsv(i) = zero
       ENDDO
      ELSEIF ((icr+ics+ict)>0 ) THEN
       DO i=1,nel
        IF(offs(i)==two.OR.ismstr==11) THEN
         IF (icp==1) THEN
          dsv(i) =dvca(i)-(dxx(i)+dyy(i)+dzz(i))*dt1
         ELSE
          dsv(i) = zero
         END IF
        END IF
       ENDDO
      END IF 
      DO i=1,nel
        IF(offs(i)==two.OR.ismstr==11) cycle
        dv=dsv(i)
        IF (abs(dv)>tol.AND.off(i)/=zero) THEN
          dv =zero
C----generally element will be switched to smstr     
C          OFF(I)=ZERO
C         IF (IMCONV==1) THEN
C#include "lockon.inc"
C          WRITE(ISTDO,2000) NGL(I)
C          WRITE(IOUT ,2000) NGL(I)
C#include "lockoff.inc"
C          IDEL7NOK = 1
C         ENDIF 
        ELSEIF(abs(dv)>tol)THEN
          dv =zero
        ENDIF
        IF(ismdisp==0) THEN
         dv1 = one-dv
         volo(i) = volo(i)*dv1
         IF (iresp==1) vol0dp(i) = vol0dp(i)*dv1
         eint(i) = eint(i)/dv1
        ENDIF
      ENDDO
C
      dt1d2=half*dt1
      IF (iscau>0 )dt1d2=dt1
      dt1d=two*dt1d2
      IF (jcvt/=0) THEN
       IF (ismdisp>0.AND.iscau==0) THEN
         d4(1:nel)   = dxy(1:nel)+dyx(1:nel)
         d5(1:nel)   = dyz(1:nel)+dzy(1:nel)
         d6(1:nel)   = dxz(1:nel)+dzx(1:nel)
         wxx(1:nel)=zero
         wyy(1:nel)=zero
         wzz(1:nel)=zero
       ELSE
        d4(1:nel)   = dxy(1:nel)+dyx(1:nel)
     .           -dt1d*(dxx(1:nel)*dxy(1:nel)+dyx(1:nel)*dyy(1:nel)+dzx(1:nel)*dzy(1:nel))
        d5(1:nel)   = dyz(1:nel)+dzy(1:nel)
     .           -dt1d*(dyy(1:nel)*dyz(1:nel)+dzy(1:nel)*dzz(1:nel)+dxy(1:nel)*dxz(1:nel))
        d6(1:nel)   = dxz(1:nel)+dzx(1:nel)
     .           -dt1d*(dzz(1:nel)*dzx(1:nel)+dxz(1:nel)*dxx(1:nel)+dyz(1:nel)*dyx(1:nel))
        dxx(1:nel)  = dxx(1:nel)
     .           -dt1d2*(dxx(1:nel)*dxx(1:nel)+dyx(1:nel)*dyx(1:nel)+dzx(1:nel)*dzx(1:nel))
        dyy(1:nel)  = dyy(1:nel)
     .           -dt1d2*(dyy(1:nel)*dyy(1:nel)+dzy(1:nel)*dzy(1:nel)+dxy(1:nel)*dxy(1:nel))
        dzz(1:nel)  = dzz(1:nel)
     .           -dt1d2*(dzz(1:nel)*dzz(1:nel)+dxz(1:nel)*dxz(1:nel)+dyz(1:nel)*dyz(1:nel))
        wxx(1:nel)=zero
        wyy(1:nel)=zero
        wzz(1:nel)=zero
       ENDIF 
      ELSE
        d4(1:nel)=dxy(1:nel)+dyx(1:nel)
        d5(1:nel)=dyz(1:nel)+dzy(1:nel)
        d6(1:nel)=dxz(1:nel)+dzx(1:nel)
        wzz(1:nel)=dt1d2*(dyx(1:nel)-dxy(1:nel))
        wyy(1:nel)=dt1d2*(dxz(1:nel)-dzx(1:nel))
        wxx(1:nel)=dt1d2*(dzy(1:nel)-dyz(1:nel))
      ENDIF
C
 2000 FORMAT(/' ZERO OR NEGATIVE SUB-VOLUME : DELETE 3D-ELEMENT NB',
     .          i8/)
      RETURN
      END