sigeps103_8F_source.html

Copyright>        OpenRadioss

Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.

Copyright>

Copyright>        This program is free software: you can redistribute it and/or modify

Copyright>        it under the terms of the GNU Affero General Public License as published by

Copyright>        the Free Software Foundation, either version 3 of the License, or

Copyright>        (at your option) any later version.

Copyright>

Copyright>        This program is distributed in the hope that it will be useful,

Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of

Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

Copyright>        GNU Affero General Public License for more details.

Copyright>

Copyright>        You should have received a copy of the GNU Affero General Public License

Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.

Copyright>

Copyright>

Copyright>        Commercial Alternative: Altair Radioss Software

Copyright>

Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss

Copyright>        software under a commercial license.  Contact Altair to discuss further if the

Copyright>        commercial version may interest you: https://www.altair.com/radioss/.

!||====================================================================

!||    sigeps103   ../engine/source/materials/mat/mat103/sigeps103.F

!||--- called by ------------------------------------------------------

!||    mulaw       ../engine/source/materials/mat_share/mulaw.F90

!||====================================================================


       SUBROUTINE sigeps103(

     A      NEL     ,NUPARAM ,NUVAR   ,TIME    ,UPARAM  ,UVAR    ,

     C      RHO0    ,RHO     ,VOLUME  ,EINT    ,EPSD    ,TEMP    ,

     D      DEPSXX  ,DEPSYY  ,DEPSZZ  ,DEPSXY  ,DEPSYZ  ,DEPSZX  ,

     E      EPSXX   ,EPSYY   ,EPSZZ   ,EPSXY   ,EPSYZ   ,EPSZX   ,

     F      SIGOXX  ,SIGOYY  ,SIGOZZ  ,SIGOXY  ,SIGOYZ  ,SIGOZX  ,

     G      SIGNXX  ,SIGNYY  ,SIGNZZ  ,SIGNXY  ,SIGNYZ  ,SIGNZX  ,

     H      SIGVXX  ,SIGVYY  ,SIGVZZ  ,SIGVXY  ,SIGVYZ  ,SIGVZX  ,

     I      SOUNDSP ,OFF     ,DPDM    ,PLA     ,JTHE    )


C------------------------------------------------------------------------

C HENSEL SPITTEL Material Law

C NUVAR   NUMBER OF USER ELEMENT VARIABLES

C UVAR    USER ELEMENT VARIABLE ARRAY

C         UVAR(I,1)   = THETA  Temperature

C

C-----------------------------------------------

C   I m p l i c i t   T y p e s

C-----------------------------------------------

#include "implicit_f.inc"

C----------------------------------------------------------------

C  I n p u t   A r g u m e n t s

C----------------------------------------------------------------

      INTEGER NEL, NUPARAM, JTHE,NUVAR

      my_real

     .   TIME       , UPARAM(NUPARAM),

     .   RHO(NEL)   , RHO0(NEL)  , VOLUME(NEL), EINT(NEL),

     .   DEPSXX(NEL), DEPSYY(NEL), DEPSZZ(NEL), DEPSXY(NEL), DEPSYZ(NEL), DEPSZX(NEL),

     .   EPSXX (NEL), EPSYY (NEL), EPSZZ (NEL), EPSXY (NEL), EPSYZ (NEL), EPSZX (NEL),

     .   SIGOXX(NEL), SIGOYY(NEL), SIGOZZ(NEL), SIGOXY(NEL), SIGOYZ(NEL), SIGOZX(NEL),

     .   OFF(NEL)   , DPDM(NEL)  , EPSD(NEL)

C----------------------------------------------------------------

C  O u t p u t   A r g u m e n t s

C----------------------------------------------------------------

      my_real

     .      signxx(nel), signyy(nel), signzz(nel),

     .      signxy(nel), signyz(nel), signzx(nel),

     .      sigvxx(nel), sigvyy(nel), sigvzz(nel),

     .      sigvxy(nel), sigvyz(nel), sigvzx(nel),

     .      soundsp(nel)

