sigeps34pi.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    sigeps34pi   ../engine/source/materials/mat/mat034/sigeps34pi.f
!||--- called by ------------------------------------------------------
!||    mulaw_ib     ../engine/source/elements/beam/mulaw_ib.F
!||====================================================================
      SUBROUTINE sigeps34pi(
     1               NEL     ,NUPARAM ,UPARAM  ,IPM     ,IMAT    ,
     2               NUVAR   ,UVAR    ,DEPSXX  ,DEPSXY  ,DEPSXZ  ,
     3               EPSXX   ,SIGOXX  ,SIGOXY  ,SIGOXZ  , 
     5               SIGNXX  ,SIGNXY  ,SIGNXZ  ,TIMESTEP,
     6               EPSXY   ,EPSXZ    )      
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C---------+---------+---+---+--------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
#include      "com04_c.inc"
C-----------------------------------------------
C   I N P U T   A r g u m e n t s
C-----------------------------------------------
      INTEGER ,INTENT(IN) :: IMAT
      INTEGER ,INTENT(IN) :: NEL,NUPARAM,NUVAR
      INTEGER ,DIMENSION(NPROPMI,NUMMAT) ,INTENT(IN) :: IPM
      my_real :: TIMESTEP
      my_real ,DIMENSION(NEL) ,INTENT(IN) :: 
     .   epsxx,depsxx,depsxy,depsxz,sigoxx,sigoxy,sigoxz,
     .   epsxy,epsxz
      my_real ,DIMENSION(*) ,INTENT(IN) :: uparam
C-----------------------------------------------
C   O U T P U T   A r g u m e n t s
C-----------------------------------------------
      my_real ,DIMENSION(NEL) ,INTENT(OUT)   :: signxx,signxy,signxz
      my_real ,DIMENSION(NEL,NUVAR) ,INTENT(INOUT):: uvar
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: I,IADBUF
      my_real :: ddexx,ddexy,ddexz,depsdxx,dexx,depsvxx,depsvxy,depsvxz,dp
      my_real, DIMENSION(NEL) :: bulk,g_ins,g_inf,ge,ge2,gv,gv2,beta,c1,c2,
     .      epspxx,epspxy,epspxz            
C=======================================================================
!!      SHFACT = FIVE_OVER_6
c
      iadbuf = ipm(7,imat)-1
      DO i=1,nel
        bulk(i)  = uparam(iadbuf+1)
        g_ins(i) = uparam(iadbuf+2)
        g_inf(i) = uparam(iadbuf+3)
        beta(i)  = uparam(iadbuf+4)
      ENDDO
c        
      ge(1:nel)  = g_inf(1:nel)                ! elastic part of shear modulus
      gv(1:nel)  = g_ins(1:nel) - g_inf(1:nel)   ! viscous part of shear modulus
      ge2(1:nel) = ge(1:nel) * two
      gv2(1:nel) = gv(1:nel) * two
      c1(1:nel)  = one - exp(-beta(1:nel)*timestep)
      c2(1:nel)  =-c1(1:nel) / beta(1:nel)
      epspxx(1:nel) = depsxx(1:nel)/max(em20,timestep)
      epspxy(1:nel) = depsxy(1:nel)/max(em20,timestep)
      epspxz(1:nel) = depsxz(1:nel)/max(em20,timestep)
c      
      DO i=1,nel
        ddexx = two_third*depsxx(i)
        ddexy = depsxy(i)
        ddexz = depsxz(i)
        
        depsdxx = two_third*epspxx(i)
        dexx = two_third*epsxx(i)
        !
        depsvxx = c1(i)*(dexx     - uvar(i,1)) + c2(i)*depsdxx
        depsvxy = c1(i)*(epsxy(i) - uvar(i,2)) + c2(i)*epspxy(i)
        depsvxz = c1(i)*(epsxz(i) - uvar(i,3)) + c2(i)*epspxz(i)
        dp  = bulk(i)*depsxx(i)
        !!        
        signxx(i) = sigoxx(i) + ge2(i)*ddexx - gv2(i)*depsvxx + dp
        signxy(i) = sigoxy(i) + ge(i) *ddexy - gv(i) *depsvxy
        signxz(i) = sigoxz(i) + ge(i) *ddexz - gv(i) *depsvxz
        
        uvar(i,1) = uvar(i,1) + depsvxx + ddexx
        uvar(i,2) = uvar(i,2) + depsvxy + ddexy
        uvar(i,3) = uvar(i,3) + depsvxz + ddexz
c
      END DO
c-----------
      RETURN
      END