spmd_i7curvcom.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
C
!||====================================================================
!||    spmd_i7curvcom        ../engine/source/mpi/interfaces/spmd_i7curvcom.f
!||--- called by ------------------------------------------------------
!||    i20normnp             ../engine/source/interfaces/int20/i20rcurv.F
!||    i20normp              ../engine/source/interfaces/int20/i20curv.F
!||    i20normsp             ../engine/source/interfaces/int20/i20curv.f
!||    i7normnp              ../engine/source/interfaces/int07/i7rcurv.F
!||    i7normp               ../engine/source/interfaces/int07/i7curv.F
!||--- calls      -----------------------------------------------------
!||--- uses       -----------------------------------------------------
!||    spmd_comm_world_mod   ../engine/source/mpi/spmd_comm_world.F90
!||====================================================================
      SUBROUTINE spmd_i7curvcom(IAD_ELEM,FR_ELEM,ADSKYT,FSKYT,
     .                          ISDSIZ  ,IRCSIZ ,ITAG  ,LENR    ,LENS)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
        USE spmd_comm_world_mod, ONLY : spmd_comm_world
#include      "implicit_f.inc"
C-----------------------------------------------
C   M e s s a g e   P a s s i n g
C-----------------------------------------------
#include "spmd.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "task_c.inc"
#include      "com01_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER LENR,LENS,ITAG(*),
     .        iad_elem(2,*), fr_elem(*), isdsiz(*), ircsiz(*),
     .        adskyt(0:*)
       my_real
     .        fskyt(3,*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
#ifdef MPI
      INTEGER I ,J ,N1, N2, N3, N4,IERROR, IAD, IAD1, IAD2, SIZ, NB,
     .        msgtyp, loc_proc, cc, msgoff,
     .        status(mpi_status_size),req_r(nspmd)
C     REAL
       my_real
     .        bufr(lenr), bufs(lens)
      DATA msgoff/195/
C-----------------------------------------------
C
      loc_proc = ispmd+1
C
      iad = 1
      DO i=1,nspmd
        siz = ircsiz(i)
        IF(siz>0)THEN
          siz = siz*3+iad_elem(1,i+1)-iad_elem(1,i)
          msgtyp = msgoff
          CALL mpi_irecv(
     s      bufr(iad),siz,real,it_spmd(i),msgtyp,
     g      spmd_comm_world,req_r(i),ierror)
            iad = iad + siz
        ENDIF
      END DO
 
      DO i=1,nspmd
        IF(isdsiz(i)>0)THEN
          iad = 0
#include      "vectorize.inc"
          DO j=iad_elem(1,i),iad_elem(1,i+1)-1
            n1 = fr_elem(j)
            iad1 = itag(n1)
            iad2 = adskyt(n1)-1
            nb = iad2-iad1+1
            iad = iad + 1
            bufs(iad) = nb
            DO cc = iad1, iad2
              iad = iad + 1
              bufs(iad) = fskyt(1,cc)
              iad = iad + 1
              bufs(iad) = fskyt(2,cc)
              iad = iad + 1
              bufs(iad) = fskyt(3,cc)
            END DO
          END DO
 
          siz = 3*isdsiz(i)+iad_elem(1,i+1)-iad_elem(1,i)
          msgtyp = msgoff
          CALL mpi_send(
     s      bufs,siz,real,it_spmd(i),msgtyp,
     g      spmd_comm_world,ierror)
        END IF
      END DO
C
      iad = 0
      DO i = 1, nspmd
        IF(ircsiz(i)>0)THEN
          CALL mpi_wait(req_r(i),status,ierror)
          DO j=iad_elem(1,i),iad_elem(1,i+1)-1
            n1 = fr_elem(j)
            iad = iad + 1
            nb = nint(bufr(iad))
            DO cc = 1, nb
              iad1 = adskyt(n1)
              adskyt(n1) = adskyt(n1)+1
              iad = iad + 1
              fskyt(1,iad1) = bufr(iad)
              iad = iad + 1
              fskyt(2,iad1) = bufr(iad)
              iad = iad + 1
              fskyt(3,iad1) = bufr(iad)
            END DO
          END DO
        END IF
      END DO
C
#endif
      RETURN
      END