sigeps34.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    sigeps34   ../engine/source/materials/mat/mat034/sigeps34.F
!||--- called by ------------------------------------------------------
!||    mulaw      ../engine/source/materials/mat_share/mulaw.F90
!||    mulaw8     ../engine/source/materials/mat_share/mulaw8.F90
!||====================================================================
      SUBROUTINE sigeps34(
     1      NEL    , NUPARAM, NUVAR   , NFUNC , IFUNC , NPF   ,
     2      TF     , TIME   , TIMESTEP, UPARAM, RHO0  , RHO   ,
     3      VOLUME , EINT   ,
     4      EPSPXX , EPSPYY , EPSPZZ  , EPSPXY, EPSPYZ, EPSPZX, 
     5      DEPSXX , DEPSYY , DEPSZZ  , DEPSXY, DEPSYZ, DEPSZX,
     6      EPSXX  , EPSYY  , EPSZZ   , EPSXY , EPSYZ , EPSZX ,
     7      SIGOXX , SIGOYY , SIGOZZ  , SIGOXY, SIGOYZ, SIGOZX,
     8      SIGNXX , SIGNYY , SIGNZZ  , SIGNXY, SIGNYZ, SIGNZX,
     9      SIGVXX , SIGVYY , SIGVZZ  , SIGVXY, SIGVYZ, SIGVZX,
     A      SOUNDSP, VISCMAX, UVAR    , OFF                    )
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C----------------------------------------------------------------
C  I N P U T   A R G U M E N T S
C----------------------------------------------------------------
      INTEGER NEL, NUPARAM, NUVAR
      my_real
     .      TIME       , TIMESTEP   , UPARAM(NUPARAM),
     .      RHO   (NEL), RHO0  (NEL), VOLUME(NEL), EINT(NEL),
     .      EPSPXX(NEL), EPSPYY(NEL), EPSPZZ(NEL),
     .      EPSPXY(NEL), EPSPYZ(NEL), EPSPZX(NEL),
     .      DEPSXX(NEL), DEPSYY(NEL), DEPSZZ(NEL),
     .      DEPSXY(NEL), DEPSYZ(NEL), DEPSZX(NEL),
     .      EPSXX (NEL), EPSYY (NEL), EPSZZ (NEL),
     .      EPSXY (NEL), EPSYZ (NEL), EPSZX (NEL),
     .      sigoxx(nel), sigoyy(nel), sigozz(nel),
     .      sigoxy(nel), sigoyz(nel), sigozx(nel)
C----------------------------------------------------------------
C  O U T P U T   A R G U M E N T S
C----------------------------------------------------------------
      my_real
     .      signxx(nel), signyy(nel), signzz(nel),
     .      signxy(nel), signyz(nel), signzx(nel),
     .      sigvxx(nel), sigvyy(nel), sigvzz(nel),
     .      sigvxy(nel), sigvyz(nel), sigvzx(nel),
     .      soundsp(nel), viscmax(nel)
C----------------------------------------------------------------
C  I N P U T  O U T P U T   A R G U M E N T S
C----------------------------------------------------------------
      my_real uvar(nel,nuvar), off(nel) 
C----------------------------------------------------------------
C  VARIABLES FOR FUNCTION INTERPOLATION 
C----------------------------------------------------------------
      INTEGER NPF(*), NFUNC, IFUNC(NFUNC)
      my_real TF(*)
C----------------------------------------------------------------
C  L O C A L  V A R I B L E S
C----------------------------------------------------------------
      INTEGER :: I
      my_real :: bulk,bulk3,g_ins,g_inf,ge,ge2,gv,gv2,c1,c2,beta,p0,phi,
     .   gama0,dp_drho
      my_real ,DIMENSION(NEL) :: gama,dpdgama,dp,
     .   depsm,epspm,em,depsvxx,depsvyy,depsvzz,depsvxy,depsvyz,depsvzx,
     .   dexx,deyy,dezz,dexy,deyz,dezx,depsdxx,depsdyy,depsdzz,
     .   depsdxy,depsdyz,depsdzx,ddexx,ddeyy,ddezz,ddexy,ddeyz,ddezx
