sms_gravit.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    sms_gravit         ../engine/source/ams/sms_gravit.F
!||--- called by ------------------------------------------------------
!||    sms_mass_scale_2   ../engine/source/ams/sms_mass_scale_2.F
!||--- calls      -----------------------------------------------------
!||    finter             ../engine/source/tools/curve/finter.F
!||--- uses       -----------------------------------------------------
!||    finter_mixed_mod   ../engine/source/tools/finter_mixed.F90
!||    python_funct_mod   ../common_source/modules/python_mod.F90
!||    sensor_mod         ../common_source/modules/sensor_mod.F90
!||====================================================================
      SUBROUTINE sms_gravit(IGRV  ,AGRV   ,NPC   ,TF   ,A     ,
     2                      V     ,X      ,SKEW  ,MS   ,SENSOR_TAB,
     3                      WEIGHT,IB    ,ITASK,TAGSLV_RBY_SMS,NSENSOR, WFEXT,python)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------  
      USE python_funct_mod, ONLY : python_
      use finter_mixed_mod, only : finter_mixed
      USE sensor_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
#include      "comlock.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
!#include      "com06_c.inc"
#include      "com08_c.inc"
#include      "task_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NPC(*),NDDIM,NVDIM,NSENSOR
      INTEGER IGRV(NIGRV,*),IB(*)
      INTEGER WEIGHT(*), ITASK, TAGSLV_RBY_SMS(*)
      my_real
     .   agrv(lfacgrv,*), tf(*), a(3,*), v(3,*), ms(*),
     .   x(3,*), skew(lskew,*)
      TYPE (SENSOR_STR_) ,DIMENSION(NSENSOR) ,INTENT(IN) :: SENSOR_TAB
      DOUBLE PRECISION,INTENT(INOUT) :: WFEXT
      TYPE(python_), intent(inout) :: python
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER NL, N1, ISK, N2, IFUNC, K1, K2, K3, ISENS,K,NN,IAD,J, IADF, IADL
      my_real NX, NY, NZ, AXI, A0, AA, VV, FX, FY, FZ, AX,  TS,GAMA, WFEXTT,FCX,FCY
      my_real,EXTERNAL :: finter
C=======================================================================
      wfextt=zero
C
      DO nl=1,ngrav
        fcy = agrv(1,nl)
        fcx = agrv(2,nl)
        nn=igrv(1,nl)
        isk=igrv(2,nl)/10
        n2 =igrv(2,nl)-10*isk
        ifunc=igrv(3,nl)
        iad=igrv(4,nl)
        iadf = iad+itask*nn/nthread
        iadl = iad-1+(itask+1)*nn/nthread
C
        isens=0
        DO k=1,nsensor
          IF(igrv(6,nl)== sensor_tab(k)%SENS_ID) isens=k ! do it in starter !!!
        ENDDO
        IF(isens==0)THEN
          ts=tt
        ELSE
          ts = tt-sensor_tab(isens)%TSTART
          IF(ts<0.0)cycle
        ENDIF
C
        IF (ifunc > 0) THEN
          a0   = fcy*finter_mixed(python,nfunct,ifunc,(ts-dt1)*fcx,npc,tf)
          gama = fcy*finter_mixed(python,nfunct,ifunc,ts*fcx,npc,tf)
        ELSE
          a0   = fcy
          gama = fcy
        ENDIF
C
        aa = gama
        IF(isk<=1)THEN
#include "vectorize.inc"
          DO j=iadf,iadl
            n1=iabs(ib(j))
            IF(tagslv_rby_sms(n1)/=0) cycle
            a(n2,n1)=a(n2,n1)+ms(n1)*aa
            IF(ib(j)>0) wfextt=wfextt + half*(a0+aa)*ms(n1)*v(n2,n1)*dt1*weight(n1)
          ENDDO
        ELSE
          k1=3*n2-2
          k2=3*n2-1
          k3=3*n2
#include "vectorize.inc"
          DO j=iadf,iadl
            n1=iabs(ib(j))
            IF(tagslv_rby_sms(n1)/=0) cycle
            vv = skew(k1,isk)*v(1,n1)+skew(k2,isk)*v(2,n1)+skew(k3,isk)*v(3,n1)
            a(1,n1)=a(1,n1)+skew(k1,isk)*ms(n1)*aa
            a(2,n1)=a(2,n1)+skew(k2,isk)*ms(n1)*aa
            a(3,n1)=a(3,n1)+skew(k3,isk)*ms(n1)*aa
            IF(ib(j)>0) wfextt=wfextt+half*(a0+aa)*ms(n1)*vv*dt1*weight(n1)
          ENDDO
        ENDIF
      END DO
C
!$OMP ATOMIC
      wfext = wfext + wfextt
C
      RETURN
      END