sensor_dist.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
C=======================================================================
!||====================================================================
!||    sensor_dist   ../engine/source/tools/sensor/sensor_dist.F
!||--- called by ------------------------------------------------------
!||    sensor_base   ../engine/source/tools/sensor/sensor_base.F
!||--- uses       -----------------------------------------------------
!||    sensor_mod    ../common_source/modules/sensor_mod.F90
!||====================================================================
      SUBROUTINE sensor_dist(SENSOR ,X      ,XSENS   )
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE sensor_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "com08_c.inc"
#include      "units_c.inc"
#include      "comlock.inc"
#include      "task_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      my_real, DIMENSION(3,NUMNOD) :: x
      my_real, DIMENSION(12)       :: xsens
      TYPE (SENSOR_STR_) ,INTENT(INOUT) ,TARGET :: SENSOR
C----------------------------------------------------------
C Local Variables
C----------------------------------------------------------
      INTEGER :: N1,N2,ICRIT,DFLAG,IFLAG,ACTI
      my_real :: dx,dy,dz,dd,dmin,dmax,tstart,tmin,tdelay
C=======================================================================
      tstart  = sensor%TSTART
      tdelay = sensor%TDELAY
      tmin   = sensor%TMIN
c      
      n1     = sensor%IPARAM(1)
      n2     = sensor%IPARAM(2)
      dflag  = sensor%IPARAM(3)
      dmin   = sensor%RPARAM(1)
      dmax   = sensor%RPARAM(2)
      icrit  = 0    ! activation
      iflag  = 0
      acti   = 0
c
      IF (nspmd == 1)THEN
        dx = x(1,n1)-x(1,n2)
        dy = x(2,n1)-x(2,n2)
        dz = x(3,n1)-x(3,n2)
      ELSE
        dx = xsens(1)-xsens(4)
        dy = xsens(2)-xsens(5)
        dz = xsens(3)-xsens(6)
      END IF
      dd = sqrt(dx*dx+dy*dy+dz*dz)
      IF (dd < dmin) THEN
        icrit = 1
        iflag = 1      
      ELSE IF (dd > dmax) THEN
        icrit = 1
        iflag = 2
      END IF
      sensor%RESULTS(1) = dd
c----------------------------------------------------------------
c     check activation status
c----------------------------------------------------------------
      IF (sensor%STATUS == 0) THEN
        IF (sensor%TCRIT + tmin > tt) THEN
          IF (icrit == 0) THEN
            sensor%TCRIT = infinity
          ELSE IF (icrit == 1 .and. sensor%TCRIT == infinity) THEN
            sensor%TCRIT = tt
          END IF
        END IF
        tstart = sensor%TCRIT + tmin + tdelay      
        IF (tstart <= tt) THEN   
          ! sensor activation
          acti = 1
          sensor%STATUS = 1
          sensor%TSTART = tstart
          sensor%VALUE  = infinity
        END IF 
      END IF 
c
      IF (dflag == 1 .and. sensor%STATUS == 1) THEN
          IF (sensor%VALUE + tmin > tt) THEN
            IF (icrit == 0 .and. sensor%VALUE == infinity) THEN
              sensor%VALUE = tt
            ELSE IF (icrit > 0) THEN
              sensor%VALUE = infinity
            END IF
          END IF
          IF (sensor%VALUE + tmin + tdelay <= tt) THEN 
            ! sensor deactivation
            acti = 2
            sensor%STATUS = 0
            sensor%TCRIT  = infinity
            sensor%TSTART = infinity
          END IF 
      END IF
c-----------------------------------------------------------------------      
      IF (acti == 1) THEN
        IF (ispmd == 0) THEN
#include "lockon.inc"
          WRITE (istdo,1000) sensor%SENS_ID,sensor%TSTART
          WRITE (iout ,1000) sensor%SENS_ID,sensor%TSTART
          IF (iflag == 1) THEN
            WRITE (iout ,1200) dmin
          ELSE IF (iflag == 2) THEN
            WRITE (iout ,1300) dmax
          END IF
          WRITE (iout ,1400) dd
#include "lockoff.inc"
        ENDIF
      ELSE IF (acti == 2) THEN
        IF (ispmd == 0) THEN
#include "lockon.inc"
          WRITE (istdo,1100) sensor%SENS_ID,tt
          WRITE (iout ,1100) sensor%SENS_ID,tt
          WRITE (iout ,1400) dd
#include "lockoff.inc"
        ENDIF
      ENDIF
c-----------------------------------------------------------------------      
1000  FORMAT(' SENSOR NUMBER ',i10,' ACTIVATED AT TIME ',1pe12.5)
1100  FORMAT(' SENSOR NUMBER ',i10,' DEACTIVATED AT TIME ',1pe12.5)
1200  FORMAT('      TARGET MIN DISTANCE= ',1pe12.5)
1300  FORMAT('      TARGET MAX DISTANCE= ',1pe12.5)
1400  FORMAT('      CURRENT DISTANCE AFTER TMIN AND TDELAY = ',1pe12.5)
c-----------------------------------------------------------------------      
      RETURN
      END SUBROUTINE