scdefc3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    scdefc3   ../engine/source/elements/thickshell/solidec/scdefc3.F
!||--- called by ------------------------------------------------------
!||    scforc3   ../engine/source/elements/thickshell/solidec/scforc3.F
!||====================================================================
      SUBROUTINE scdefc3(
     1   PX1,     PX2,     PX3,     PX4,
     2   PY1,     PY2,     PY3,     PY4,
     3   PZ1,     PZ2,     PZ3,     PZ4,
     4   VX1,     VX2,     VX3,     VX4,
     5   VX5,     VX6,     VX7,     VX8,
     6   VY1,     VY2,     VY3,     VY4,
     7   VY5,     VY6,     VY7,     VY8,
     8   VZ1,     VZ2,     VZ3,     VZ4,
     9   VZ5,     VZ6,     VZ7,     VZ8,
     A   DXX,     DXY,     DXZ,     DYX,
     B   DYY,     DYZ,     DZX,     DZY,
     C   DZZ,     D4,      D5,      D6,
     D   WXX,     WYY,     WZZ,     DHXX,
     E   DHXY,    DHYX,    DHYY,    DHZX,
     F   DHZY,    DHZZ,    DH4,     DH5,
     G   DH6,     PX1H1,   PX1H2,   PX2H1,
     H   PX2H2,   PX3H1,   PX3H2,   PX4H1,
     I   PX4H2,   HGX1,    HGY2,    HGZ1,
     J   HGZ2,    RX0,     RY0,     SX0,
     K   SY0,     NU,      DDHV,    NEL)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
C     REAL
      my_real
     .   VX1(*), VX2(*), VX3(*), VX4(*), VX5(*), VX6(*), VX7(*), VX8(*),
     .   VY1(*), VY2(*), VY3(*), VY4(*), VY5(*), VY6(*), VY7(*), VY8(*),
     .   VZ1(*), VZ2(*), VZ3(*), VZ4(*), VZ5(*), VZ6(*), VZ7(*), VZ8(*),
     .   PX1(*), PX2(*), PX3(*), PX4(*),
     .   PY1(*), PY2(*), PY3(*), PY4(*),
     .   PZ1(*), PZ2(*), PZ3(*), PZ4(*), 
     .   DXX(*), DXY(*), DXZ(*),
     .   DYX(*), DYY(*), DYZ(*),
     .   DZX(*), DZY(*), DZZ(*), D4(*), D5(*), D6(*),
     .   WXX(*), WYY(*), WZZ(*), 
     .   DHXX(*), DHXY(*), 
     .   DHYX(*), DHYY(*), 
     .   DHZX(*), DHZY(*), DHZZ(*),DH4(*), DH5(*), DH6(*),
     .   PX1H1(*), PX1H2(*) , PX2H1(*), PX2H2(*), 
     .   PX3H1(*), PX3H2(*) , PX4H1(*), PX4H2(*), 
     .   HGX1(*),  HGY2(*)  , HGZ1(*), HGZ2(*),
     .   RX0(*), RY0(*), SX0(*), SY0(*),NU(*),DDHV(*) 
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER  I, J
C     REAL
      my_real
     .   VX17(MVSIZ), VY17(MVSIZ), VZ17(MVSIZ),
     .   VX28(MVSIZ), VY28(MVSIZ), VZ28(MVSIZ),
     .   VX35(MVSIZ), VY35(MVSIZ), VZ35(MVSIZ),
     .   VX46(MVSIZ), VY46(MVSIZ), VZ46(MVSIZ), DT1D2,DT1D1
      my_real 
     .   PXX2,PYY2,PZZ2,PXX2P,PYY2P,PZZ2P,
     .   HGY1(MVSIZ), HGX2(MVSIZ),
     .   H1VX,H1VY,H1VZ,H2VX,H2VY,H2VZ,NU1,
     .   X1VX,X2VX,Y1VY,Y2VY,Y2VY_NU,X1VX_NU
C=======================================================================
      DO I=1,nel
       vx17(i)=vx1(i)-vx7(i)
       vx28(i)=vx2(i)-vx8(i)
       vx35(i)=vx3(i)-vx5(i)
       vx46(i)=vx4(i)-vx6(i)
       vy17(i)=vy1(i)-vy7(i)
       vy28(i)=vy2(i)-vy8(i)
       vy35(i)=vy3(i)-vy5(i)
       vy46(i)=vy4(i)-vy6(i)
       vz17(i)=vz1(i)-vz7(i)
       vz28(i)=vz2(i)-vz8(i)
       vz35(i)=vz3(i)-vz5(i)
       vz46(i)=vz4(i)-vz6(i)
      ENDDO
