sensor_dist_surf.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    sensor_dist_surf     ../engine/source/tools/sensor/sensor_dist_surf.F
!||--- called by ------------------------------------------------------
!||    sensor_base          ../engine/source/tools/sensor/sensor_base.F
!||--- calls      -----------------------------------------------------
!||    dist_node_plane_3n   ../engine/source/tools/sensor/dist_node_plane_3n.F
!||--- uses       -----------------------------------------------------
!||    groupdef_mod         ../common_source/modules/groupdef_mod.F
!||    sensor_mod           ../common_source/modules/sensor_mod.f90
!||====================================================================
      SUBROUTINE sensor_dist_surf(SENSOR ,X   ,IGRSURF)
!$COMMENT
!       SENSOR_DIST_SURF description
!       computation of distance to surface for sensor typ16 + plane defined by 3 nodes
!       and modification of the state of sensor
!       For the other surface, the distance computation is done in SENSOR_DIST_SURF0 routine
!       
!       SENSOR_DIST_SURF0 organization :
!       - computation of local distance for sensor 16 + plane defined by 3 nodes
!       - sensor state modification
!$ENDCOMMENT
c-----------------------------------------------
C   M o d u l e s
c-----------------------------------------------
      USE groupdef_mod
      USE sensor_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
#include      "comlock.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "units_c.inc"
#include      "com04_c.inc"
#include      "com08_c.inc"
#include      "task_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      my_real ,DIMENSION(3,NUMNOD) :: x
      TYPE (SURF_) ,DIMENSION(NSURF), TARGET :: IGRSURF
      TYPE (SENSOR_STR_) :: SENSOR
C----------------------------------------------------------
C Local Variables
C----------------------------------------------------------
       INTEGER ISURF, INOD, NP1, NP2, NP3, ICRIT, IFLAG
       my_real dist,dmin,dmax,tdelay,tmin
       my_real xnod,ynod,znod,xp1,yp1,zp1,xp2,yp2,zp2,xp3,yp3,zp3
C=======================================================================
      IF (sensor%STATUS == 1) RETURN   ! already activated
 
C.....................................................
C ==> DIST between node and a plan defined by 3 nodes
C.....................................................
C     ID_N1 : Node identifier
C     ID_PN1 : Plan Node 1 identifier
C     ID_PN2 : Plan Node 2 identifier
C     ID_PN3 : Plan Node 3 identifier
C
      tmin   = sensor%TMIN
      tdelay = sensor%TDELAY      ! time delay before activation
      inod   = sensor%IPARAM(1)
      isurf  = sensor%IPARAM(2)
c
      dmin   = sensor%RPARAM(1)
      dmax   = sensor%RPARAM(2)
      icrit  = 0
      iflag  = 0
c
c...  Current position of reference node
c
      xnod  = x(1,inod)
      ynod  = x(2,inod)
      znod  = x(3,inod)
c    
c
      IF (isurf == 0) THEN  ! calculate distance to plane defined by 3 nodes
c
        np1 = sensor%IPARAM(3)
        np2 = sensor%IPARAM(4)
        np3 = sensor%IPARAM(5)
        xp1 = x(1,np1)
        yp1 = x(2,np1)
        zp1 = x(3,np1)
        xp2 = x(1,np2)
        yp2 = x(2,np2)
        zp2 = x(3,np2)
        xp3 = x(1,np3)
        yp3 = x(2,np3)
        zp3 = x(3,np3)
        CALL dist_node_plane_3n(dist,
     .       xnod,ynod,znod,xp1,yp1,zp1,xp2,yp2,zp2,xp3,yp3,zp3)
c
        sensor%VALUE = dist
      END IF
      IF (sensor%VALUE <= dmin) THEN
        icrit = 1
        iflag = 1
      ELSE IF (sensor%VALUE >= dmax) THEN
        icrit = 1
        iflag = 2
      END IF
      sensor%RESULTS(1) = sensor%VALUE
c----------------------------------------------------------------
c     check activation status
c----------------------------------------------------------------
      IF (sensor%TCRIT + tmin > tt) THEN
        IF (icrit == 0) THEN
          sensor%TCRIT = infinity
        ELSE IF (sensor%TCRIT == infinity) THEN
          sensor%TCRIT = min(sensor%TCRIT, tt)
        END IF
      END IF
      IF (sensor%TSTART == infinity .and. sensor%TCRIT < infinity) THEN
        sensor%TSTART = sensor%TCRIT + tmin + tdelay      
      END IF
      IF (sensor%TSTART <= tt) THEN   ! sensor activation
        sensor%STATUS = 1
      END IF
c----------------------------------------------------------
      IF (sensor%STATUS == 1 .and. ispmd == 0) THEN
#include "lockon.inc"
        WRITE (istdo,1100) sensor%SENS_ID,sensor%TSTART
        WRITE (iout ,1100) sensor%SENS_ID,sensor%TSTART
        IF (iflag == 1) THEN
          WRITE (iout ,1200) dmin,dist
        ELSE IF (iflag == 2) THEN
          WRITE (iout ,1300) dmax,dist
        END IF
#include "lockoff.inc"
      END IF
c-----------------------------------------------------------------------      
1100  FORMAT(' SENSOR NUMBER ',i10,' ,ACTIVATED AT TIME ',1pe12.5)
1200  FORMAT('      TARGET MIN DISTANCE TO PLAN = ',1pe12.5,/
     .       '      CURRENT DISTANCE AFTER TMIN and TDELAY = ',1pe12.5)
1300  FORMAT('      TARGET MAX DISTANCE TO PLAN = ',1pe12.5,/
     .       '      CURRENT DISTANCE AFTER TMIN and TDELAY = ',1pe12.5)
c----------------------------------------------------------
      RETURN
      END SUBROUTINE