sensor_sens.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    sensor_sens      ../engine/source/tools/sensor/sensor_sens.F
!||--- called by ------------------------------------------------------
!||    sensor_logical   ../engine/source/tools/sensor/sensor_logical.F
!||--- uses       -----------------------------------------------------
!||    sensor_mod       ../common_source/modules/sensor_mod.F90
!||====================================================================
      SUBROUTINE sensor_sens(NSENSOR,SENSOR_TAB,SENS)
C-----------------------------------------------
C   ROUTINE DESCRIPTION :
C   ===================
C   SENS sensor : starts when IS1 starts,
C                 Remains active for at least TDELAY
C                 IF IS2 is defined : stops when IS2 starts
C                 ELSE stops after TDELAY.
C                 IS1 and IS2 are the sensors given as definition
C----------------------------------------------------------------
C   DUMMY ARGUMENTS DESCRIPTION:
C   ===================
C
C     NAME          DESCRIPTION                         
C
C    SENSOR_TAB     Sensor Structure
C    SENS           SENSOR ID to treat
C----------------------------------------------------------------
C    Sensor activation flag:
C 
C    Sensor inactive & cannot be reactivated afterwards
C    SENSOR_TAB(SENS)%TSTART = INFINITY (1.E+20)
C    SENSOR_TAB(SENS)%STATUS = -1
C
C    Sensor inactive :
C    SENSOR_TAB(SENS)%TSTART = INFINITY (1.E+20)
C    SENSOR_TAB(SENS)%STATUS = 0
C
C    Sensor active :
C    SENSOR_TAB(SENS)%TSTART = TT (or activation time : TT+DT2)
C    SENSOR_TAB(SENS)%STATUS = 1
C
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE sensor_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
#include      "com08_c.inc"
#include      "units_c.inc"
#include      "task_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NSENSOR,SENS
      TYPE (SENSOR_STR_), INTENT(INOUT) ,DIMENSION(NSENSOR) :: SENSOR_TAB
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER IS1,STATUS_IS1
      INTEGER IS2,STATUS_IS2
 
      INTEGER ACTI,SENS_ID
      my_real tstart, tdelay,tstart1, tstops
C-----------------------------------------------
      acti = 0
c
      sens_id = sensor_tab(sens)%SENS_ID
      tstart  = sensor_tab(sens)%TSTART
      tdelay  = sensor_tab(sens)%TDELAY
      tstops  = infinity
c
      is1        = sensor_tab(sens)%IPARAM(1)
      status_is1 = sensor_tab(is1)%STATUS
      tstart1    = sensor_tab(is1)%TSTART
c
      is2        = sensor_tab(sens)%IPARAM(2)
      IF (is2 > 0) THEN
          status_is2 = sensor_tab(is2)%STATUS
      ENDIF
 
      IF (sensor_tab(sens)%STATUS == -1)THEN         ! Status= -1 : Sensor will never wake up again
         RETURN
      ENDIF
 
 
      IF (status_is1 <= 0) THEN
          tstart1 = infinity
      END IF
 
      IF (status_is1 == 1) THEN                      ! check status of sensor1
         IF (sensor_tab(sens)%STATUS == 0) THEN
              acti = 1
              sensor_tab(sens)%STATUS = 1
              sensor_tab(sens)%TSTART = tstart1     
         ENDIF
      ENDIF
 
      IF (tt > (tstart + tdelay) ) THEN              ! We reached TDELAY
 
         IF (is2 == 0) THEN                          ! If sensor2 not defined : STOP
            tstops = tt
         ELSE                                        ! sensor2 defined : stop when sens2 starts
            tstops = infinity
            IF (sensor_tab(is2)%STATUS == 1) THEN
              tstops = tt
            ENDIF
         ENDIF
 
         IF (tstops <= tt) THEN
              sensor_tab(sens)%TSTART = infinity
              sensor_tab(sens)%STATUS = -1           ! Status= -1 : Sensor will never wake up again
              acti = acti + 2
         ENDIF
      ENDIF
 
     
      IF (acti == 1) THEN
 
        IF (ispmd == 0) THEN
          WRITE (istdo,1000) sensor_tab(sens)%SENS_ID,tstart1
          WRITE (iout ,1000) sensor_tab(sens)%SENS_ID,tstart1
        ENDIF
 
      ELSE IF (acti == 2) THEN
 
        IF (ispmd == 0) THEN
          WRITE (istdo,1100) sensor_tab(sens)%SENS_ID,tt
          WRITE (iout ,1100) sensor_tab(sens)%SENS_ID,tt
        ENDIF
 
      ENDIF
c-----------------------------------------------------------------------      
1000  FORMAT(' SENSOR NUMBER ',i10,' ACTIVATED AT TIME ',1pe12.5)
1100  FORMAT(' SENSOR NUMBER ',i10,' DEACTIVATED AT TIME ',1pe12.5)
C-----------------------------------------------
      END