spmd_exch_rbe2_sms.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    spmd_exch_rbe2_sms    ../engine/source/mpi/kinematic_conditions/spmd_exch_rbe2_sms.F
!||--- called by ------------------------------------------------------
!||    sms_diag_rbe2         ../engine/source/ams/sms_rbe2.F
!||    sms_rbe_cnds          ../engine/source/ams/sms_rbe2.F
!||    sms_rbe_prec          ../engine/source/ams/sms_rbe2.f
!||--- calls      -----------------------------------------------------
!||--- uses       -----------------------------------------------------
!||    spmd_comm_world_mod   ../engine/source/mpi/spmd_comm_world.F90
!||====================================================================
      SUBROUTINE spmd_exch_rbe2_sms(
     1   A     ,IAD_M   ,FR_M  ,LCOMM  ,ISIZE)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
        USE spmd_comm_world_mod, ONLY : spmd_comm_world
#include      "implicit_f.inc"
C-----------------------------------------------
C   M e s s a g e   P a s s i n g
C-----------------------------------------------
#include "spmd.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "task_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER LCOMM, ISIZE, FR_M(*), IAD_M(*)
      double precision
     .        a(isize,6,*)
C-----------------------------------------------
C   L o c a l  V a r i a b l e s
C-----------------------------------------------
#ifdef MPI
      INTEGER MSGTYP,LOC_PROC,NOD,I,J,L,IDEB,IAD,LEN,
     .        nbindex,index,msgoff,siz,ierror,k,m,
     .        status(mpi_status_size),isize6,
     .        req_s(nspmd),req_r(nspmd),indexi(nspmd),irot
      DATA msgoff/212/
      double precision
     .        sbuf(lcomm*isize*6), rbuf(lcomm*isize*6)
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
      loc_proc = ispmd + 1
      isize6=isize*6
C
      ideb = 1
      l = 0
      DO i = 1, nspmd
        len = iad_m(i+1)-iad_m(i)
        IF(len>0) THEN
          siz = len*isize6
          l=l+1
          indexi(l)=i
          msgtyp = msgoff
          CALL mpi_irecv(
     s      rbuf(ideb),siz,mpi_double_precision,it_spmd(i),msgtyp,
     g      spmd_comm_world,req_r(l),ierror)
          ideb = ideb + siz
        ENDIF
      ENDDO
      nbindex = l
C
      ideb = 1
      DO l = 1, nbindex
        i = indexi(l)
        len = iad_m(i+1) - iad_m(i)
        iad = iad_m(i)-1
#include      "vectorize.inc"
        DO j = 1, len
          nod = fr_m(iad+j)
          DO k = 1, 6
           DO m=1,isize
             sbuf(ideb)   = a(m,k,nod)
             ideb = ideb + 1
           END DO
          ENDDO
        ENDDO
      ENDDO
C
      ideb = 1
      DO l=1,nbindex
        i = indexi(l)
        len = iad_m(i+1)-iad_m(i)
        siz = len*isize6
        msgtyp = msgoff 
        CALL mpi_isend(
     s    sbuf(ideb),siz,mpi_double_precision,it_spmd(i),msgtyp,
     g    spmd_comm_world,req_s(l),ierror)
        ideb = ideb + siz
      ENDDO
C
      DO l=1,nbindex
        CALL mpi_waitany(nbindex,req_r,index,status,ierror)
        i = indexi(index)
        ideb = 1+(iad_m(i)-1)*isize6
        len = iad_m(i+1)-iad_m(i)
        iad = iad_m(i)-1
#include      "vectorize.inc"
        DO j = 1, len
          nod = fr_m(iad+j)
          DO k = 1, 6
           DO m=1,isize
             a(m,k,nod)   = a(m,k,nod) + rbuf(ideb)
             ideb = ideb + 1
           ENDDO
          ENDDO
        ENDDO
      ENDDO
C
      DO l=1,nbindex
        CALL mpi_waitany(nbindex,req_s,index,status,ierror)
      ENDDO
C
#endif
      RETURN
      END