split_cfd_solide.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
        
!||====================================================================
!||    split_cfd_solide       ../starter/source/spmd/split_cfd_solide.F
!||--- called by ------------------------------------------------------
!||    lectur                 ../starter/source/starter/lectur.F
!||--- calls      -----------------------------------------------------
!||    plist_ifront           ../starter/source/spmd/node/ddtools.F
!||--- uses       -----------------------------------------------------
!||    split_cfd_mod          ../starter/share/modules1/split_cfd_mod.F
!||====================================================================
        SUBROUTINE split_cfd_solide(NUMELS,ALE_CONNECTIVITY,IXS,ALE_ELM,SIZE_ALE_ELM)
!$COMMENT
!       SPLIT_CFD_SOLIDE description :
!              SPLIT_CFD_SOLIDE retains all the useful solid elements
!              for the splitting in DDSPLIT for each domain in order to 
!              avoid a quadratic loop in DDSPLIT
!       SPLIT_CFD_SOLIDE organization :
!               - first allocation of ALE_ELM%SOL_ID array
!               - for each solid element, if a neighbouring element 
!                 is useful for the splitting, catch the processor list
!               - fill the ALE_ELM array and if the ALE_ELM size is not
!                 sufficient, then increase the size
!$ENDCOMMENT
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
        USE split_cfd_mod
        USE ale_connectivity_mod
        use element_mod , only : nixs
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
        INTEGER, INTENT(IN) :: NUMELS
        INTEGER, DIMENSION(NIXS,*), INTENT(IN) :: IXS    
        INTEGER, DIMENSION(NSPMD) :: SIZE_ALE_ELM  
        TYPE(split_cfd_type), DIMENSION(NSPMD), INTENT(INOUT) :: ALE_ELM
        TYPE(t_ale_connectivity), INTENT(INOUT) :: ALE_CONNECTIVITY
!       -*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-**-*-*-*-*-*-*-*-*-*-*-*-*
!       NUMELS   : integer ; number of solid element
!       NIXS     : integer ; dimension of IXS array
 
!       IXS      : integer ; dimension=NIXS,NUMELS ; property of solid element
!       SIZE_ALE_ELM : integer ; dimension=nspmd ; size of ale_elm%SOL_ID array
!       ALE_ELM : split_cfd_type ; dimension=NSPMD ; solid element ID used 
!                 during the domain splitting (ALE part)
!       -*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-**-*-*-*-*-*-*-*-*-*-*-*-*
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
        LOGICAL, DIMENSION(NSPMD) :: BOOL
        INTEGER :: I,J,K,L,N,NS,IAD1,LGTH
        INTEGER :: SOLV,ISPMD,NBR_PROC,NEW_SIZE_II,MIN_SIZE
        INTEGER, DIMENSION(NSPMD) :: ID_SPMD,II
        INTEGER, DIMENSION(:), ALLOCATABLE :: TMP   
C ----------------------------------------
 
        !       -----------------------------
        !       allocation of ALE_ELM (overestimation of the size)
        size_ale_elm(1:nspmd) = numels/nspmd+1
        DO ispmd=1,nspmd
                ALLOCATE( ale_elm(ispmd)%SOL_ID(size_ale_elm(ispmd)) )
        ENDDO
        !       -----------------------------
        ii(1:nspmd) = 0
        DO i=1,numels
                !       -----------------------------
                ! check if a neighbouring element is used
                bool(1:nspmd)=.false.
                iad1 = ale_connectivity%ee_connect%iad_connect(i)
                lgth = ale_connectivity%ee_connect%iad_connect(i+1)-ale_connectivity%ee_connect%iad_connect(i)
                DO j=1,8
                  ns = ixs(j+1,i)
                  DO k=1,lgth
                    solv = ale_connectivity%ee_connect%connected(iad1 + k - 1)
                    IF (solv>0) THEN
                      DO l=1,8
                        n = ixs(l+1,solv)
                        CALL plist_ifront(id_spmd,n,nbr_proc)
                        DO ispmd=1,nbr_proc
                          bool(id_spmd(ispmd)) = .true.
                        ENDDO
                      ENDDO
                    ENDIF
                  ENDDO
                ENDDO
                !       -----------------------------
                !       fill the ALE_ELM array / increase the size
                DO ispmd=1,nspmd
                  IF( bool(ispmd) ) THEN
                    ii(ispmd) = ii(ispmd) + 1
                    IF( ii(ispmd)>size_ale_elm(ispmd) ) THEN
                      !       need to check the size for small test, ie. when NUMELS < NSPMS
                      min_size=max(1,5* numels/ ( 4*nspmd ))
                      new_size_ii = size_ale_elm(ispmd) + min_size
                      ALLOCATE( tmp( new_size_ii ) )
                      tmp(1:size_ale_elm(ispmd)) = ale_elm(ispmd)%SOL_ID( 1:size_ale_elm(ispmd) )
                      CALL move_alloc(from=tmp,to=ale_elm(ispmd)%SOL_ID)
                      size_ale_elm(ispmd) = new_size_ii
                    ENDIF
                    ale_elm(ispmd)%SOL_ID(ii(ispmd)) = i
                  ENDIF
                ENDDO
                !       -----------------------------
        ENDDO
        !       -----------------------------
 
        size_ale_elm(1:nspmd) = ii(1:nspmd)
 
        RETURN
        END SUBROUTINE split_cfd_solide
 
 
 
!||====================================================================
!||    deallocate_split_cfd_solide   ../starter/source/spmd/split_cfd_solide.F
!||--- called by ------------------------------------------------------
!||    lectur                        ../starter/source/starter/lectur.F
!||--- uses       -----------------------------------------------------
!||    split_cfd_mod                 ../starter/share/modules1/split_cfd_mod.F
!||====================================================================
        SUBROUTINE deallocate_split_cfd_solide(ALE_ELM)
!$COMMENT
!       DEALLOCATE_SPLIT_CFD_SOLIDE description :
!              DEALLOCATE_SPLIT_CFD_SOLIDE deallocates the
!               ALE_ELM array
!       DEALLOCATE_SPLIT_CFD_SOLIDE organization :
!               - loop over NSPMD + deallocation
!$ENDCOMMENT
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
        USE split_cfd_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
        TYPE(split_cfd_type), DIMENSION(NSPMD), INTENT(INOUT) :: ALE_ELM 
!       -*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-**-*-*-*-*-*-*-*-*-*-*-*-*
!       ALE_ELM : split_cfd_type ; dimension=NSPMD ; solid element ID used 
!                 during the domain splitting (ALE part)
!       -*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-**-*-*-*-*-*-*-*-*-*-*-*-*
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
        INTEGER :: ISPMD
C ----------------------------------------
        DO ispmd=1,nspmd
                IF( ALLOCATED(ale_elm(ispmd)%SOL_ID) ) DEALLOCATE( ale_elm(ispmd)%SOL_ID )
        ENDDO
        RETURN
        END SUBROUTINE deallocate_split_cfd_solide