sensor_acc.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
C=======================================================================
!||====================================================================
!||    sensor_acc    ../engine/source/tools/sensor/sensor_acc.F
!||--- called by ------------------------------------------------------
!||    sensor_base   ../engine/source/tools/sensor/sensor_base.F
!||--- uses       -----------------------------------------------------
!||    sensor_mod    ../common_source/modules/sensor_mod.F90
!||====================================================================
      SUBROUTINE sensor_acc(SENSOR ,ACC)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE sensor_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
#include      "com08_c.inc"
#include      "units_c.inc"
#include      "comlock.inc"
#include      "task_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      my_real, DIMENSION(LLACCELM,*) :: acc
      TYPE (SENSOR_STR_) ,TARGET :: SENSOR
C----------------------------------------------------------
C Local Variables
C----------------------------------------------------------
      INTEGER I,J,K,NACC,IACC,IDIR,ICRIT
c
      my_real :: accmin,tstart,tmin,tdelay
C=======================================================================
      IF (sensor%STATUS == 1) RETURN   ! already activated
c
      tmin   = sensor%TMIN
      tdelay = sensor%TDELAY
      nacc   = sensor%IPARAM(1)
c      
      DO i = 1,nacc
        j = (i-1)*2 + 1
        k = (i-1)*3
        iacc   = sensor%IPARAM(j+1)
        idir   = sensor%IPARAM(j+2)
        accmin = sensor%RPARAM(k+1)
        tmin   = sensor%RPARAM(k+2)
        tstart = sensor%RPARAM(k+3)
        icrit  = 0
        IF (idir == 1) THEN
C         X
          IF (abs(acc(20,iacc)) > accmin) icrit = 1
        ELSEIF (idir == 2) THEN
C         Y
          IF (abs(acc(21,iacc)) > accmin) icrit = 1
        ELSEIF (idir == 4) THEN
C         Z
          IF (abs(acc(22,iacc)) > accmin) icrit = 1
        ELSEIF (idir == 3) THEN
C         XY
          IF (sqrt(acc(20,iacc)*acc(20,iacc)
     .           + acc(21,iacc)*acc(21,iacc)) > accmin) icrit = 1
        ELSEIF (idir == 5) THEN
C         XZ
          IF (sqrt(acc(20,iacc)*acc(20,iacc)
     .           + acc(22,iacc)*acc(22,iacc)) > accmin) icrit = 1
        ELSEIF (idir == 6) THEN
C         YZ
          IF (sqrt(acc(21,iacc)*acc(21,iacc)
     .           + acc(22,iacc)*acc(22,iacc)) > accmin) icrit = 1
        ELSEIF (idir == 7) THEN
C         XYZ
          IF (sqrt(acc(20,iacc)*acc(20,iacc)
     .           + acc(21,iacc)*acc(21,iacc)
     .           + acc(22,iacc)*acc(22,iacc)) > accmin) icrit = 1
        ENDIF
c----------------------------------------------------------------
c       check activation status
c----------------------------------------------------------------
        IF (sensor%TCRIT + tmin > tt) THEN
          IF (icrit == 0) THEN
            sensor%TCRIT = infinity
          ELSE IF (sensor%TCRIT == infinity) THEN
            sensor%TCRIT = min(sensor%TCRIT, tt)
          END IF
        END IF
c
        IF (sensor%TSTART == infinity .and. sensor%TCRIT < infinity) THEN
          sensor%RPARAM(k+3) = sensor%TCRIT + tmin + tdelay      
        END IF
        IF (sensor%RPARAM(k+3) <= tt) THEN   ! sensor activation
          sensor%STATUS = 1
          sensor%TSTART = tt
        END IF
        
      END DO
c-----------------------------------------------------------------------      
      IF (sensor%STATUS == 1 .and. ispmd == 0) THEN
#include "lockon.inc"
        WRITE (istdo,1100) sensor%SENS_ID,sensor%TSTART
        WRITE (iout ,1100) sensor%SENS_ID,sensor%TSTART
#include "lockoff.inc"
      ENDIF
c-----------------------------------------------------------------------      
1100  FORMAT(' SENSOR NUMBER ',i10,' ,ACTIVATED AT TIME ',1pe12.5)
c-----------------------------------------------------------------------      
      RETURN
      END SUBROUTINE