sfac_mem_dynamic.F

Go to the documentation of this file.

C
C  This file is part of MUMPS 5.5.1, released
C  on Tue Jul 12 13:17:24 UTC 2022
C
C
C  Copyright 1991-2022 CERFACS, CNRS, ENS Lyon, INP Toulouse, Inria,
C  Mumps Technologies, University of Bordeaux.
C
C  This version of MUMPS is provided to you free of charge. It is
C  released under the CeCILL-C license 
C  (see doc/CeCILL-C_V1-en.txt, doc/CeCILL-C_V1-fr.txt, and
C  https://cecill.info/licences/Licence_CeCILL-C_V1-en.html)
C
      MODULE smumps_dynamic_memory_m
      CONTAINS
      SUBROUTINE smumps_dm_set_dynptr( CB_STATE, A, LA,
     &                                PAMASTER_OR_PTRAST, IXXD,
     &                                IXXR, SON_A, IACHK, RECSIZE )
      IMPLICIT NONE
      INTEGER, INTENT(IN) :: CB_STATE
      INTEGER, INTENT(IN) :: IXXR(2), IXXD(2)
      INTEGER(8), INTENT(IN) :: LA, PAMASTER_OR_PTRAST
      REAL, INTENT(IN), TARGET :: A( LA )
#if defined(mumps_f2003)
      REAL, POINTER, DIMENSION(:), INTENT(OUT) :: SON_A
#else
      REAL, POINTER, DIMENSION(:) :: SON_A
#endif
      INTEGER(8), INTENT(OUT) :: IACHK, RECSIZE
      IF ( SMUMPS_DM_IS_DYNAMIC( IXXD ) ) THEN
        CALL mumps_geti8(recsize, ixxd)
        CALL smumps_dm_set_ptr( pamaster_or_ptrast, recsize, son_a )
        iachk = 1_8
      ELSE
        CALL mumps_geti8(recsize, ixxr)
        iachk = pamaster_or_ptrast
        son_a => a
      ENDIF
      RETURN
      END SUBROUTINE smumps_dm_set_dynptr
      SUBROUTINE smumps_dm_pamasterorptrast( N, SLAVEF, MYID, KEEP28,
     &                              KEEP199, INODE, CB_STATE, IXXD,
     &                              STEP, DAD, PROCNODE_STEPS,
     &                              RCURRENT, PAMASTER, PTRAST,
     &                              IS_PAMASTER, IS_PTRAST )
      IMPLICIT NONE
      INTEGER, INTENT(in) :: KEEP28, N, SLAVEF, MYID, INODE, CB_STATE
      INTEGER, INTENT(in) :: KEEP199
      INTEGER, INTENT(in) :: IXXD(2)
      INTEGER, INTENT(in) :: DAD(KEEP28)
      INTEGER, INTENT(in) :: STEP(N)
      INTEGER, INTENT(in) :: PROCNODE_STEPS(KEEP28)
      LOGICAL, INTENT(out) :: IS_PAMASTER, IS_PTRAST
      INTEGER(8), INTENT(in) :: PAMASTER(KEEP28), PTRAST(KEEP28)
      INTEGER(8), INTENT(in) :: RCURRENT
      LOGICAL :: DAD_TYPE2_NOT_ON_MYID
      INTEGER :: NODETYPE, DADTYPE
      include 'mumps_headers.h'
      INTEGER, EXTERNAL :: MUMPS_TYPENODE
      INTEGER, EXTERNAL :: MUMPS_PROCNODE
      is_pamaster = .false.
      is_ptrast   = .false.
      IF (cb_state .EQ. s_free) THEN
        RETURN
      ENDIF
      nodetype = mumps_typenode(procnode_steps(step(inode)), keep199)
      dadtype=-99999 
      dad_type2_not_on_myid = .false.
      IF (dad(step(inode)) .NE. 0) THEN
        dadtype= mumps_typenode(
     &           procnode_steps(step(dad(step(inode)))),
     &           keep199)
        IF (dadtype .EQ. 2 .AND.
     &      mumps_procnode(
     &           procnode_steps(step(dad(step(inode)))),
     &           keep199).NE.myid
     &    ) THEN
          dad_type2_not_on_myid = .true.
        ENDIF
      ENDIF
      IF (smumps_dm_isband(cb_state)) THEN
        is_ptrast=.true.
      ELSE IF (nodetype.EQ.1
     &  .AND. mumps_procnode(procnode_steps(step(inode)),
     &           keep199).EQ.myid
     &  .AND. dad_type2_not_on_myid)
     &  THEN
        is_ptrast=.true.
      ELSE
        is_pamaster=.true.
      ENDIF
      RETURN
      END SUBROUTINE smumps_dm_pamasterorptrast
      LOGICAL FUNCTION smumps_dm_isband(XXSTATE)
      INTEGER, INTENT(IN) :: xxstate
      include 'mumps_headers.h'
      SELECT CASE (xxstate)
        CASE(s_notfree, s_cb1comp);
          smumps_dm_isband = .false.
        CASE(s_active, s_all,
     &    s_nolcbcontig, s_nolcbnocontig, s_nolcleaned,
     &    s_nolcbnocontig38, s_nolcbcontig38, s_nolcleaned38,
     &    s_nolnocb, s_nolnocbcleaned);
          smumps_dm_isband = .true.
        CASE(s_free);
          smumps_dm_isband = .false.
        CASE DEFAULT;
          WRITE(*,*) "Wrong state during SMUMPS_DM_ISBAND", xxstate
          CALL mumps_abort()
        END SELECT
      RETURN
      END FUNCTION smumps_dm_isband
      LOGICAL FUNCTION smumps_dm_is_dynamic(IXXD)
      INTEGER :: ixxd(2)
      INTEGER(8) :: dyn_size
      CALL mumps_geti8( dyn_size, ixxd )
      smumps_dm_is_dynamic = dyn_size > 0_8
      RETURN
      END FUNCTION smumps_dm_is_dynamic
      SUBROUTINE smumps_dm_fac_alloc_allowed
     &                     (mem_count_to_allocate, keep8, 
     &                      iflag, ierror)
      IMPLICIT NONE
      INTEGER(8), INTENT(IN)    :: MEM_COUNT_TO_ALLOCATE
      INTEGER(8), INTENT(INOUT) :: KEEP8(150)
      INTEGER, INTENT(INOUT)    :: IFLAG, IERROR
      IF ( KEEP8(73) + MEM_COUNT_TO_ALLOCATE
     &     .GT. KEEP8(75) ) THEN
           iflag = -19
           CALL mumps_set_ierror(
     &        keep8(73) + mem_count_to_allocate -keep8(75),
     &        ierror )
      ENDIF
      RETURN
      END SUBROUTINE smumps_dm_fac_alloc_allowed
      SUBROUTINE smumps_dm_cbstatic2dynamic( STRATEGY,
     &           SIZER_NEEDED, SKIP_TOP_STACK,
     &           MYID, N, SLAVEF,
     &           KEEP, KEEP8,
     &           IW, LIW, IWPOSCB, IWPOS,
     &           A, LA, LRLU, IPTRLU, LRLUS, 
     &           STEP, PTRAST, PAMASTER,
     &           PROCNODE_STEPS, DAD, IFLAG, IERROR)
!$    USE OMP_LIB
      USE smumps_load, ONLY : smumps_load_mem_update
      IMPLICIT NONE
      INTEGER, INTENT(in) :: STRATEGY
      INTEGER(8), INTENT(in) :: SIZER_NEEDED
      LOGICAL, INTENT(in)    :: SKIP_TOP_STACK
      INTEGER, INTENT(in)  :: N, SLAVEF, KEEP(500)
      INTEGER, INTENT(in)  :: MYID
      INTEGER(8), INTENT(inout) :: KEEP8(150)
      INTEGER :: IWPOS, IWPOSCB, LIW
      INTEGER, INTENT(inout) :: IW( LIW )
      INTEGER(8) :: LA, LRLU, IPTRLU, LRLUS
      REAL, INTENT(in) :: A( LA )
      INTEGER, INTENT(in)    :: STEP(N)
      INTEGER(8), INTENT(inout) :: PTRAST(KEEP(28)), PAMASTER(KEEP(28))
      INTEGER, INTENT(in)    :: PROCNODE_STEPS(KEEP(28)), DAD(KEEP(28))
      INTEGER, INTENT(inout) :: IFLAG, IERROR
      include 'mumps_headers.h'
      INTEGER    :: ICURRENT, INODE, TYPEINODE, CB_STATE
      INTEGER(8) :: RCURRENT, RCURRENT_SIZE, SIZEHOLE
      INTEGER(8) :: KEEP8TMPCOPY
      LOGICAL    :: MOVE2DYNAMIC
      LOGICAL    :: SSARBRDAD 
      INTEGER(8) :: TMP_ADDRESS, ITMP8
      INTEGER(8) :: I8
      REAL, DIMENSION(:), POINTER :: DYNAMIC_CB
      LOGICAL :: IS_PAMASTER, IS_PTRAST
      INTEGER :: allocok
!$    INTEGER(8) :: CHUNK8 
!$    LOGICAL    :: OMP_FLAG
!$    INTEGER    :: NOMP
      LOGICAL      :: IFLAG_M13_OCCURED, IFLAG_M19_OCCURED
      INTEGER(8)   :: MIN_SIZE_M13, MIN_SIZE_M19
      INTEGER, EXTERNAL :: MUMPS_TYPENODE
      IF ( strategy .EQ. 0 ) THEN
        IF (lrlus.LT.sizer_needed) THEN
          iflag = -9
          CALL mumps_set_ierror(sizer_needed-lrlus, ierror)
        ENDIF
        RETURN
      ENDIF
      iflag_m13_occured  = .false.
      min_size_m13       = huge(min_size_m13)
      iflag_m19_occured  = .false.
      min_size_m19       = huge(min_size_m19)
!$    NOMP = OMP_GET_MAX_THREADS()
      icurrent  = iwposcb + 1 
      rcurrent  = iptrlu  + 1
      IF (strategy.EQ.1 .AND. sizer_needed.LE.lrlus) GOTO 500
      IF (( keep8(73) + sizer_needed-lrlus).GT.
     &               keep8(75)) THEN
           iflag = -19
           CALL mumps_set_ierror
     &       (keep8(73) + sizer_needed-lrlus-keep8(75), ierror)
            GOTO 500
      ENDIF
      DO WHILE (icurrent .NE. liw-keep(ixsz)+1)
        inode        = iw(icurrent+xxn)
        cb_state     = iw(icurrent+xxs)
        CALL mumps_geti8( rcurrent_size, iw(icurrent+xxr))
        CALL smumps_dm_pamasterorptrast( n, slavef, myid, keep(28),
     &                                  keep(199), inode, cb_state,
     &                                  iw(icurrent+xxd:icurrent+xxd+1),
     &                                  step, dad, procnode_steps,
     &                                  rcurrent, pamaster, ptrast,
     &                                  is_pamaster, is_ptrast )
        IF ( cb_state .NE. s_free .AND.
     &       .NOT. smumps_dm_is_dynamic(iw(icurrent+xxd)) ) THEN
          typeinode = mumps_typenode(procnode_steps(step(inode)),
     &                               keep(199))
          IF (strategy .EQ. -1) THEN
            move2dynamic = .false.  
            move2dynamic = move2dynamic .OR.
     &                     cb_state .EQ. s_nolcbcontig .OR.
     &                     cb_state .EQ. s_nolcbnocontig .OR.
     &                     cb_state .EQ. s_nolcleaned .OR.
     &                     cb_state .EQ. s_all .OR.
     &                     cb_state .EQ. s_active
          ELSE IF (strategy .EQ. 2 .OR. strategy .EQ. 3) THEN
            move2dynamic = .true. 
            move2dynamic = move2dynamic .AND. (typeinode.NE.3)
          ELSE IF (strategy .EQ. 1) THEN
            move2dynamic = .false. 
            IF (lrlus.GT.sizer_needed) GOTO 500
            IF (typeinode.EQ.3) GOTO 100
            move2dynamic = move2dynamic.OR..true.
          ELSE
            WRITE(*,*) "Internal error in SMUMPS_DM_CBSTATIC2DYNAMIC",
     &      move2dynamic
            CALL mumps_abort()
          ENDIF
          move2dynamic = move2dynamic .AND. (rcurrent_size .NE. 0_8)
          move2dynamic = move2dynamic .AND. 
     &         .NOT. ((icurrent.EQ.iwposcb + 1).AND.(skip_top_stack))
          IF (strategy .NE. 3) THEN
            IF ( keep(405) .EQ. 1 ) THEN
!$OMP         ATOMIC READ
              keep8tmpcopy = keep8(73)
!$OMP         END ATOMIC
            ELSE
              keep8tmpcopy = keep8(73)
            ENDIF
            IF ( rcurrent_size + keep8tmpcopy .GT. keep8(75) ) THEN
               iflag_m19_occured= .true.
               min_size_m19     = min( min_size_m19,  
     &           rcurrent_size+keep8(73)-keep8(75) )
               move2dynamic = .false.
            ENDIF
          ENDIF
          IF ( move2dynamic ) THEN
#if defined(MUMPS_ALLOC_FROM_C)
            CALL mumps_malloc_c( tmp_address,
     &      rcurrent_size * keep(35) )
            IF (tmp_address .EQ. 0_8) THEN
              allocok=1 
            ELSE 
              allocok=0
            ENDIF
#else
            ALLOCATE(dynamic_cb(rcurrent_size), stat=allocok)
#endif
            IF (allocok .GT. 0) THEN
              IF ( (strategy .NE. 1).OR. 
     &           (sizer_needed-lrlus).GE.rcurrent_size) THEN
                iflag = -13
                CALL mumps_set_ierror(sizer_needed-lrlus, ierror)
                GOTO 500
              ENDIF
              iflag_m13_occured = .true.
              min_size_m13  = min(min_size_m13, rcurrent_size)
              GOTO 100
            ENDIF
            sizehole=0_8
            IF (keep(216).NE.3) THEN
              CALL smumps_sizefreeinrec( iw(icurrent),
     &        liw-icurrent+1, sizehole, keep(ixsz))
            ENDIF
            CALL mumps_storei8(rcurrent_size,iw(icurrent+xxd))
#if defined(MUMPS_ALLOC_FROM_C)
            CALL smumps_dm_set_ptr( tmp_address, rcurrent_size,
     &                              dynamic_cb )
#else
            CALL mumps_addr_c(dynamic_cb(1), tmp_address)
#endif
            IF (is_ptrast) THEN
              ptrast(step(inode)) = tmp_address
            ELSE IF (is_pamaster) THEN
              pamaster(step(inode)) = tmp_address
            ELSE
              WRITE(*,*) 
     &          "Internal error 3 in SMUMPS_DM_CBSTATIC2DYNAMIC",
     &        rcurrent, ptrast(step(inode)), pamaster(step(inode))
              CALL mumps_abort()
            ENDIF
            itmp8 = (rcurrent_size-sizehole)
            lrlus = lrlus + itmp8
            IF (keep(405).EQ.1) THEN
              IF (sizehole .NE. 0_8) THEN
!$OMP           ATOMIC CAPTURE
                keep8(69) = keep8(69) + sizehole
                keep8tmpcopy = keep8(69)
!$OMP           END ATOMIC
!$OMP           ATOMIC UPDATE
                keep8(68) = max( keep8(68), keep8tmpcopy )
!$OMP           END ATOMIC
              ENDIF
            ELSE
              keep8(69) = keep8(69) + sizehole
              keep8(68) = max( keep8(68), keep8(69) )
            ENDIF
            CALL mumps_set_ssarbr_dad(ssarbrdad, inode,
     &           dad, n, keep(28),
     &           step, procnode_steps, keep(199))
            CALL smumps_load_mem_update( ssarbrdad, .false.,
     &      la - lrlus, 0_8, -(rcurrent_size-sizehole),
     &      keep, keep8, lrlus)
            IF (icurrent .EQ. iwposcb+1) THEN
              iptrlu = iptrlu + rcurrent_size
              lrlu = lrlu + rcurrent_size
              CALL mumps_storei8(0_8, iw(icurrent+xxr))
            ENDIF
            IF (strategy .NE. 3) THEN
              CALL mumps_dm_fac_upd_dyn_memcnts (
     &                      rcurrent_size, keep(405).EQ.1, keep8, 
     &                      iflag, ierror, .false., .false.)
              IF (iflag.LT.0) GOTO 500
            ENDIF
!$          CHUNK8 = max( int(KEEP(361),8),
!$   &              (RCURRENT_SIZE+NOMP-1) / NOMP)
!$          OMP_FLAG = ( (RCURRENT_SIZE > int(KEEP(361),8))
!$   &                   .AND.(NOMP.GT.1)
!$   &                  )
!$OMP       PARALLEL DO PRIVATE(I8) SCHEDULE(STATIC, CHUNK8)
!$OMP&      IF (OMP_FLAG) 
             DO i8=1_8, rcurrent_size
               dynamic_cb(i8) = a(rcurrent+i8-1_8)
             ENDDO
!$OMP       END PARALLEL DO 
          ENDIF
        ENDIF
 100    CONTINUE
        rcurrent = rcurrent + rcurrent_size
        icurrent = icurrent + iw(icurrent+xxi)
      END DO
      IF (lrlus.LT.sizer_needed) THEN
        IF (iflag_m19_occured) THEN
            iflag = -19
            CALL mumps_set_ierror(min_size_m19, ierror)
        ELSE IF (iflag_m13_occured) THEN
            iflag = -13
            CALL mumps_set_ierror(min_size_m13, ierror)
        ELSE
            iflag = -9
            CALL mumps_set_ierror(sizer_needed-lrlus, ierror)
        ENDIF
      ENDIF
 500  CONTINUE
      RETURN
      END SUBROUTINE smumps_dm_cbstatic2dynamic
      SUBROUTINE smumps_dm_freealldynamiccb( MYID, N, SLAVEF,
     &           KEEP, KEEP8, IW, LIW, IWPOSCB, IWPOS,
     &           STEP, PTRAST, PAMASTER,
     &           PROCNODE_STEPS, DAD, ATOMIC_UPDATES )
      INTEGER, INTENT(in)  :: N, SLAVEF, KEEP(500)
      INTEGER, INTENT(in)  :: MYID
      INTEGER(8), INTENT(inout) :: KEEP8(150)  
      INTEGER :: IWPOS, IWPOSCB, LIW
      INTEGER, INTENT(inout) :: IW( LIW ) 
      INTEGER, INTENT(in)    :: STEP(N)
      INTEGER(8), INTENT(in) :: PTRAST(KEEP(28)), PAMASTER(KEEP(28))
      INTEGER, INTENT(in)    :: PROCNODE_STEPS(KEEP(28)), DAD(KEEP(28))
      LOGICAL, INTENT(in)    :: ATOMIC_UPDATES
      include 'mumps_headers.h'
      INTEGER :: ICURRENT, INODE
      INTEGER :: CB_STATE
      INTEGER(8) :: DYN_SIZE, TMP_ADDRESS
      INTEGER(8), PARAMETER :: RDUMMY = -987654
      logical :: is_pamaster, is_ptrast
      REAL, DIMENSION(:), POINTER :: TMP_PTR
      icurrent  = iwposcb + 1 
      IF (keep8(73) .NE. 0_8) THEN
       DO WHILE (icurrent .LT. liw-keep(ixsz)+1)
        inode = iw(icurrent+xxn)
        cb_state = iw(icurrent+xxs)
        IF (cb_state.NE.s_free) THEN
         CALL mumps_geti8( dyn_size, iw(icurrent+xxd) )
         IF (dyn_size .GT. 0_8) THEN
          CALL smumps_dm_pamasterorptrast( n, slavef, myid, keep(28),
     &    keep(199), inode, cb_state, iw(icurrent+xxd),
     &    step, dad, procnode_steps,
     &    rdummy, pamaster, ptrast,  
     &    is_pamaster, is_ptrast )
          IF (is_pamaster) THEN
            tmp_address = pamaster(step(inode))
          ELSE IF (is_ptrast) THEN
            tmp_address = ptrast(step(inode))
          ELSE
            WRITE(*,*) "Internal error 1 in SMUMPS_DM_FREEALLDYNAMICCB"
     &      , is_ptrast, is_pamaster
          ENDIF
          CALL smumps_dm_set_ptr(tmp_address, dyn_size, tmp_ptr)
          CALL smumps_dm_free_block( iw(icurrent+xxg),
     &                               tmp_ptr, dyn_size,
     &                               atomic_updates, keep8 )
          CALL mumps_storei8(0_8, iw(icurrent+xxd))
         ENDIF
        ENDIF
        icurrent = icurrent + iw(icurrent+xxi)
       ENDDO
      ENDIF
      RETURN
      END SUBROUTINE smumps_dm_freealldynamiccb
      SUBROUTINE smumps_dm_set_ptr(ADDRESS, SIZFR8, CBPTR)
      USE smumps_static_ptr_m, ONLY : smumps_get_tmp_ptr
      IMPLICIT NONE
      INTEGER(8), INTENT(IN) :: ADDRESS, SIZFR8
#if defined(MUMPS_F2003)
      REAL, DIMENSION(:), POINTER, INTENT(out) :: CBPTR
#else
      REAL, DIMENSION(:), POINTER :: CBPTR
#endif
!$OMP CRITICAL(STATIC_PTR_ACCESS)
      CALL smumps_set_tmp_ptr_c( address, sizfr8 )
      CALL smumps_get_tmp_ptr( cbptr )
!$OMP END CRITICAL(STATIC_PTR_ACCESS)
      RETURN
      END SUBROUTINE smumps_dm_set_ptr
      SUBROUTINE smumps_dm_free_block( XXG_STATUS, DYNPTR, SIZFR8,
     &                                 ATOMIC_UPDATES, KEEP8 )
      IMPLICIT NONE
      include 'mumps_headers.h'
      INTEGER :: XXG_STATUS
      REAL, POINTER, DIMENSION(:) :: DYNPTR
      INTEGER(8) :: SIZFR8
      LOGICAL, INTENT(IN) :: ATOMIC_UPDATES
      INTEGER(8) :: KEEP8(150)
      INTEGER IDUMMY
#if defined(MUMPS_ALLOC_FROM_C)
      CALL MUMPS_FREE_C(DYNPTR(1))
#else
      DEALLOCATE(dynptr)
#endif
      NULLIFY(dynptr)
      CALL mumps_dm_fac_upd_dyn_memcnts (
     &           -sizfr8, atomic_updates, keep8, idummy, idummy,
     &           .true., .false.)
      RETURN
      END SUBROUTINE smumps_dm_free_block
      END MODULE smumps_dynamic_memory_m
      SUBROUTINE smumps_dm_freealldynamiccb_i( MYID, N, SLAVEF,
     &           KEEP, KEEP8, IW, LIW, IWPOSCB, IWPOS,
     &           STEP, PTRAST, PAMASTER,
     &           PROCNODE_STEPS, DAD, ATOMIC_UPDATES )
      USE smumps_dynamic_memory_m, ONLY : smumps_dm_freealldynamiccb
      IMPLICIT NONE
      INTEGER, INTENT(in)  :: N, SLAVEF, KEEP(500)
      INTEGER, INTENT(in)  :: MYID
      INTEGER(8), INTENT(inout) :: KEEP8(150)  
      INTEGER :: IWPOS, IWPOSCB, LIW
      INTEGER, INTENT(inout) :: IW( LIW ) 
      INTEGER, INTENT(in)    :: STEP(N)
      INTEGER(8), INTENT(in) :: PTRAST(KEEP(28)), PAMASTER(KEEP(28))
      INTEGER, INTENT(in)    :: PROCNODE_STEPS(KEEP(28)), DAD(KEEP(28))
      LOGICAL, INTENT(in)    :: ATOMIC_UPDATES
      CALL       SMUMPS_DM_FREEALLDYNAMICCB( MYID, N, SLAVEF,
     &           KEEP, KEEP8, IW, LIW, IWPOSCB, IWPOS,
     &           step, ptrast, pamaster,
     &           procnode_steps, dad, atomic_updates )
      RETURN
      END SUBROUTINE smumps_dm_freealldynamiccb_i
      SUBROUTINE smumps_dm_cbstatic2dynamic_i(
     &           STRATEGY,
     &           SIZER_NEEDED, SKIP_TOP_STACK,
     &           MYID, N, SLAVEF,
     &           KEEP, KEEP8,
     &           IW, LIW, IWPOSCB, IWPOS,
     &           A, LA, LRLU, IPTRLU, LRLUS, 
     &           STEP, PTRAST, PAMASTER,
     &           PROCNODE_STEPS, DAD, IFLAG, IERROR)
      USE smumps_dynamic_memory_m, ONLY : smumps_dm_cbstatic2dynamic
      IMPLICIT NONE
      INTEGER, INTENT(in)  :: STRATEGY
      INTEGER(8), INTENT(in) :: SIZER_NEEDED
      LOGICAL, INTENT(in)    :: SKIP_TOP_STACK
      INTEGER, INTENT(in)  :: N, SLAVEF, KEEP(500)
      INTEGER, INTENT(in)  :: MYID
      INTEGER(8), INTENT(inout) :: KEEP8(150)
      INTEGER :: IWPOS, IWPOSCB, LIW
      INTEGER, INTENT(inout) :: IW( LIW )
      INTEGER(8) :: LA, LRLU, IPTRLU, LRLUS
      REAL, INTENT(in) :: A( LA )
      INTEGER, INTENT(in)    :: STEP(N)
      INTEGER(8), INTENT(inout) :: PTRAST(KEEP(28)), PAMASTER(KEEP(28))
      INTEGER, INTENT(in)    :: PROCNODE_STEPS(KEEP(28)), DAD(KEEP(28))
      INTEGER, INTENT(inout) :: IFLAG, IERROR
      CALL SMUMPS_DM_CBSTATIC2DYNAMIC( STRATEGY,
     &           sizer_needed, skip_top_stack,
     &           myid, n, slavef,
     &           keep, keep8,
     &           iw, liw, iwposcb, iwpos,
     &           a, la, lrlu, iptrlu, lrlus, 
     &           step, ptrast, pamaster,
     &           procnode_steps, dad, iflag, ierror)
      RETURN
      END SUBROUTINE smumps_dm_cbstatic2dynamic_i