C----------------------------------------------------------------

C  I n p u t  O u t p u t   A r g u m e n t s

C----------------------------------------------------------------

      my_real ,DIMENSION(NEL,NUVAR) ,INTENT(INOUT) :: uvar

      my_real ,DIMENSION(NEL)       ,INTENT(INOUT) :: pla

      my_real ,DIMENSION(NEL)       ,INTENT(INOUT) :: temp

C----------------------------------------------------------------

C  L o c a l  V a r i a b l e s

C----------------------------------------------------------------

      INTEGER :: I

      my_real :: DAVG(NEL), POLD(NEL), THETA(NEL), HM(NEL), EPS(NEL)

      my_real :: yld(nel), yld_h(nel), yld_sr(nel), yld_t(nel), svm(nel)

      my_real :: a0, eps0, time_fac, rhocp, tini, eta, t0k, ratio, dpla, g, g2, g3, j2

      my_real :: m1, m2, m3, m4, m5, m7

C----------------------------------------------------------------

C  I n i t i a l i z a t i o n

C----------------------------------------------------------------

      a0      = uparam(1)

      time_fac= uparam(2)

      g       = uparam(3)

      m1      = uparam(4)

      m2      = uparam(5)

      m3      = uparam(6)

      m4      = uparam(7)

      m5      = uparam(8)

      m7      = uparam(9)

      rhocp   = uparam(10)

      tini    = uparam(11)

      eta     = uparam(12)

      t0k     = uparam(13)

      eps0    = uparam(14)

      g2      = two*g

      g3      = three*g


      IF (time == zero) THEN

        uvar(1:nel,1) = tini

      ENDIF


      DO i=1,nel

         pold(i) = -(sigoxx(i)+sigoyy(i)+sigozz(i))*third

         davg(i) =  (depsxx(i)+depsyy(i)+depszz(i))*third

         eps(i)  = eps0 + pla(i)

      ENDDO

C-----------------------------------------------------------------------

C  Elastic deviatoric stress tensor

C-----------------------------------------------------------------------

      DO i=1,nel

         signxx(i)=sigoxx(i)+pold(i)+g2*(depsxx(i)-davg(i))

         signyy(i)=sigoyy(i)+pold(i)+g2*(depsyy(i)-davg(i))

         signzz(i)=sigozz(i)+pold(i)+g2*(depszz(i)-davg(i))

         signxy(i)=sigoxy(i)+g*depsxy(i)

         signyz(i)=sigoyz(i)+g*depsyz(i)

         signzx(i)=sigozx(i)+g*depszx(i)

      ENDDO

C--------------------------------------------------------

C  Sound speed                                                   !

C--------------------------------------------------------

      DO i=1,nel

         dpdm(i)    = dpdm(i) + four_over_3*g

         soundsp(i) = sqrt(abs(dpdm(i))/rho0(i))

      ENDDO

C--------------------------------------------------------

C  Von Mises equivalent stress

C--------------------------------------------------------

      DO i=1,nel

         j2 =half*(signxx(i)**2+signyy(i)**2+signzz(i)**2)+signxy(i)**2+signyz(i)**2+signzx(i)**2

         svm(i) =sqrt(three*j2)

      ENDDO

C--------------------------------------------------------

C     Conversion of Kelvin to Celsius temp used in equations

C--------------------------------------------------------

      IF (jthe >= 0) THEN

         theta(1:nel) = uvar(1:nel,1) - t0k

      ELSE

         theta(1:nel) = temp(1:nel)   - t0k

      ENDIF

C--------------------------------------------------------

C  Yield Stress

C--------------------------------------------------------

