sensor_vel.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
C=======================================================================
!||====================================================================
!||    sensor_vel    ../engine/source/tools/sensor/sensor_vel.F
!||--- called by ------------------------------------------------------
!||    sensor_base   ../engine/source/tools/sensor/sensor_base.F
!||--- calls      -----------------------------------------------------
!||    butterworth   ../engine/source/tools/univ/butterworth.F
!||--- uses       -----------------------------------------------------
!||    sensor_mod    ../common_source/modules/sensor_mod.f90
!||====================================================================
      SUBROUTINE sensor_vel(SENSOR ,V)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE sensor_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
#include      "com08_c.inc"
#include      "units_c.inc"
#include      "comlock.inc"
#include      "task_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      my_real, DIMENSION(3,NUMNOD) :: v
      TYPE (SENSOR_STR_) ,INTENT(INOUT) :: SENSOR
C----------------------------------------------------------
C Local Variables
C----------------------------------------------------------
      INTEGER NODE,ICRIT
c
      my_real :: vel,vx,vy,vz,vv,vvx,vvy,fvx,fvy,fv,freq,
     .           tmin,tstart,tdelay,infinity
      parameter(infinity = 1.0e20)
C=======================================================================
      IF (sensor%STATUS == 1) RETURN   ! already activated
c
      tstart  = sensor%TSTART
      tdelay = sensor%TDELAY
      node   = sensor%IPARAM(1)
      vel    = sensor%RPARAM(1)
      freq   = sensor%RPARAM(2)
      tmin   = zero
      icrit  = 0
c      
      vx = v(1,node)
      vy = v(2,node)
      vz = v(3,node)
      vv = sqrt(vx*vx+vy*vy+vz*vz)
c
      IF (freq > 0) THEN   ! filtering (Butterworth) 
        vvx = sensor%VAR(1)
        vvy = sensor%VAR(2)
        fvx = sensor%VAR(3)
        fvy = sensor%VAR(4)
c
        CALL butterworth(dt2,freq,vvy,vvx,vv,fvy,fvx,fv)
c
        sensor%VAR(1) = vv  
        sensor%VAR(2) = vvx  
        sensor%VAR(3) = fv  
        sensor%VAR(4) = fvx  
        vv = fv
      ENDIF
      IF (vv > vel) icrit = 1
c----------------------------------------------------------------
c     check activation status
c----------------------------------------------------------------
      IF (sensor%TCRIT + tmin > tt) THEN
        IF (icrit == 0) THEN
          sensor%TCRIT = infinity
        ELSE IF (sensor%TCRIT == infinity) THEN
          sensor%TCRIT = tt
        END IF
      END IF
      IF (sensor%TCRIT < infinity) tstart = sensor%TCRIT + tmin + tdelay
      IF (tstart <= tt) THEN   ! sensor activation
        sensor%STATUS = 1
        sensor%TSTART = tstart
      END IF
c-----------------------------------------------------------------------      
      IF (sensor%STATUS == 1 .and. ispmd == 0) THEN
#include "lockon.inc"
        WRITE (istdo,1100) sensor%SENS_ID,sensor%TSTART
        WRITE (iout ,1100) sensor%SENS_ID,sensor%TSTART
        WRITE (iout ,1200) vel,vv
#include "lockoff.inc"
      ENDIF
c-----------------------------------------------------------------------      
1100  FORMAT(' SENSOR NUMBER ',i10,' ,ACTIVATED AT TIME ',1pe12.5)
1200  FORMAT('      TARGET VELOCITY = ',1pe12.5,/
     .       '      CURRENT VELOCITY AFTER TDELAY = ',1pe12.5)
c-----------------------------------------------------------------------      
      RETURN
      END SUBROUTINE