sconnect_off.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    sconnect_off   ../engine/source/elements/solid/sconnect/sconnect_off.f
!||--- called by ------------------------------------------------------
!||    suser43        ../engine/source/elements/solid/sconnect/suser43.F
!||--- uses       -----------------------------------------------------
!||    elbufdef_mod   ../common_source/modules/mat_elem/elbufdef_mod.f90
!||====================================================================
      SUBROUTINE sconnect_off(ELBUF_STR,OFFG     ,NEL    ,NPG    ,NGL     ,
     .                        ISOLID   ,TIME     )
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE elbufdef_mod            
C-------------------------------------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include "units_c.inc"
#include "scr17_c.inc"
#include "comlock.inc"
C----------------------------------------------------------
C   D u m m y   A r g u m e n t s  
C----------------------------------------------------------
      INTEGER NEL,NPG,ISOLID
      INTEGER NGL(NEL)
      my_real time
      my_real ,DIMENSION(NEL) :: offg
      TYPE (ELBUF_STRUCT_), TARGET :: ELBUF_STR
C-----------------------------------------------
C   L O C A L   V A R I A B L E S
C-----------------------------------------------
      INTEGER I,IPG,IEL,NINDX,NDEL
      INTEGER ,DIMENSION(NEL) :: INDX
      my_real ,DIMENSION(NEL) :: countpg
      my_real ,DIMENSION(:) ,POINTER :: offl     
C=======================================================================
      DO iel=1,nel
        IF (offg(iel) < em01) offg(iel) = zero  
        IF (offg(iel) < one)   offg(iel) = offg(iel)*four_over_5
      ENDDO
c
      countpg(1:nel) = zero
      DO ipg = 1,npg
        offl  => elbuf_str%BUFLY(1)%LBUF(ipg,1,1)%OFF(1:nel)
        DO iel=1,nel
          IF (offg(iel)==zero .AND. offl(iel)/=offg(iel)) 
     .        offl(iel)=offg(iel)  
          countpg(iel) = countpg(iel) + offl(iel)
        ENDDO         ! IEL=1,NEL
      ENDDO
c
      nindx = 0
      DO iel=1,nel
        IF (offg(iel) == one) THEN
          ndel = npg - countpg(iel)
          IF (ndel >= isolid) THEN
          nindx = nindx+1
          indx(nindx) = iel
          offg(iel) = four_over_5
          idel7nok  = 1
          ENDIF
        ENDIF
      ENDDO         ! IEL=1,NEL          
c----------------------------------------
c     Print out
c----------------------------------------
      IF (nindx > 0) THEN
        DO i=1,nindx
          iel = indx(i)
#include "lockon.inc"
          WRITE(iout ,1000) ngl(iel)
          WRITE(istdo,1100) ngl(iel),time
#include "lockoff.inc"
        END DO
      ENDIF         
c-------------------------------
 1000 FORMAT(5x,' DELETE CONNECTION SOLID ELEMENT ',i10)
 1100 FORMAT(5x,' DELETE CONNECTION SOLID ELEMENT ',i10,' AT TIME ',1pe16.9)
c-----------
      RETURN
      END