C Hardening scale factor

      DO i=1,nel

         yld_h(i) = one

      ENDDO

      IF(m2 /= zero) THEN

        DO i=1,nel

           IF(eps(i) > zero) yld_h(i) = yld_h(i)*eps(i)**m2

        ENDDO

      ENDIF

      IF(m4 /= zero) THEN

          DO i=1,nel

             IF(eps(i) > zero) yld_h(i) = yld_h(i) * exp(m4/eps(i))

          ENDDO

      ENDIF

      IF(m7 /= zero) THEN

          DO i=1,nel

             IF(eps(i) > zero) yld_h(i) = yld_h(i) * exp(m7*eps(i))

          ENDDO

      ENDIF

C Strain rate scale factor; convert strain rate in second-1

      IF(m3 /= zero) THEN

         DO i=1,nel

           yld_sr(i) = (epsd(i)*time_fac)**m3

        ENDDO

      ELSE

        DO i=1,nel

           yld_sr(i) = one

        ENDDO

      ENDIF

C     temperature scale factor

      IF(m1 /= zero .AND. m5 /= zero) THEN

              DO i=1,nel

           yld_t(i) = exp(theta(i)*m1) * (one+eps(i))**(theta(i)*m5)

        ENDDO

      ELSEIF(m1 /= zero) THEN

              DO i=1,nel

           yld_t(i) = exp(theta(i)*m1)

        ENDDO

      ELSEIF(m5 /= zero) THEN

        DO i=1,nel

           yld_t(i) = (one+eps(i))**(theta(i)*m5)

        ENDDO

      ELSE

        DO i=1,nel

           yld_t(i) = one

        ENDDO

      ENDIF

C Yield Stress

      DO i=1,nel

         yld(i) = a0 * yld_h(i) * yld_sr(i) * yld_t(i)

      ENDDO

C----------------------------------------------------------------

C  Compute hardening modulus

C----------------------------------------------------------------

      DO i=1,nel

         hm(i) = m7*yld(i)

      ENDDO

            DO i=1,nel

         IF(eps(i) > zero) hm(i) = hm(i) + yld(i)*(m2-m4/eps(i))/eps(i)

      ENDDO

C----------------------------------------------------------------

C  Update deviatoric stress tensor

C----------------------------------------------------------------

      DO i=1,nel

         ratio = min(one,yld(i)/ max(svm(i),em20))

         ! plastic strain increment.

         dpla = (one-ratio)*svm(i)/max(g3+hm(i),em20)

         ! actual yield stress

         yld(i) = max(yld(i)+dpla*hm(i),zero)

         ratio  = min(one,yld(i)/ max(svm(i),em20))

         signxx(i) = signxx(i)*ratio

         signyy(i) = signyy(i)*ratio

         signzz(i) = signzz(i)*ratio

         signxy(i) = signxy(i)*ratio

         signyz(i) = signyz(i)*ratio

         signzx(i) = signzx(i)*ratio

         pla(i) = pla(i) + dpla

         theta(i) = uvar(i,1) + eta*yld(i)*dpla/rhocp

      ENDDO

C

      DO i=1,nel

         uvar(i,1) = theta(i)

         sigvxx(i) = zero

         sigvyy(i) = zero

         sigvzz(i) = zero

         sigvxy(i) = zero

         sigvyz(i) = zero

         sigvzx(i) = zero

      ENDDO

      IF (jthe == 0) THEN

        temp(1:nel) = theta(1:nel) + t0k

      END IF

!-----------

      RETURN


      END

min
#define min(a, b)
Definition macros.h:20

max
#define max(a, b)
Definition macros.h:21

sigeps103
subroutine sigeps103(nel, nuparam, nuvar, time, uparam, uvar, rho0, rho, volume, eint, epsd, temp, depsxx, depsyy, depszz, depsxy, depsyz, depszx, epsxx, epsyy, epszz, epsxy, epsyz, epszx, sigoxx, sigoyy, sigozz, sigoxy, sigoyz, sigozx, signxx, signyy, signzz, signxy, signyz, signzx, sigvxx, sigvyy, sigvzz, sigvxy, sigvyz, sigvzx, soundsp, off, dpdm, pla, jthe)
Definition sigeps103.F:37