spmd_exch_nodarea2.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
 
 
 
!||====================================================================
!||    spmd_exch_nodarea2    ../engine/source/mpi/anim/spmd_exch_nodarea2.F
!||--- called by ------------------------------------------------------
!||    genani                ../engine/source/output/anim/generate/genani.F
!||    h3d_nodal_tensor      ../engine/source/output/h3d/h3d_results/h3d_nodal_tensor.F
!||    h3d_sol_skin_scalar   ../engine/source/output/h3d/h3d_results/h3d_sol_skin_scalar.F
!||    h3d_sol_skin_tensor   ../engine/source/output/h3d/h3d_results/h3d_sol_skin_tensor.F
!||--- calls      -----------------------------------------------------
!||--- uses       -----------------------------------------------------
!||    spmd_comm_world_mod   ../engine/source/mpi/spmd_comm_world.F90
!||====================================================================
      SUBROUTINE spmd_exch_nodarea2(
     .           NODAREA,IAD_ELEM,FR_ELEM,LENR,WEIGHT,JJ)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
        USE spmd_comm_world_mod, ONLY : spmd_comm_world
#include      "implicit_f.inc"
C-----------------------------------------------------------------
C   M e s s a g e   P a s s i n g
C-----------------------------------------------
#include "spmd.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "task_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER  IAD_ELEM(2,*),FR_ELEM(*), SIZE, LENR,WEIGHT(*),JJ
      my_real 
     .        nodarea(3,*)
C-----------------------------------------------
C   L o c a l  V a r i a b l e s
C-----------------------------------------------
#ifdef MPI
      INTEGER MSGTYP,I,NOD,LOC_PROC,IERROR,
     .        siz,j,k,l,nb_nod,
     .        status(mpi_status_size),
     .        iad_send(nspmd+1),iad_recv(nspmd+1),
     .        req_r(nspmd),req_s(nspmd),msgoff
 
      my_real,
     . DIMENSION(:),ALLOCATABLE :: sbuf,rbuf
      DATA msgoff/7035/
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
      ALLOCATE(sbuf(lenr))
      ALLOCATE(rbuf(lenr))
C-----------------------------------------------
      loc_proc = ispmd+1
      l = 1
      iad_recv(1)=1
 
C   Mise en place des buffers de reception
      DO i=1,nspmd
         siz = iad_elem(1,i+1)-iad_elem(1,i)
         IF(siz/=0) THEN
           msgtyp = msgoff
           CALL mpi_irecv(
     s      rbuf(l),siz,real,it_spmd(i),msgtyp,
     g      spmd_comm_world,req_r(i),ierror)
           l = l+siz
         END IF
         iad_recv(i+1) = l
      END DO
 
! Remplissage des buffers d'envoi et envoi des donnees
C
      l=1
      iad_send(1)=1
      DO i=1,nspmd
         DO j=iad_elem(1,i),iad_elem(1,i+1)-1
            nod = fr_elem(j)
            sbuf(l) = nodarea(jj,nod)
            l = l+1
         END DO
        iad_send(i+1) = l
      END DO
 
      DO i=1,nspmd
 
       IF(iad_elem(1,i+1)-iad_elem(1,i)>0)THEN
 
          
          msgtyp = msgoff
          siz = iad_send(i+1)-iad_send(i)
          l = iad_send(i)
 
          CALL mpi_isend(
     s      sbuf(l),siz,real,it_spmd(i),msgtyp,
     g      spmd_comm_world,req_s(i),ierror)
       ENDIF                
      END DO
! Reception et traitement
      DO i = 1, nspmd
C
        nb_nod = iad_elem(1,i+1)-iad_elem(1,i)
        IF(nb_nod>0)THEN
          CALL mpi_wait(req_r(i),status,ierror)
          l = iad_recv(i)
 
          DO j=iad_elem(1,i),iad_elem(1,i+1)-1
 
             nod = fr_elem(j)
             nodarea(jj,nod) = nodarea(jj,nod) + rbuf(l)
             l = l+1
          ENDDO
        ENDIF
      ENDDO
 
      DO i = 1, nspmd
        IF(iad_elem(1,i+1)-iad_elem(1,i)>0)THEN
          CALL mpi_wait(req_s(i),status,ierror)
        ENDIF
      ENDDO
C-----------------------------------------------
      DEALLOCATE(sbuf)
      DEALLOCATE(rbuf)
C-----------------------------------------------
#endif
      RETURN
      END