sgeodel3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
C-----------------------------------------------
!||====================================================================
!||    sgeodel3      ../engine/source/elements/solid/solide/sgeodel3.F
!||--- called by ------------------------------------------------------
!||    s10forc3      ../engine/source/elements/solid/solide10/s10forc3.F
!||    s20forc3      ../engine/source/elements/solid/solide20/s20forc3.f
!||    s4forc3       ../engine/source/elements/solid/solide4/s4forc3.f
!||    s8eforc3      ../engine/source/elements/solid/solide8e/s8eforc3.F
!||    s8zforc3      ../engine/source/elements/solid/solide8z/s8zforc3.F
!||    sforc3        ../engine/source/elements/solid/solide/sforc3.F
!||    szforc3       ../engine/source/elements/solid/solidez/szforc3.F
!||--- uses       -----------------------------------------------------
!||    dt_mod        ../engine/source/modules/dt_mod.F
!||    message_mod   ../engine/share/message_module/message_mod.F
!||====================================================================
      SUBROUTINE sgeodel3(
     1   NGL,     OFFG,    VOLG,    DELTAX,
     2   VOLG0,   GEO,     L_MAX,   DT,
     3   NEL,     IDEL7NOK)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE message_mod
      USE dt_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
#include      "mvsiz_p.inc"
#include      "comlock.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "units_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(INOUT) :: IDEL7NOK
      INTEGER ,INTENT(IN)  :: NEL
      INTEGER ,DIMENSION(MVSIZ) ,INTENT(IN)  :: NGL
      my_real, DIMENSION(NPROPG) , INTENT(IN)  :: geo 
      my_real, DIMENSION(NEL) , INTENT(IN)  :: volg0 
      my_real, DIMENSION(MVSIZ) , INTENT(IN)  :: volg,deltax,l_max 
      my_real, DIMENSION(NEL) , INTENT(INOUT)  :: offg 
      TYPE(dt_), INTENT(INOUT) :: DT
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,J,ICOUNT,LIST(MVSIZ),ITET
      my_real
     .   TET_COLLA(MVSIZ),DEF_V(MVSIZ),APS_R(MVSIZ),
     .   c_min,al,vdefmin,vdefmax,aspmax,colmin,c_max,gdel
C---------------------------------------------
      vdefmin = max(geo(190),dt%BRICK_DEL_DEFV_MIN)
      vdefmax = geo(191)
      aspmax  = geo(192)
      colmin  = max(geo(193),dt%BRICK_DEL_COL_MIN)
C-----
      gdel=vdefmin+vdefmax+aspmax+colmin
      IF(gdel==zero.AND.dt%IDEL_BRICK==0) RETURN
C-----
      IF(dt%BRICK_DEL_DEFV_MAX>zero .AND. (dt%BRICK_DEL_DEFV_MAX<vdefmax 
     .   .OR.vdefmax==zero) ) vdefmax = dt%BRICK_DEL_DEFV_MAX 
      IF(dt%BRICK_DEL_ASP_MAX>zero .AND. ( dt%BRICK_DEL_ASP_MAX<aspmax 
     .   .OR.aspmax==zero) ) aspmax = dt%BRICK_DEL_ASP_MAX 
      c_min = one
      c_max = one
      IF (l_max(1) >zero) THEN
        itet = 0
      ELSE
        itet = 1
      END IF
C--- tet      
      IF (itet >0) THEN
       c_max = 1.24*sqr3
       c_min = one/c_max
      END IF
C
      IF ((vdefmin+vdefmax) >zero) THEN
        DO i=1,nel
          IF (offg(i)==zero) cycle
          def_v(i) = volg(i)/volg0(i)
        END DO
      END IF
C      
      IF (vdefmin >zero) THEN
       icount = 0
       DO i=1,nel
        IF (offg(i)==zero) cycle
        IF (def_v(i) < vdefmin) THEN
         offg(i) = zero
         icount=icount+1
         list(icount)=i
        END IF
       END DO
       IF (icount > 0) THEN
#include "lockon.inc"
          WRITE(iout,1001)
          WRITE(istdo,1001)
        DO j=1,icount
          i=list(j)
          WRITE(iout,'(6X,I10,1PG20.13)')ngl(i),def_v(i)
          WRITE(istdo,'(6X,I10,1PG20.13)')ngl(i),def_v(i)
        ENDDO
         WRITE(iout,*)
         WRITE(istdo,*)
