set_elgroup_param.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    set_elgroup_param   ../starter/source/elements/shell/coque/set_elgroup_param.F
!||--- called by ------------------------------------------------------
!||    lectur              ../starter/source/starter/lectur.F
!||--- uses       -----------------------------------------------------
!||====================================================================
      SUBROUTINE set_elgroup_param(
     .           GROUP_PARAM_TAB,IPARG    ,NGROUP   ,N2D      ,
     .           IPM            ,IGEO     ,PM       ,GEO      ,
     .           BUFMAT         )
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE group_param_mod            
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
#include      "com04_c.inc"
#include      "tabsiz_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NGROUP,N2D
      INTEGER ,DIMENSION(NPARG,NGROUP)   :: IPARG
      INTEGER ,DIMENSION(NPROPMI,NUMMAT) :: IPM
      INTEGER ,DIMENSION(NPROPGI,NUMGEO) :: IGEO
      my_real ,DIMENSION(NPROPM,NUMMAT)  :: pm
      my_real ,DIMENSION(NPROPG,NUMGEO)  :: geo
      my_real ,DIMENSION(SBUFMAT)        :: bufmat
      TYPE(group_param_) ,DIMENSION(NGROUP) :: GROUP_PARAM_TAB
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER NG,ITY,IGTYP,IDEF,IGMAT,IHBE,ISH3N,IEL,PID,IMAT,ILAW,IADD,
     .        NIP,ISMSTR,ICOAT
      my_real DM,TCOAT
C=======================================================================
      DO ng=1,ngroup
        ity   = iparg(5,ng)
        IF (n2d == 0 .and. (ity == 3 .or. ity == 7)) THEN
          ilaw  = iparg(1,ng)
          imat  = iparg(18,ng)
          pid   = iparg(62,ng)
          iel   = iparg(3,ng)+1
          igtyp = iparg(38,ng)
          dm    = geo(16,pid)
          idef  = igeo(31,pid)
          igmat = igeo(98,pid)
c          IHBE  = IGEO(10,PID)   ! should be the same, GEO(171) is obsolete, check !!!
          ihbe  = nint(geo(171,pid))
          ish3n = igeo(18,pid)
c
c         Set default membrane shell viscosity parameter (DM)         
c
          IF (dm == zero) THEN
            SELECT CASE (ilaw)
              CASE (65)
                dm = fiveem2
              CASE (19, 119)
                IF (ity == 3 .AND. ihbe == 23) THEN
                  dm = zep015
                ELSE
                  dm = fourth
                END IF
              CASE (58, 158)
                IF (ihbe == 11) THEN
                  dm = one_fifth
                ELSE
                  dm = three_over_4 * em01
                END IF
              CASE (25, 125, 127)
                IF (ihbe == 23) dm = em01
              CASE (42, 69)
                IF (ihbe == 11) THEN
                  dm = zep04
                ELSE
                  dm = zep03
                END IF
              CASE DEFAULT
                IF (ihbe == 23 .AND. (igtyp == 1 .or. igtyp == 9)) dm = zep015
            END SELECT
          END IF
c------   specific composite IGMAT > 0
          IF (igmat > 0) THEN  ! .and. (ILAW /= 15 .AND. ILAW /= 27)) THEN
            IF (dm == zero) dm = fiveem2
          ELSEIF ( ilaw == 15 .or. ilaw == 27 .or. ilaw == 25 .or. ilaw==125 
     .                                                        .or. ilaw == 127) THEN
            IF (dm == zero) dm = fiveem2
          ENDIF !(IGMAT > 0
c          
          group_param_tab(ng)%VISC_DM = dm  
c
c------   special settings for law119
c          
          IF (ilaw == 119) THEN
            iadd = max(1,ipm(7,imat))-1
            icoat = nint(bufmat(iadd+14))
            tcoat = bufmat(iadd+16)
            ismstr = 11   ! force small strain formulation for law 119 regardless of input
            ihbe   = 11   ! force full shell integration (Batoz) for law 119 regardless of input
            IF (icoat > zero .AND. tcoat > zero) THEN 
              nip = 3
              ! update shell thickness in the property to take coating into account
              geo(1,pid) = geo(1,pid) + two*tcoat
            ELSE
              nip = 1
            END IF
            iparg(6,ng) = nip
            iparg(9,ng) = ismstr
            iparg(23,ng)= ihbe
          END IF
           
 
        ELSE
c
          group_param_tab(ng)%VISC_DM = zero  
c
        ENDIF
c
        group_param_tab(ng)%VISC_DN = zero  
      
      ENDDO
c-----------
      RETURN
      END