seatbelt_reduction_factor.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    seatbelt_reduction_factor   ../engine/source/tools/seatbelts/seatbelt_reduction_factor.F
!||--- called by ------------------------------------------------------
!||    forintc                     ../engine/source/elements/forintc.F
!||--- uses       -----------------------------------------------------
!||    elbufdef_mod                ../common_source/modules/mat_elem/elbufdef_mod.F90
!||====================================================================
      SUBROUTINE seatbelt_reduction_factor(ELBUF_STR,JFT,JLT,IXC,NEL,X,NFT)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE elbufdef_mod
C----6------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
C-----------------------------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: IXC(NIXC,NUMELC),NEL,JFT,JLT,NFT
      my_real, INTENT(IN) :: x(3,numnod)
      TYPE (ELBUF_STRUCT_), INTENT(INOUT), TARGET :: ELBUF_STR
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,J,K,N1,N2,N3,N4,POS,POS_B,NEL_L,CORES(MVSIZ+1),FLAG,NODE_CORES_DIR2(4)
      my_real 
     .        dist,distb
      TYPE(g_bufel_) ,POINTER :: GBUF
C---------------------------------------------------------
C
      gbuf => elbuf_str%GBUF
C
C-----------------------------------------------------------------------
C     Computation of logarthmic reduction factor of stress for seatbelts
C-----------------------------------------------------------------------
C
      nel_l = 0
C
#include "vectorize.inc" 
      DO i=jft,jlt
        flag = min(1,abs(gbuf%UPDATE(i)))
        nel_l = nel_l + flag
        cores(1+nel_l*flag) = i
      ENDDO
C
      DO k=1,nel_l
C
        i = cores(k+1)
        j = nft + i
C
C--     Element is partially activated - scaling factor in mulawc between 0.0 and 1.0
        IF (gbuf%UPDATE(i) /= zero) THEN
C
          IF (gbuf%ADD_NODE(i) == ixc(3,j)) THEN
C--         dir1 is N1 N2
            node_cores_dir2(1) = 4
            node_cores_dir2(2) = 3
            node_cores_dir2(3) = 2
            node_cores_dir2(4) = 1
          ELSE
C--         dir1 is N1 N4
            node_cores_dir2(1) = 2
            node_cores_dir2(2) = 1
            node_cores_dir2(3) = 4
            node_cores_dir2(4) = 3
          ENDIF
C
          pos = abs(gbuf%UPDATE(i))
          pos_b = node_cores_dir2(pos)
          n1 = ixc(1+pos,j)
          n2 = gbuf%ADD_NODE(nel*pos+i)
          n3 = ixc(1+pos_b,j)
          n4 = gbuf%ADD_NODE(nel*pos_b+i)
C
          dist = sqrt(max(em20,(x(1,n1)-x(1,n2))**2+(x(2,n1)-x(2,n2))**2+(x(3,n1)-x(3,n2))**2))
          distb = sqrt(max(em20,(x(1,n3)-x(1,n4))**2+(x(2,n3)-x(2,n4))**2+(x(3,n3)-x(3,n4))**2))
          dist = min(dist,distb)
          gbuf%INTVAR(i) = log(one + 1.72*dist/gbuf%INTVAR(nel+i))
          gbuf%INTVAR(i) = max(zero,gbuf%INTVAR(i))
          gbuf%INTVAR(i) = min(one,gbuf%INTVAR(i))
C
        ENDIF
C
      ENDDO
C
      RETURN
      END