sgparav3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    sgparav3   ../engine/source/elements/solid/solide/sgparav3.F
!||--- called by ------------------------------------------------------
!||    s6cforc3   ../engine/source/elements/thickshell/solide6c/s6cforc3.F
!||    s8cforc3   ../engine/source/elements/thickshell/solide8c/s8cforc3.F
!||    scforc3    ../engine/source/elements/thickshell/solidec/scforc3.F
!||====================================================================
      SUBROUTINE sgparav3(
     1   NPE,     X,       IXS,     RX,
     2   RY,      RZ,      SX,      SY,
     3   SZ,      TX,      TY,      TZ,
     4   NEL)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      INTEGER NPE
      INTEGER IXS(NIXS,*)
C     REAL
      my_real
     .  x(3,*),rx(*), ry(*), rz(*), sx(*), sy(*), sz(*),
     .  tx(*), ty(*), tz(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,NPE1,N
      INTEGER NC(MVSIZ,NPE)
C     REAL
      my_real
     .  x0(mvsiz,npe), y0(mvsiz,npe), z0(mvsiz,npe)
C-----------------------------------------------
C
      npe1=npe-1
      IF (npe==4.OR.npe==10) THEN
       DO i=1,nel
        nc(i,1)=ixs(2,i)
        nc(i,2)=ixs(4,i)
        nc(i,3)=ixs(7,i)
        nc(i,4)=ixs(6,i)
       ENDDO
      ELSEIF (npe==6) THEN
       DO i=1,nel
        nc(i,1)=ixs(2,i)
        nc(i,2)=ixs(3,i)
        nc(i,3)=ixs(4,i)
        nc(i,4)=ixs(6,i)
        nc(i,5)=ixs(7,i)
        nc(i,6)=ixs(8,i)
       ENDDO
      ELSE
       DO n=1,npe
        DO i=1,nel
         nc(i,n)=ixs(n+1,i)
        ENDDO
       ENDDO
      ENDIF 
C----------------------------
C     NODAL COORDINATES     /
C----------------------------
      DO n=1,npe
       DO i=1,nel
        x0(i,n)=x(1,nc(i,n))
        y0(i,n)=x(2,nc(i,n))
        z0(i,n)=x(3,nc(i,n))
       ENDDO
      ENDDO 
C----------------------------
C     R,S,T     |
C----------------------------
      SELECT CASE (npe)
      CASE(4,10)                                             
       DO i=1,nel
        rx(i) =  x0(i,1) - x0(i,4)
        ry(i) =  y0(i,1) - y0(i,4)
        rz(i) =  z0(i,1) - z0(i,4)
C
        sx(i) =  x0(i,2) - x0(i,4)
        sy(i) =  y0(i,2) - y0(i,4)
        sz(i) =  z0(i,2) - z0(i,4)
C
        tx(i) =  x0(i,3) - x0(i,4)
        ty(i) =  y0(i,3) - y0(i,4)
        tz(i) =  z0(i,3) - z0(i,4)
       ENDDO
      CASE(6)                                          
       DO i=1,nel
        rx(i) =  x0(i,3) + x0(i,6) - x0(i,1)- x0(i,4)
        ry(i) =  y0(i,3) + y0(i,6) - y0(i,1)- y0(i,4)
        rz(i) =  z0(i,3) + z0(i,6) - z0(i,1) - z0(i,4)
C
        sx(i) = (x0(i,4)+x0(i,5)+x0(i,6)-x0(i,1)+x0(i,2)+x0(i,3))*third
        sy(i) = (y0(i,4)+y0(i,5)+y0(i,6)-y0(i,1)+y0(i,2)+y0(i,3))*third
        sz(i) = (z0(i,4)+z0(i,5)+z0(i,6)-z0(i,1)+z0(i,2)+z0(i,3))*third
C
        tx(i) = x0(i,2) + x0(i,5)- x0(i,1) - x0(i,4)
        ty(i) = y0(i,2) + y0(i,5)- y0(i,1) - y0(i,4)
        tz(i) = z0(i,2) + z0(i,5)- z0(i,1) - z0(i,4)
       ENDDO
      CASE(8)                                          
       DO i=1,nel
        rx(i) = x0(i,3)+x0(i,4)+x0(i,7)+x0(i,8)-
     .         (x0(i,1)+x0(i,2)+x0(i,5)+x0(i,6)) 
        ry(i) = y0(i,3)+y0(i,4)+y0(i,7)+y0(i,8)-
     .         (y0(i,1)+y0(i,2)+y0(i,5)+y0(i,6))
        rz(i) = z0(i,3)+z0(i,4)+z0(i,7)+z0(i,8)-
     .         (z0(i,1)+z0(i,2)+z0(i,5)+z0(i,6))
C
        sx(i) = x0(i,5)+x0(i,6)+x0(i,7)+x0(i,8)-
     .         (x0(i,1)+x0(i,2)+x0(i,3)+x0(i,4)) 
        sy(i) = y0(i,5)+y0(i,6)+y0(i,7)+y0(i,8)-
     .         (y0(i,1)+y0(i,2)+y0(i,3)+y0(i,4))
        sz(i) = z0(i,5)+z0(i,6)+z0(i,7)+z0(i,8)-
     .         (z0(i,1)+z0(i,2)+z0(i,3)+z0(i,4))
C
        tx(i) = x0(i,3)+x0(i,2)+x0(i,7)+x0(i,6)-
     .         (x0(i,1)+x0(i,4)+x0(i,5)+x0(i,8)) 
        ty(i) = y0(i,3)+y0(i,2)+y0(i,7)+y0(i,6)-
     .         (y0(i,1)+y0(i,4)+y0(i,5)+y0(i,8))
        tz(i) = z0(i,3)+z0(i,2)+z0(i,7)+z0(i,6)-
     .         (z0(i,1)+z0(i,4)+z0(i,5)+z0(i,8))
C
       ENDDO
      END SELECT 
C
      RETURN
      END