C=======================================================================
      bulk  = uparam(1)     
      g_ins = uparam(2)        ! instant shear modulus
      g_inf = uparam(3)        ! long term shear modulus
      beta  = uparam(4)
      p0    = uparam(5)
      phi   = uparam(6)
      gama0 = uparam(7)
c      
      ge  = g_inf              ! elastic part of shear modulus
      gv  = g_ins-g_inf        ! viscous part of shear modulus
      ge2 = ge * two
      gv2 = gv * two
      c1  = one - exp(-beta*timestep)
      c2  =-c1 / beta
      bulk3 = bulk*three
c
      DO i=1,nel
        gama(i) = rho0(i)/rho(i) - one + gama0
        dpdgama(i)=-p0*(one-phi) / (one+gama(i)-phi)
        depsm(i) = third *(depsxx(i)+depsyy(i)+depszz(i))
        epspm(i) = third *(epspxx(i)+epspyy(i)+epspzz(i))
        em(i)    = third *(epsxx(i) +epsyy(i) +epszz(i) )
      END DO
c
c     Deviators of strain, strain increment and strain rate       
c
      DO i=1,nel
        dexx(i) = epsxx(i)-em(i)
        deyy(i) = epsyy(i)-em(i)
        dezz(i) = epszz(i)-em(i)
        dexy(i) = epsxy(i)
        deyz(i) = epsyz(i)
        dezx(i) = epszx(i) 
c
        ddexx(i) = depsxx(i)-depsm(i)
        ddeyy(i) = depsyy(i)-depsm(i)
        ddezz(i) = depszz(i)-depsm(i)
        ddexy(i) = depsxy(i)
        ddeyz(i) = depsyz(i)
        ddezx(i) = depszx(i)
c
        depsdxx(i) = epspxx(i)-epspm(i)
        depsdyy(i) = epspyy(i)-epspm(i)
        depsdzz(i) = epspzz(i)-epspm(i)
        depsdxy(i) = epspxy(i)
        depsdyz(i) = epspyz(i)
        depsdzx(i) = epspzx(i)
      END DO
 
      DO i=1,nel
        depsvxx(i) = c1*(dexx(i)-uvar(i,1)) + c2*depsdxx(i)
        depsvyy(i) = c1*(deyy(i)-uvar(i,2)) + c2*depsdyy(i)
        depsvzz(i) = c1*(dezz(i)-uvar(i,3)) + c2*depsdzz(i)
        depsvxy(i) = c1*(dexy(i)-uvar(i,4)) + c2*depsdxy(i)
        depsvyz(i) = c1*(deyz(i)-uvar(i,5)) + c2*depsdyz(i)
        depsvzx(i) = c1*(dezx(i)-uvar(i,6)) + c2*depsdzx(i)
      END DO
 
      dp(1:nel) = (bulk3 - dpdgama(1:nel)) * depsm(1:nel)
 
      DO i=1,nel
        signxx(i) = sigoxx(i) + ge2*ddexx(i) - gv2*depsvxx(i) + dp(i)
        signyy(i) = sigoyy(i) + ge2*ddeyy(i) - gv2*depsvyy(i) + dp(i)
        signzz(i) = sigozz(i) + ge2*ddezz(i) - gv2*depsvzz(i) + dp(i)
        signxy(i) = sigoxy(i) + ge *ddexy(i) - gv *depsvxy(i)
        signyz(i) = sigoyz(i) + ge *ddeyz(i) - gv *depsvyz(i)
        signzx(i) = sigozx(i) + ge *ddezx(i) - gv *depsvzx(i)
      END DO        
c
      dp_drho = four_over_3*g_ins + bulk
      soundsp(1:nel) = sqrt(dp_drho / rho0(1:nel))
c
      DO i=1,nel
        uvar(i,1) = uvar(i,1) + depsvxx(i) + ddexx(i)
        uvar(i,2) = uvar(i,2) + depsvyy(i) + ddeyy(i)
        uvar(i,3) = uvar(i,3) + depsvzz(i) + ddezz(i)
        uvar(i,4) = uvar(i,4) + depsvxy(i) + ddexy(i)
        uvar(i,5) = uvar(i,5) + depsvyz(i) + ddeyz(i)
        uvar(i,6) = uvar(i,6) + depsvzx(i) + ddezx(i)
      END DO
c-----------
      RETURN
      END