sensor_temp.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    sensor_temp    ../engine/source/tools/sensor/sensor_temp.F
!||--- called by ------------------------------------------------------
!||    sensor_base    ../engine/source/tools/sensor/sensor_base.F
!||--- uses       -----------------------------------------------------
!||    groupdef_mod   ../common_source/modules/groupdef_mod.F
!||    sensor_mod     ../common_source/modules/sensor_mod.F90
!||====================================================================
      SUBROUTINE sensor_temp(SENSOR   ,ISENS     ,IGRNOD   ) 
c-----------------------------------------------------------------------
!$COMMENT
!       SENSOR_TEMP description
!       SENSOR_TEMP organization :
!       - sensor state modification
!$ENDCOMMENT
c-----------------------------------------------
C   M o d u l e s
c-----------------------------------------------
      USE groupdef_mod
      USE sensor_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
#include      "comlock.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "units_c.inc"
#include      "com04_c.inc"
#include      "com08_c.inc"
#include      "task_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER :: ISENS
      TYPE(GROUP_)  ,DIMENSION(NGRNOD) ,INTENT(IN) :: IGRNOD
      TYPE (SENSOR_STR_) :: SENSOR
C----------------------------------------------------------
C Local Variables
C----------------------------------------------------------
      INTEGER :: I,IGN,ICRIT,TFLAG
      my_real :: tstart,tdelay,tmin,temp_max,temp_min,temp_avg
c----------------------------------------------------------
c     SENSOR%VAR(1)   = TEMP_MAX
c     SENSOR%VAR(2)   = TEMP_MIN 
c     SENSOR%VAR(3)   = TEMP_AVG 
c
c     sensor status : ICRIT
c            = 0   : inactive, criterion not met
c            = 1   : criterium reached, testing duration time Tmin 
c            = 2   : ready to activate after Tdelay
c            = 3   : activated at Time = TSTART
C=======================================================================
      IF (sensor%STATUS == 1) RETURN   ! already activated
c
      IF (tt == zero) sensor%VAR(2) = ep20   ! initialize Temp min
      tstart   = sensor%TSTART
      tdelay   = sensor%TDELAY
      tmin     = sensor%TMIN
      ign      = sensor%IPARAM(1)
      temp_max = sensor%VAR(1)
      temp_min = sensor%VAR(2)    
      temp_avg = sensor%VAR(3)    
      icrit = 0
      tflag = 0
 
      IF (temp_avg > sensor%RPARAM(3)) THEN
        icrit = 1
        tflag = 3      
      ELSE IF (temp_max > sensor%RPARAM(1)) THEN
        icrit = 1
        tflag = 1      
      ELSE IF (temp_min < sensor%RPARAM(2)) THEN
        icrit = 1
        tflag = 2      
      END IF 
c----------------------------------------------------------------
c     check activation status
c----------------------------------------------------------------
      IF (sensor%TCRIT + tmin > tt) THEN
        IF (icrit == 0) THEN
          sensor%TCRIT = infinity
        ELSE IF (sensor%TCRIT == infinity) THEN
          sensor%TCRIT = tt
        END IF
      END IF
      tstart = sensor%TCRIT + tmin + tdelay      
      IF (tstart <= tt) THEN   ! sensor activation
        sensor%STATUS = 1
        sensor%TSTART = tstart
      END IF
c-----------------------------------------------------------------------      
      IF (sensor%STATUS == 1 .and. ispmd == 0) THEN
#include "lockon.inc"
        WRITE (istdo,1100 ) sensor%SENS_ID,sensor%TSTART
        WRITE (iout ,1100 ) sensor%SENS_ID,sensor%TSTART
        IF (tflag == 1) THEN
          WRITE (iout ,1200)  sensor%RPARAM(1),temp_max
        ELSE IF (tflag == 2) THEN
          WRITE (iout ,1300)  sensor%RPARAM(2),temp_min
        ELSE IF (tflag == 3) THEN
          WRITE (iout ,1400)  sensor%RPARAM(3),temp_avg
        END IF
#include "lockoff.inc"
      ENDIF
c-----------------------------------------------------------------------      
1100  FORMAT(' SENSOR TEMPERATURE NUMBER ',i10,' ACTIVATED AT TIME ',1pe12.5)
1200  FORMAT('      TARGET MAX TEMPERATURE = ',1pe12.5,/
     .       '      CURRENT TEMPERATURE AFTER TMIN and TDELAY = ',1pe12.5)
1300  FORMAT('      TARGET MIN TEMPERATURE = ',1pe12.5,/
     .       '      CURRENT TEMPERATURE AFTER TMIN and TDELAY = ',1pe12.5)
1400  FORMAT('      TARGET AVG TEMPERATURE = ',1pe12.5,/
     .       '      CURRENT TEMPERATURE AFTER TMIN and TDELAY = ',1pe12.5)
c----------------------------------------------------------
      RETURN
      END SUBROUTINE sensor_temp