spmd_glob_min5.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
C==========================================================================
!||====================================================================
!||    spmd_glob_min5        ../engine/source/mpi/generic/spmd_glob_min5.F
!||--- called by ------------------------------------------------------
!||    resol                 ../engine/source/engine/resol.F
!||--- calls      -----------------------------------------------------
!||--- uses       -----------------------------------------------------
!||    intbufdef_mod         ../common_source/modules/interfaces/intbufdef_mod.F90
!||    spmd_comm_world_mod   ../engine/source/mpi/spmd_comm_world.F90
!||====================================================================
      SUBROUTINE spmd_glob_min5(DT2  ,ITYPTS,NELTS,ICODT,IMSCH,
     .                         TSTOP,IWIOUT,MSTOP,ISMSCH,
     .                         INT24USE,NBINTC,INTLIST,IPARI,INTBUF_TAB)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE intbufdef_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
        USE spmd_comm_world_mod, ONLY : spmd_comm_world
#include      "implicit_f.inc"
C-----------------------------------------------------------------
C   M e s s a g e   P a s s i n g
C-----------------------------------------------
#include "spmd.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "task_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER ITYPTS, NELTS, ICODT ,IMSCH, IWIOUT,MSTOP,
     .        ISMSCH
C Interface type 24 communication addon
      INTEGER INT24USE,NBINTC,INTLIST(*),IPARI(NPARI,*)
      my_real
     .        dt2, tstop
      TYPE(intbuf_struct_) INTBUF_TAB(*)
C-----------------------------------------------
C   L o c a l  V a r i a b l e s
C-----------------------------------------------
#ifdef MPI
      INTEGER IERROR, LOC_PROC, MSTOP1, MSTOP2, LEN, myop
      my_real,
     . DIMENSION(:),ALLOCATABLE :: rbuf, sbuf 
C interface type 24 comm Addon
      INTEGER NIN,NI,NTY
      INTEGER ::  MY_TYPE
      INTEGER GLOB_MIN
      EXTERNAL glob_min
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
      IF(int24use==1)THEN
        len = 10 + nbintc
      ELSE
        len = 10
      ENDIF
      ALLOCATE(rbuf(len))
      ALLOCATE(sbuf(len))
      rbuf(1:len)=zero
      
      mstop1=0
      mstop2=0
      IF(mstop==1)mstop1=1
      IF(mstop==2)mstop2=1
C
      loc_proc=ispmd+1
C
      sbuf(1) = dt2
      sbuf(2) = itypts
      sbuf(3) = nelts 
      sbuf(4) = iexicodt
      sbuf(5) = imsch
      sbuf(6) = tstop
      sbuf(7) = iwiout
      sbuf(8) = mstop1
      sbuf(9) = mstop2
      sbuf(10)= ismsch
      
      IF (int24use==1)THEN
         DO ni=1,nbintc
            nin = intlist(ni)
            nty   = ipari( 7,nin)
            IF(nty==24.OR.nty==25) THEN
              sbuf(10+ni) = intbuf_tab(nin)%VARIABLES(23)
            ELSE
              sbuf(10+ni) = zero
            ENDIF
         ENDDO
      ENDIF
 
      CALL mpi_type_contiguous(10,real,my_type,ierror)
      CALL mpi_type_commit(my_type,ierror)
C
      CALL mpi_op_create(glob_min, .true., myop, ierror)
      
      CALL mpi_allreduce(sbuf, rbuf, 1, my_type, myop,
     &                   spmd_comm_world, ierror)
     
      IF (int24use==1)THEN
        CALL mpi_allreduce(sbuf(11), rbuf(11), nbintc, real , mpi_max,
     &                   spmd_comm_world, ierror)
      ENDIF
 
      CALL mpi_op_free(myop, ierror)
      CALL mpi_type_free(my_type,ierror)
 
C
      dt2      = rbuf(1)
      itypts   = nint(rbuf(2))
      nelts    = nint(rbuf(3))
      iexicodt = nint(rbuf(4))
      imsch    = nint(rbuf(5))
      tstop    = rbuf(6)
      iwiout   = nint(rbuf(7))
      mstop1   = nint(rbuf(8))
      mstop2   = nint(rbuf(9))
      IF(mstop1/=0)mstop=1
      IF(mstop2/=0)mstop=2
      ismsch   = rbuf(10)
C
      IF (int24use==1)THEN
         DO ni=1,nbintc
            nin = intlist(ni)
            nty   = ipari( 7,nin)
            IF(nty==24.OR.nty==25) THEN
              intbuf_tab(nin)%VARIABLES(23) = rbuf(10+ni)
            ENDIF
         ENDDO
      ENDIF
C
      DEALLOCATE(rbuf)
      DEALLOCATE(sbuf)
C
#endif
      RETURN
      END