spmd_exch_userwi.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    spmd_exch_userwi       ../engine/source/mpi/user_interface/spmd_exch_userwi.F
!||--- called by ------------------------------------------------------
!||    user_windows_routine   ../engine/source/user_interface/user_windows.F
!||--- calls      -----------------------------------------------------
!||--- uses       -----------------------------------------------------
!||    spmd_comm_world_mod    ../engine/source/mpi/spmd_comm_world.F90
!||    user_windows_mod       ../common_source/modules/user_windows_mod.F
!||====================================================================
      SUBROUTINE spmd_exch_userwi(A,AR,USER_WINDOWS)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE user_windows_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
        USE spmd_comm_world_mod, ONLY : spmd_comm_world
#include      "implicit_f.inc"
C-----------------------------------------------------------------
C   M e s s a g e   P a s s i n g
C-----------------------------------------------
#include "spmd.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "task_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE(user_windows_),INTENT(INOUT) :: USER_WINDOWS
      my_real
     *  a(3,*),ar(3,*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
#ifdef MPI
      INTEGER MSGOFF,MSGTYP,P,I,ND,IAD,NUM,SIZ,
     .        STATUS(MPI_STATUS_SIZE),IERROR,LOC_PROC
 
      my_real
     * , DIMENSION(:,:), ALLOCATABLE ::  rbuf,sbuf
 
      DATA msgoff/227/
C-----------------------------------------------
      loc_proc = ispmd + 1
      IF (ispmd==0)THEN
        siz = user_windows%IAD_USERW(nspmd+1)-1
        ALLOCATE( sbuf(6,siz))
        DO p=2,nspmd
          num = user_windows%IAD_USERW(p+1)-user_windows%IAD_USERW(p)
 
          IF(num > 0)THEN
            iad = user_windows%IAD_USERW(p)
            DO i=1,num
              nd = user_windows%FR_USERW(iad+i-1)
              sbuf(1,iad+i-1)=a(1,nd)
              sbuf(2,iad+i-1)=a(2,nd)
              sbuf(3,iad+i-1)=a(3,nd)
              sbuf(4,iad+i-1)=ar(1,nd)
              sbuf(5,iad+i-1)=ar(2,nd)
              sbuf(6,iad+i-1)=ar(3,nd)
            ENDDO
          ENDIF
        ENDDO
 
        DO p=2,nspmd
           num = user_windows%IAD_USERW(p+1)-user_windows%IAD_USERW(p)
           iad = user_windows%IAD_USERW(p)
           IF(num > 0)THEN
             msgtyp=msgoff
             CALL mpi_send(sbuf(1,iad),6*num,real,it_spmd(p),msgtyp,
     .                spmd_comm_world,ierror)
           ENDIF
        ENDDO
        DEALLOCATE(sbuf)
      ELSE
        num = user_windows%S_FR_USERW
        ALLOCATE(rbuf(6,num))
        IF(num > 0)THEN
          msgtyp = msgoff
          CALL mpi_recv(rbuf,6*num,real,it_spmd(1),msgtyp,
     .                spmd_comm_world,status,ierror)
          DO i=1,num
            nd=user_windows%FR_USERW(i)
            a(1,nd)=a(1,nd)+rbuf(1,i)
            a(2,nd)=a(2,nd)+rbuf(2,i)
            a(3,nd)=a(3,nd)+rbuf(3,i)
            ar(1,nd)=a(1,nd)+rbuf(4,i)
            ar(2,nd)=a(2,nd)+rbuf(5,i)
            ar(3,nd)=a(3,nd)+rbuf(6,i)
          ENDDO
        ENDIF
        DEALLOCATE(rbuf)
      ENDIF
 
#endif
      RETURN
      END