sktvonm3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    sktvonm3   ../engine/source/elements/solid/solide8z/sktvonm3.F
!||--- called by ------------------------------------------------------
!||    mmstifs    ../engine/source/elements/solid/solide8z/mmstifs.F
!||====================================================================
      SUBROUTINE sktvonm3(LFT ,LLT ,DD  ,HH   ,SIG  ,
     .                    DD1 ,GT  ,HT  ,NEL  )
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER LFT,LLT,NEL
C     REAL
      my_real
     .   dd(3,3,*),hh(2,*),sig(nel,6),dd1(3,3,*),gt(3,3,*),ht(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,J,K
C     REAL
      my_real
     .   ss(3,mvsiz),st(3,mvsiz),p,sigy2,g(mvsiz),
     .   ss2,ds2,st2,norm(mvsiz),normi,g2,tt,tv
      my_real    
     .   ew(3,mvsiz),tol,lamda(mvsiz),ev(3,3),kk(3,3)
C
      tol=em5
C----------  verifier-------------------------------------
      DO i=lft,llt
         g(i) = hh(2,i)
         g2 = two*g(i)
         tv=hh(1,i)
         tt=tv+g2
         dd(1,1,i)=tt
         dd(2,2,i)=tt
         dd(3,3,i)=tt
         dd(1,2,i)=tv
         dd(1,3,i)=tv
         dd(2,3,i)=tv
         dd(2,1,i)=tv
         dd(3,1,i)=tv
         dd(3,2,i)=tv
         DO j=1,3
          gt(j,j,i)=g2
         ENDDO
      ENDDO
C----------HT(i)>0 
      DO i=lft,llt
       IF (ht(i)>zero) THEN
        p  =-third*(sig(i,1)+sig(i,2)+sig(i,3))
        ss(1,i)=sig(i,1)+p
        ss(2,i)=sig(i,2)+p
        ss(3,i)=sig(i,3)+p
        st(1,i)=sig(i,4)
        st(2,i)=sig(i,5)
        st(3,i)=sig(i,6)
       ENDIF 
      ENDDO
C      
      DO i=lft,llt
       IF (ht(i)>zero) THEN
        ss2=(ss(1,i)**2+ss(2,i)**2+ss(3,i)**2)*half
        st2=st(1,i)**2+st(2,i)**2+st(3,i)**2
        sigy2=max(em20,three*(ss2+st2))
        ds2=three*g(i)+ht(i)
        norm(i)=three*g(i)/sqrt(ds2*sigy2)
       ENDIF
      ENDDO
C      
      DO i=lft,llt
       IF (ht(i)>zero) THEN
        DO j=1,3
         ss(j,i)=ss(j,i)*norm(i)
         st(j,i)=st(j,i)*norm(i)
        ENDDO
       ENDIF 
      ENDDO
C-----------GT->u-------- 
      DO i=lft,llt
       IF (ht(i)>zero) THEN
        DO j=1,3
        DO k=j,3
         dd(j,k,i)=dd(j,k,i)-ss(j,i)*ss(k,i)
         gt(j,k,i)=gt(j,k,i)*half-st(j,i)*st(k,i)
         dd(k,j,i)=dd(j,k,i)
         gt(k,j,i)=gt(j,k,i)
        ENDDO
        ENDDO
        DO j=1,3
        DO k=1,3
         dd1(j,k,i)=-ss(j,i)*st(k,i)
        ENDDO
        ENDDO
       ENDIF 
      ENDDO
C
      RETURN
      END