sctherm.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    sctherm   ../engine/source/elements/thickshell/solidec/sctherm.F
!||--- called by ------------------------------------------------------
!||    scforc3   ../engine/source/elements/thickshell/solidec/scforc3.F
!||====================================================================
      SUBROUTINE sctherm(
     1   PM,      IMAT,    VOL,     NC1,
     2   NC2,     NC3,     NC4,     NC5,
     3   NC6,     NC7,     NC8,     PX1,
     4   PX2,     PX3,     PX4,     PY1,
     5   PY2,     PY3,     PY4,     PZ1,
     6   PZ2,     PZ3,     PZ4,     DT1,
     7   TEMPNC,  TEL,     HEAT,    FPHI,
     8   OFFG,    OFF,     NEL,     THEACCFACT)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      INTEGER, INTENT(IN) :: IMAT
      INTEGER NC1(MVSIZ),NC2(MVSIZ),
     .       NC3(MVSIZ),NC4(MVSIZ),NC5(MVSIZ),NC6(MVSIZ),
     .       NC7(MVSIZ),NC8(MVSIZ)
      my_real, INTENT(IN) :: THEACCFACT
      my_real :: VOL(*), PX1(MVSIZ), PY1(MVSIZ),PZ1(MVSIZ),
     .            PX2(MVSIZ), PY2(MVSIZ),PZ2(MVSIZ),
     .            px3(mvsiz), py3(mvsiz),pz3(mvsiz),
     .            px4(mvsiz), py4(mvsiz),pz4(mvsiz),
     .    ni(8), tempnc(*), fphi(mvsiz,8), pm(npropm,*), heat(*),
     .    dt1, tel(*), off(*), offg(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
      my_real
     .  CA, CB, KC, PHIX, PHIY, PHIZ, A
C----------------------------------------------- 
      CA = pm(75,imat)
      cb = pm(76,imat)
!
      DO i=1,nel
       IF(off(i)==zero.OR.offg(i)<=zero) cycle
       phix = zero
       phiy = zero
       phiz = zero
C 
C - flux
C
          phix =  tempnc(nc1(i))*px1(i) + tempnc(nc2(i))*px2(i)  +
     .            tempnc(nc3(i))*px3(i) + tempnc(nc4(i))*px4(i)  -
     .            tempnc(nc5(i))*px3(i) - tempnc(nc6(i))*px4(i)  -
     .            tempnc(nc7(i))*px1(i) - tempnc(nc8(i))*px2(i)       
          
          phiy =  tempnc(nc1(i))*py1(i) + tempnc(nc2(i))*py2(i)  +
     .            tempnc(nc3(i))*py3(i) + tempnc(nc4(i))*py4(i)  -
     .            tempnc(nc5(i))*py3(i) - tempnc(nc6(i))*py4(i)  -
     .            tempnc(nc7(i))*py1(i) - tempnc(nc8(i))*py2(i)
      
          phiz =  tempnc(nc1(i))*pz1(i) + tempnc(nc2(i))*pz2(i)  +
     .            tempnc(nc3(i))*pz3(i) + tempnc(nc4(i))*pz4(i)  -
     .            tempnc(nc5(i))*pz3(i) - tempnc(nc6(i))*pz4(i)  -
     .            tempnc(nc7(i))*pz1(i) - tempnc(nc8(i))*pz2(i) 
C
        kc = (ca + cb*tel(i))*dt1*vol(i)*theaccfact          
        phix = kc*phix
        phiy = kc*phiy
        phiz = kc*phiz
C
C force thermique nodale
C
              a = heat(i)*one_over_8
          fphi(i,1) = fphi(i,1) +
     .        a - (phix*px1(i) + phiy*py1(i) + phiz*pz1(i))
          fphi(i,2) = fphi(i,2) +
     .        a - (phix*px2(i) + phiy*py2(i) + phiz*pz2(i))
          fphi(i,3) = fphi(i,3) +
     .        a - (phix*px3(i) + phiy*py3(i) + phiz*pz3(i))
          fphi(i,4) = fphi(i,4) +
     .        a - (phix*px4(i) + phiy*py4(i) + phiz*pz4(i))
          fphi(i,5) = fphi(i,5) +
     .        a + (phix*px3(i) + phiy*py3(i) + phiz*pz3(i))
          fphi(i,6) = fphi(i,6) +
     .        a + (phix*px4(i) + phiy*py4(i) + phiz*pz4(i))
          fphi(i,7) = fphi(i,7) +
     .        a + (phix*px1(i) + phiy*py1(i) + phiz*pz1(i))
          fphi(i,8) = fphi(i,8) +
     .        a + (phix*px2(i) + phiy*py2(i) + phiz*pz2(i))
       ENDDO
C 
      RETURN
      END