spmd_fvb_adim.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
 
!||====================================================================
!||    spmd_fvb_adim         ../engine/source/mpi/anim/spmd_fvb_adim.F
!||--- called by ------------------------------------------------------
!||    genani                ../engine/source/output/anim/generate/genani.F
!||--- calls      -----------------------------------------------------
!||--- uses       -----------------------------------------------------
!||    fvbag_mod             ../engine/share/modules/fvbag_mod.F
!||    spmd_comm_world_mod   ../engine/source/mpi/spmd_comm_world.F90
!||====================================================================
      SUBROUTINE spmd_fvb_adim(NFVTR, FVOFF , NFVNOD, NFVPART, NFVSUBS,
     .                         IDMAX, ITAB  , NODCUT, NNWL   , NNSRG  ,
     .                         NNSMD, NNSPHG)
C-----------------------------------------------
C   M o d u l e s 
C-----------------------------------------------
      USE fvbag_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
        USE spmd_comm_world_mod, ONLY : spmd_comm_world
#include      "implicit_f.inc"
C-----------------------------------------------------------------
C   M e s s a g e   P a s s i n g
C-----------------------------------------------
#include "spmd.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "task_c.inc"
#include      "spmd_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NFVTR, FVOFF(2,*), NFVNOD, NFVPART, NFVSUBS, IDMAX,
     .        ITAB(*), NODCUT, NNWL, NNSRG, NNSMD, NNSPHG
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
#ifdef MPI
      INTEGER IDMAXL, I, MSGOFF, IDMAXP(NSPMD-1), 
     .        REQ(NSPMD-1), IERR, STAT(MPI_STATUS_SIZE,NSPMD-1),
     .        pmain, tab(4),msgtyp
      DATA msgoff/7037/
C
      idmaxl=0
      DO i=1,numnod
         idmaxl=max(idmaxl,itab(i))
      ENDDO
      IF (ispmd==0) THEN
         DO i=1,nspmd-1
            msgtyp=msgoff
            CALL mpi_irecv(idmaxp(i), 1, mpi_integer, it_spmd(i+1),
     .                     msgtyp, spmd_comm_world, req(i), ierr)
         ENDDO
         CALL mpi_waitall(nspmd-1, req, stat, ierr)
C
         idmax=idmaxl
         DO i=1,nspmd-1
            idmax=max(idmax,idmaxp(i))
         ENDDO
      ELSE
         msgtyp=msgoff
         CALL mpi_isend(idmaxl, 1, mpi_integer, it_spmd(1),
     .                  msgtyp, spmd_comm_world, req, ierr)
         CALL mpi_wait(req, stat, ierr)
      ENDIF
C
      DO i=1,nfvbag
         pmain=fvspmd(i)%PMAIN
         IF (ispmd==0) THEN
            IF (ispmd==pmain-1) THEN
               nfvtr=nfvtr+fvdata(i)%NNTR
               fvoff(1,i)=numnodg+nodcut+nsect+nrwall+nnwl
     .                   +nnsrg+nnsmd+nnsphg+2*numels16g+nfvnod
               fvoff(2,i)=idmax+nfvnod
               nfvnod=nfvnod+fvdata(i)%NNS_ANIM
               nfvpart=nfvpart+fvdata(i)%NPOLH_ANIM
               nfvsubs=nfvsubs+1
            ELSE
               msgtyp=msgoff
               CALL mpi_recv(tab, 3, mpi_integer, it_spmd(pmain),
     .                       msgtyp, spmd_comm_world, stat, ierr)
C
               nfvtr=nfvtr+tab(1)
               fvoff(1,i)=numnodg+nodcut+nsect+nrwall+nnwl
     .                   +nnsrg+nnsmd+nnsphg+2*numels16g+nfvnod
               fvoff(2,i)=idmax+nfvnod
               nfvnod=nfvnod+tab(2)
               nfvpart=nfvpart+tab(3)
               nfvsubs=nfvsubs+1
            ENDIF
         ELSE
            IF (ispmd==pmain-1) THEN
               msgtyp=msgoff
               tab(1)=fvdata(i)%NNTR
               tab(2)=fvdata(i)%NNS_ANIM
               tab(3)=fvdata(i)%NPOLH_ANIM
               CALL mpi_send(tab, 3, mpi_integer, it_spmd(1),
     .                       msgtyp, spmd_comm_world,  ierr)
            ENDIF
         ENDIF
      ENDDO
C
      IF (ispmd==0) THEN
         tab(1)=nfvtr
         tab(2)=nfvnod
         tab(3)=nfvpart
         tab(4)=nfvsubs
      ENDIF
      CALL mpi_bcast(tab, 4, mpi_integer, it_spmd(1),
     .               spmd_comm_world, ierr)
      IF (ispmd/=0) THEN
         nfvtr=tab(1)
         nfvnod=tab(2)
         nfvpart=tab(3)
         nfvsubs=tab(4)
      ENDIF
C
#endif
      RETURN
      END