C                                                                     12
      DO i=1,nel
        dxx(i)=px1(i)*vx17(i)+px2(i)*vx28(i)+
     .         px3(i)*vx35(i)+px4(i)*vx46(i)
        dyy(i)=py1(i)*vy17(i)+py2(i)*vy28(i)+
     .         py3(i)*vy35(i)+py4(i)*vy46(i)
        dzz(i)=pz1(i)*vz17(i)+pz2(i)*vz28(i)+
     .         pz3(i)*vz35(i)+pz4(i)*vz46(i)
        dxy(i)=py1(i)*vx17(i)+py2(i)*vx28(i)+
     .         py3(i)*vx35(i)+py4(i)*vx46(i)
        dxz(i)=pz1(i)*vx17(i)+pz2(i)*vx28(i)+
     .         pz3(i)*vx35(i)+pz4(i)*vx46(i)
        dyx(i)=px1(i)*vy17(i)+px2(i)*vy28(i)+
     .         px3(i)*vy35(i)+px4(i)*vy46(i)
        dyz(i)=pz1(i)*vy17(i)+pz2(i)*vy28(i)+
     .         pz3(i)*vy35(i)+pz4(i)*vy46(i)
        dzx(i)=px1(i)*vz17(i)+px2(i)*vz28(i)+
     .         px3(i)*vz35(i)+px4(i)*vz46(i)
        dzy(i)=py1(i)*vz17(i)+py2(i)*vz28(i)+
     .         py3(i)*vz35(i)+py4(i)*vz46(i)
      ENDDO
C      
       DO i=1,nel
        wxx(i)=zero
        wyy(i)=zero
        wzz(i)=zero
       ENDDO
C------------------------------------------------
C 1 1 -1 -1 -1 -1 1 1
      DO i=1,nel
        h1vx=vx1(i)+vx2(i)-vx3(i)-vx4(i)
     .         -vx5(i)-vx6(i)+vx7(i)+vx8(i)
        h1vy=vy1(i)+vy2(i)-vy3(i)-vy4(i)
     .         -vy5(i)-vy6(i)+vy7(i)+vy8(i)
        h1vz=vz1(i)+vz2(i)-vz3(i)-vz4(i)
     .         -vz5(i)-vz6(i)+vz7(i)+vz8(i)
        hgx1(i)=one_over_8*h1vx-
     .         (px1h1(i)*vx17(i)+px2h1(i)*vx28(i)+
     .          px3h1(i)*vx35(i)+px4h1(i)*vx46(i))
        hgy1(i)=one_over_8*h1vy-
     .         (px1h1(i)*vy17(i)+px2h1(i)*vy28(i)+
     .          px3h1(i)*vy35(i)+px4h1(i)*vy46(i))
        hgz1(i)=one_over_8*h1vz-
     .         (px1h1(i)*vz17(i)+px2h1(i)*vz28(i)+
     .          px3h1(i)*vz35(i)+px4h1(i)*vz46(i))
      ENDDO
C 1 -1 -1 1 -1 1 1 -1
      DO i=1,nel
        h2vx=vx1(i)-vx2(i)-vx3(i)+vx4(i)
     .         -vx5(i)+vx6(i)+vx7(i)-vx8(i)
        h2vy=vy1(i)-vy2(i)-vy3(i)+vy4(i)
     .         -vy5(i)+vy6(i)+vy7(i)-vy8(i)
        h2vz=vz1(i)-vz2(i)-vz3(i)+vz4(i)
     .         -vz5(i)+vz6(i)+vz7(i)-vz8(i)
        hgx2(i)=one_over_8*h2vx-
     .         (px1h2(i)*vx17(i)+px2h2(i)*vx28(i)+
     .          px3h2(i)*vx35(i)+px4h2(i)*vx46(i))
        hgy2(i)=one_over_8*h2vy-
     .         (px1h2(i)*vy17(i)+px2h2(i)*vy28(i)+
     .          px3h2(i)*vy35(i)+px4h2(i)*vy46(i))
        hgz2(i)=one_over_8*h2vz-
     .         (px1h2(i)*vz17(i)+px2h2(i)*vz28(i)+
     .          px3h2(i)*vz35(i)+px4h2(i)*vz46(i))
      ENDDO
      DO i=1,nel
       nu1 = nu(i)/(one - nu(i))
       x1vx =-ry0(i)*hgx1(i)
       x2vx =sy0(i)*hgx2(i)
       y1vy =rx0(i)*hgy1(i)
       y2vy =-sx0(i)*hgy2(i)
       y2vy_nu=-nu(i)*y2vy
       x1vx_nu=-nu(i)*x1vx
       dhxx(i)= x1vx+x2vx+y2vy_nu
       dhyy(i)= y1vy+y2vy+x1vx_nu
       ddhv(i)= x1vx_nu+y2vy_nu
       dhzz(i)= ddhv(i)-nu1*(x2vx+y1vy) 
       dhxy(i)=  rx0(i)*hgx1(i)-sx0(i)*hgx2(i)
       dhyx(i)= -ry0(i)*hgy1(i)+sy0(i)*hgy2(i)
       dhzx(i)= -ry0(i)*hgz1(i)
       dhzy(i)= -sx0(i)*hgz2(i)
      ENDDO
C
C-----------
      RETURN
      END