spmd_collect_seatbelt.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
C
!||====================================================================
!||    spmd_collect_seatbelt   ../engine/source/mpi/output/spmd_collect_seatbelt.F
!||--- called by ------------------------------------------------------
!||    hist2                   ../engine/source/output/th/hist2.F
!||--- calls      -----------------------------------------------------
!||--- uses       -----------------------------------------------------
!||    seatbelt_mod            ../common_source/modules/seatbelt_mod.F
!||    spmd_comm_world_mod     ../engine/source/mpi/spmd_comm_world.F90
!||====================================================================
      SUBROUTINE spmd_collect_seatbelt()
C-----------------------------------------------
      USE seatbelt_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
        USE spmd_comm_world_mod, ONLY : spmd_comm_world
#include      "implicit_f.inc"
C-----------------------------------------------------------------
C   M e s s a g e   P a s s i n g
C-----------------------------------------------
#include "spmd.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "task_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   L o c a l  V a r i a b l e s
C-----------------------------------------------
#ifdef MPI
      INTEGER MSGTYP,MSGOFF,IERROR,LOC_PROC,NN,L,I,K,M,N,II,J,
     .        IDEB,SIZ,A_AR,NBIRECV,INDEX,
     .        IRINDEX(NSPMD),REQ_R(NSPMD),IAD_RECV(NSPMD),
     .        STATUS(MPI_STATUS_SIZE)
      my_real
     .        sbuf(7*nslipring+4*nretractor),rbuf(7*nslipring_g+4*nretractor_g),fac
      DATA msgoff/203/
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
      loc_proc = ispmd + 1
C
      IF (loc_proc==1) THEN
        ideb = 1
C
        DO ii = 1, nseatbelt_th_proc
          i = seatbelt_th_exch(ii)%ID_PROC
          iad_recv(i) = ideb
          irindex(ii) = i
          siz = 7*seatbelt_th_exch(ii)%NSLIPRING + 4*seatbelt_th_exch(ii)%NRETRACTOR
          msgtyp = msgoff 
          CALL mpi_irecv(
     s    rbuf(ideb),siz,real,it_spmd(i),msgtyp,
     g    spmd_comm_world,req_r(ii),ierror)
          ideb = ideb + siz
        END DO
C
        DO ii = 1, nseatbelt_th_proc
          CALL mpi_waitany(nseatbelt_th_proc,req_r,index,status,ierror)
          i = irindex(index)
          l = iad_recv(i)
C
          DO n = 1,seatbelt_th_exch(index)%NSLIPRING
            k = nint(rbuf(l))
            DO m=1,6
              th_slipring(k,m) = rbuf(l+m)
            ENDDO
            l = l + 7
          END DO
C
          DO n = 1,seatbelt_th_exch(index)%NRETRACTOR
            k = nint(rbuf(l))
            DO m=1,3
              th_retractor(k,m) = rbuf(l+m)
            ENDDO
            l = l + 4
          END DO
        END DO
C
      ELSE
C
        k = 0
        sbuf = 0
C
        DO n = 1, nslipring
          sbuf(k+1) = slipring(n)%IDG
          k = k + 1
          fac = one/slipring(n)%NFRAM
          DO l = 1,slipring(n)%NFRAM
C--         IF NFRAM > 1 - RINGLSIP and BETA are average of the 1d sliprings - FORCE is the sum - GAMMA = ZERO
            sbuf(k+1) = sbuf(k+1) + fac*slipring(n)%FRAM(l)%RINGSLIP
            sbuf(k+2) = sbuf(k+2) + slipring(n)%FRAM(l)%SLIP_FORCE(3)
            sbuf(k+3) = sbuf(k+3) + slipring(n)%FRAM(l)%SLIP_FORCE(1)
            sbuf(k+4) = sbuf(k+4) + slipring(n)%FRAM(l)%SLIP_FORCE(2)
            sbuf(k+5) = sbuf(k+5) + fac*slipring(n)%FRAM(l)%BETA
            sbuf(k+6) = sbuf(k+6) + fac*slipring(n)%FRAM(l)%ORIENTATION_ANGLE
          END DO
          k = k + 6
        END DO
C
        DO n = 1, nretractor
          sbuf(k+1) = retractor(n)%IDG
          sbuf(k+2) = retractor(n)%RINGSLIP
          sbuf(k+3) = retractor(n)%RET_FORCE
          sbuf(k+4) = retractor(n)%LOCKED
          k = k + 4
        END DO
C
        siz = k
        IF (siz > 0) THEN
          msgtyp=msgoff
          CALL mpi_send(sbuf,siz,real,it_spmd(1),msgtyp,
     g                  spmd_comm_world,ierror)
        ENDIF
C
      END IF
C
#endif
      RETURN
      END