#include "lockoff.inc"
         idel7nok = 1
       END IF !(ICOUNT > 0) THEN
      END IF 
C       
      IF (vdefmax >zero) THEN
       icount = 0
       DO i=1,nel
        IF (offg(i)==zero) cycle
        IF (def_v(i) > vdefmax) THEN
         offg(i) = zero
         icount=icount+1
         list(icount)=i
        END IF
       END DO
        IF (icount > 0) THEN
#include "lockon.inc"
          WRITE(iout,1002)
          WRITE(istdo,1002)
         DO j=1,icount
          i=list(j)
          WRITE(iout,'(6X,I10,1PG20.13)')ngl(i),def_v(i)
          WRITE(istdo,'(6X,I10,1PG20.13)')ngl(i),def_v(i)
         ENDDO
         WRITE(iout,*)
         WRITE(istdo,*)
#include "lockoff.inc"
         idel7nok = 1
        END IF !(ICOUNT > 0) THEN
      END IF 
C--- Hexa : APS_r=lmax/lmin lmax~sqrt(Amax); lmin~lc & V~ lc*Amax -> 
C---        APS_r~sqrt(Amax/lc^2)=sqrt(V/lc^3) ; now we compute L_max for Hexa   
        IF ((aspmax+colmin) >zero) THEN
          IF (itet ==0) THEN
            DO i=1,nel
              IF (offg(i)==zero) cycle
              aps_r(i) = l_max(i)/deltax(i)
              tet_colla(i) = deltax(i) / l_max(i)
            END DO
          ELSE
            DO i=1,nel
              IF (offg(i)==zero) cycle
              al = sqrt(volg(i)/deltax(i)**3)
              aps_r(i) = c_max*al
              tet_colla(i) = c_min / al
            END DO
          END IF
        END IF
        IF (aspmax>zero) THEN
          icount = 0
          DO i=1,nel
           IF (offg(i)==zero) cycle
           IF (aps_r(i) > aspmax) THEN
            offg(i) = zero
            icount=icount+1
            list(icount)=i
           END IF
          END DO
          IF (icount > 0) THEN
#include "lockon.inc"
              WRITE(iout,1003)
              WRITE(istdo,1003)
            DO j=1,icount
              i=list(j)
              WRITE(iout,'(6X,I10,1PG20.13)')ngl(i),aps_r(i)
              WRITE(istdo,'(6X,I10,1PG20.13)')ngl(i),aps_r(i)
            ENDDO
             WRITE(iout,*)
             WRITE(istdo,*)
#include "lockoff.inc"
            idel7nok = 1
          END IF !(ICOUNT > 0) THEN
        END IF
C
C--- Tet4 : TET_c= h/sqrt(A)/1.24 h~lc; V~ lc*A*2/6 -> 
C---        TET_c~sqrt(h^2/A)/1.24=sqrt(h^3/V)/1.24/sqrt(3)
C---        TET_c =1/ASP_r
        IF (colmin>zero) THEN
          icount = 0
          DO i=1,nel
           IF (offg(i)==zero) cycle
           IF (tet_colla(i) < colmin) THEN
            offg(i) = zero
            icount=icount+1
            list(icount)=i
           END IF
          END DO
          IF (icount > 0) THEN
#include "lockon.inc"
             WRITE(iout,1004)
             WRITE(istdo,1004)
           DO j=1,icount
             i=list(j)
             WRITE(iout,'(6X,I10,1PG20.13)')ngl(i),tet_colla(i)
             WRITE(istdo,'(6X,I10,1PG20.13)')ngl(i),tet_colla(i)
           ENDDO
            WRITE(iout,*)
            WRITE(istdo,*)
#include "lockoff.inc"
            idel7nok = 1
          END IF !(ICOUNT > 0) THEN
        END IF
C
      RETURN
 1001 FORMAT(/
     .    'THE FOLLOWING SOLID ELEMENTS WILL BE DELETED BY MINIMUM VOLUME RATIO' /)
 1002 FORMAT(/
     .    'THE FOLLOWING SOLID ELEMENTS WILL BE DELETED BY MAXIMUM VOLUME RATIO' /)
 1003 FORMAT(/
     .    'THE FOLLOWING SOLID ELEMENTS WILL BE DELETED BY MAXIMUM ASPECT RATIO' /)
 1004 FORMAT(/
     .    'THE FOLLOWING SOLID ELEMENTS WILL BE DELETED BY MINIMUM COLLAPSE RATIO' /)
      END