spmd_exch_sms.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    spmd_exch_sms    ../engine/source/mpi/ams/spmd_exch_sms.F
!||--- called by ------------------------------------------------------
!||    sms_build_diag   ../engine/source/ams/sms_build_diag.F
!||    sms_inisi        ../engine/source/ams/sms_proj.F
!||    sms_mav_lt       ../engine/source/ams/sms_pcg.F
!||    sms_mav_lt2      ../engine/source/ams/sms_pcg.F
!||--- calls      -----------------------------------------------------
!||--- uses       -----------------------------------------------------
!||    spmd_mod         ../engine/source/mpi/spmd_mod.F90
!||====================================================================
      SUBROUTINE spmd_exch_sms(V,NODNX_SMS,IAD_ELEM,FR_ELEM,
     .                           SIZE,LENR)
        USE spmd_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------------------------
C   M e s s a g e   P a s s i n g
C-----------------------------------------------
#include "spmd.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "task_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NODNX_SMS(*), IAD_ELEM(2,*), FR_ELEM(*), SIZE, LENR
      my_real
     .        v(SIZE,*)
C-----------------------------------------------
C   L o c a l  V a r i a b l e s
C-----------------------------------------------
#ifdef MPI
      INTEGER MSGTYP,I,NOD,LOC_PROC,IERROR, MSGOFF,
     .        siz,j,l,nb_nod,k,
     .        status(mpi_status_size),
     .        iad_send(nspmd+1),iad_recv(nspmd+1),
     .        req_r(nspmd),req_s(nspmd)
      my_real
     .        rbuf(size*lenr), sbuf(size*lenr), w(SIZE,lenr)
      DATA msgoff/213/
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
      loc_proc = ispmd + 1
      l = 1
      iad_recv(1) = 1
      DO i=1,nspmd
 
        siz = 0
        DO j=iad_elem(1,i),iad_elem(1,i+1)-1
          nod = fr_elem(j)
          IF(nodnx_sms(nod)/=0)THEN
            siz = siz + SIZE
          END IF
        END DO
 
        IF(siz/=0)THEN
          msgtyp = msgoff
          CALL mpi_irecv(
     s      rbuf(l),siz,real,it_spmd(i),msgtyp,
     g      spmd_comm_world,req_r(i),ierror)
          l = l + siz
        ENDIF
        iad_recv(i+1) = l
      END DO
      l = 1
      iad_send(1) = 1
      DO i=1,nspmd
#include      "vectorize.inc"
        DO j=iad_elem(1,i),iad_elem(1,i+1)-1
          nod = fr_elem(j)
          IF(nodnx_sms(nod)/=0)THEN
            DO k=1,SIZE
              sbuf(l+k-1) =  v(k,nod)
            END DO
            l = l + SIZE
          END IF
        END DO
        iad_send(i+1) = l
      ENDDO
C
C   echange messages
C
      DO i=1,nspmd
C--------------------------------------------------------------------
ccc       IF(IAD_ELEM(1,I+1)-IAD_ELEM(1,I)>0)THEN
       IF(iad_send(i+1)-iad_send(i)>0)THEN
          msgtyp = msgoff
          siz = iad_send(i+1)-iad_send(i)
          l = iad_send(i)
          CALL mpi_isend(
     s      sbuf(l),siz,real,it_spmd(i),msgtyp,
     g      spmd_comm_world,req_s(i),ierror)
       ENDIF
C--------------------------------------------------------------------
      ENDDO
C
      DO j=1,iad_elem(1,nspmd+1)-1
        nod = fr_elem(j)
        IF(nodnx_sms(nod)/=0)THEN
          DO k=1,SIZE
            w(k,j)   = v(k,nod)
            v(k,nod) = zero
          END DO
        END IF
      END DO
C
      DO i = 1, loc_proc-1
ccc        IF(IAD_ELEM(1,I+1)-IAD_ELEM(1,I)>0)THEN
        IF(iad_recv(i+1)-iad_recv(i)>0)THEN
          CALL mpi_wait(req_r(i),status,ierror)
          l = iad_recv(i)
#include      "vectorize.inc"
          DO j=iad_elem(1,i),iad_elem(1,i+1)-1
            nod = fr_elem(j)
            IF(nodnx_sms(nod)/=0) THEN
              DO k=1,SIZE
                v(k,nod) = v(k,nod)+rbuf(l+k-1)
              END DO
              l = l + SIZE
            END IF
          END DO
        ENDIF
      END DO
C
      DO j=1,iad_elem(1,nspmd+1)-1
        nod = fr_elem(j)
        IF(nodnx_sms(nod)/=0)THEN
          DO k=1,SIZE
            v(k,nod) = v(k,nod) + w(k,j)
          END DO
        END IF
      END DO
C
      DO i = loc_proc+1,nspmd
ccc        IF(IAD_ELEM(1,I+1)-IAD_ELEM(1,I)>0)THEN
        IF(iad_recv(i+1)-iad_recv(i)>0)THEN
          CALL mpi_wait(req_r(i),status,ierror)
          l = iad_recv(i)
#include      "vectorize.inc"
          DO j=iad_elem(1,i),iad_elem(1,i+1)-1
            nod = fr_elem(j)
            IF(nodnx_sms(nod)/=0) THEN
              DO k=1,SIZE
                v(k,nod) = v(k,nod)+rbuf(l+k-1)
              END DO
              l = l + SIZE
            END IF
          END DO
        ENDIF
      END DO
C
      DO i = 1, nspmd
ccc        IF(IAD_ELEM(1,I+1)-IAD_ELEM(1,I)>0)THEN
        IF(iad_send(i+1)-iad_send(i)>0)THEN
          CALL mpi_wait(req_s(i),status,ierror)
        ENDIF
      ENDDO
C
#endif
      RETURN
      END