sensor_gauge.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
C=======================================================================
!||====================================================================
!||    sensor_gauge   ../engine/source/tools/sensor/sensor_gauge.F
!||--- called by ------------------------------------------------------
!||    sensor_base    ../engine/source/tools/sensor/sensor_base.F
!||--- uses       -----------------------------------------------------
!||    sensor_mod     ../common_source/modules/sensor_mod.F90
!||====================================================================
      SUBROUTINE sensor_gauge(SENSOR ,GAUGE)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE sensor_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
#include      "com08_c.inc"
#include      "units_c.inc"
#include      "comlock.inc"
#include      "task_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      my_real, DIMENSION(LLGAUGE,*) :: gauge
      TYPE (SENSOR_STR_) :: SENSOR
C----------------------------------------------------------
C Local Variables
C----------------------------------------------------------
      INTEGER I,J,NGAUGE,IGAU,ICRIT
c
      my_real :: pmin,tmin,tstart,tdelay,maxp
C=======================================================================
      IF (sensor%STATUS == 1) RETURN   ! already activated
c
      tdelay = sensor%TDELAY
      ngauge = sensor%IPARAM(1)
 
      j = 0
      maxp = - infinity
      DO i = 1,ngauge
        icrit  = 0
        igau   = sensor%IPARAM(i+1)
        pmin   = sensor%RPARAM(j+1)
        tmin   = sensor%RPARAM(j+2)
        tstart = sensor%RPARAM(j+3)
        IF (abs(gauge(30,igau)) > pmin) icrit  = 1
        IF(abs(gauge(30,igau)) > maxp) maxp = abs(gauge(30,igau))
c----------------------------------------------------------------
c       check activation status
c----------------------------------------------------------------
        IF (sensor%TCRIT + tmin > tt) THEN
          IF (icrit == 0) THEN
            sensor%TCRIT = infinity
          ELSE IF (sensor%TCRIT == infinity) THEN
            sensor%TCRIT = min(sensor%TCRIT, tt)
          END IF
        ELSE IF (sensor%RPARAM(j+3) == infinity) THEN
          sensor%RPARAM(j+3) = sensor%TCRIT + tmin + tdelay
        END IF
        IF (sensor%RPARAM(j+3) <= tt) THEN   ! sensor activation
          sensor%STATUS = 1
          sensor%TSTART = sensor%RPARAM(j+3)
        END IF
c  
        IF (sensor%STATUS == 1 .and. ispmd == 0) THEN
#include "lockon.inc"
          WRITE (istdo,1100) sensor%SENS_ID,sensor%TSTART
          WRITE (iout ,1100) sensor%SENS_ID,sensor%TSTART
          WRITE (iout ,1200) pmin,abs(gauge(30,igau))
#include "lockoff.inc"
        ENDIF
        j = j + 3
      END DO
      sensor%RESULTS(1) = maxp
c-----------------------------------------------------------------------      
1100  FORMAT(' SENSOR NUMBER ',i10,' ,ACTIVATED AT TIME ',1pe12.5)
1200  FORMAT('      TARGET PRESSURE = ',1pe12.5,/
     .       '      CURRENT PRESSURE AFTER TMIN AND TDELAY = ',1pe12.5)
c-----------------------------------------------------------------------      
      RETURN
      END SUBROUTINE