spmd_collectm.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
C
!||====================================================================
!||    spmd_collectm         ../engine/source/mpi/output/spmd_collectm.F
!||--- called by ------------------------------------------------------
!||    resol                 ../engine/source/engine/resol.F
!||--- calls      -----------------------------------------------------
!||    my_orders             ../common_source/tools/sort/my_orders.c
!||--- uses       -----------------------------------------------------
!||    inoutfile_mod         ../common_source/modules/inoutfile_mod.F
!||    spmd_comm_world_mod   ../engine/source/mpi/spmd_comm_world.F90
!||====================================================================
      SUBROUTINE spmd_collectm(NODNX_SMS, ITAB, WEIGHT,NODGLOB,SIZP0)
      USE inoutfile_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
        USE spmd_comm_world_mod, ONLY : spmd_comm_world
#include      "implicit_f.inc"
C-----------------------------------------------------------------
C   M e s s a g e   P a s s i n g
C-----------------------------------------------
#include "spmd.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "task_c.inc"
#include      "spmd_c.inc"
#include      "chara_c.inc"
#include      "units_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER ITAB(*),WEIGHT(*),NODGLOB(*),SIZP0,NODNX_SMS(*)
C-----------------------------------------------
C   L o c a l  V a r i a b l e s
C-----------------------------------------------
#ifdef MPI
      INTEGER MSGOFF,MSGOFF0,MSGTYP,INFO,I,K,NG,N,M,NK,
     .        EMPL,SDNODG(NUMNODM),FILEN
      INTEGER STATUS(MPI_STATUS_SIZE),IERROR
      INTEGER IGLOB(2,NUMNODM),RECGLOB(2,SIZP0),RTRI(2,SIZP0),
     .         ITRI(NUMNODG),INDEX(2*NUMNODG),WORK(70000)
 
      CHARACTER FILNAM*100,CYCLENUM*7
 
      INTEGER :: LEN_TMP_NAME
      CHARACTER(len=2148) :: TMP_NAME
 
      DATA msgoff0/182/
      DATA msgoff/183/
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
      WRITE(cyclenum,'(I7.7)')ncycle
      filnam=rootnam(1:rootlen)//'_'//chrun//'_'//cyclenum//'.mdb'
 
      len_tmp_name = outfile_name_len + len_trim(filnam)
      tmp_name=outfile_name(1:outfile_name_len)//filnam(1:len_trim(filnam)) 
       
      OPEN(unit=67,file=tmp_name(1:len_tmp_name),access='SEQUENTIAL',
     .                  form='FORMATTED',status='UNKNOWN')
 
      filen = rootlen+17
      IF (ispmd/=0) THEN
        n = 0
        DO i = 1, numnod
         IF (weight(i)==1) THEN
           n = n+1
           sdnodg(n) = nodglob(i)
           iglob(1,n) = itab(i)
           iglob(2,n) = nodnx_sms(i)
         END IF
        END DO
        msgtyp=msgoff0
        CALL mpi_send(sdnodg,n,mpi_integer,
     .                it_spmd(1),msgtyp,
     .                spmd_comm_world,ierror)
        msgtyp=msgoff
        CALL mpi_send(iglob,2*n,mpi_integer,
     .                it_spmd(1),msgtyp,
     .                spmd_comm_world,ierror)
      ELSE
        DO i=1,numnod
          IF (weight(i)==1) THEN
            empl = nodglob(i)
            rtri(1,empl) = itab(i)
            rtri(2,empl) = nodnx_sms(i)
          ENDIF
        ENDDO
 
        DO k=2,nspmd
            msgtyp=msgoff0
            CALL mpi_recv(sdnodg,numnodm,mpi_integer,
     .                    it_spmd(k),msgtyp,
     .                    spmd_comm_world,status,ierror)
 
            CALL mpi_get_count(status,mpi_integer,n,ierror)
 
            msgtyp=msgoff
            CALL mpi_recv(iglob,2*n,mpi_integer,
     .                    it_spmd(k),msgtyp,
     .                    spmd_comm_world,status,ierror)
 
            DO i=1,n
              empl = sdnodg(i)
              rtri(1,empl) = iglob(1,i)
              rtri(2,empl) = iglob(2,i)
            ENDDO
 
        END DO
C
        WRITE(67,'(A)') '   NODE ID','  NO TERMS'
        DO i = 1, numnodg
          WRITE(67,'(I10,I10)' )
     .      rtri(1,i),rtri(2,i)
        END DO
 
        DO i = 1, numnodg
          itri(i) =rtri(2,i)
          index(i)=i
        END DO
        CALL my_orders(0,work,itri,index,numnodg,1)
        DO i = 1, numnodg
          recglob(1,i) = rtri(1,index(i))
          recglob(2,i) = rtri(2,index(i))
        END DO
 
        WRITE(67,'(A)')'----- RESUME OF MATRIX STRUCTURE -----'
        i =1
        nk=1
        n=recglob(2,i)
        DO WHILE(i+1 < numnodg)
          m=recglob(2,i+1)
          IF(m==n)THEN
            nk=nk+1
          ELSE
            WRITE(67,'(A,I10,A,I10)')
     .        'NO of NODES WITH ',n,' TERMS =',nk
            nk=1
            n =m
          END IF
          i=i+1
        END DO
        WRITE(67,'(A,I10,A,I10)')
     .        'NO of NODES WITH ',n,' TERMS =',nk
 
        WRITE (iout,1300)  filnam(1:filen)
        WRITE (istdo,1300) filnam(1:filen)
        CLOSE(unit=67)
 
      END IF
C
 1300   FORMAT (4x,' DEBUG ANALYSIS FILE:',1x,a,' WRITTEN')
#endif
      RETURN
      END