spmd_r4get_partn.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
 
!||====================================================================
!||    spmd_r4get_partn      ../engine/source/mpi/anim/spmd_r4get_partn.F
!||--- called by ------------------------------------------------------
!||    animcale              ../engine/source/output/anim/generate/monvol_anim.F90
!||    dfunc0                ../engine/source/output/anim/generate/dfunc0.F
!||    dfuncc                ../engine/source/output/anim/generate/dfuncc.F
!||    dfuncc_crk            ../engine/source/output/anim/generate/dfuncc_crk.F
!||    dfuncc_ply            ../engine/source/output/anim/generate/dfuncc_ply.F
!||    dfuncf                ../engine/source/output/anim/generate/dfuncf.F
!||    dfuncs                ../engine/source/output/anim/generate/dfunc6.F
!||    genani                ../engine/source/output/anim/generate/genani.F
!||    tensor0               ../engine/source/output/anim/generate/tensor0.F
!||    tensorc               ../engine/source/output/anim/generate/tensorc.F
!||    tensorc_crk           ../engine/source/output/anim/generate/tensorc_crk.F
!||    tensorc_ply           ../engine/source/output/anim/generate/tensorc_ply.F
!||    tensors               ../engine/source/output/anim/generate/tensor6.F
!||    torseur               ../engine/source/output/anim/generate/torseur.F
!||--- calls      -----------------------------------------------------
!||    write_r_c             ../common_source/tools/input_output/write_routtines.c
!||--- uses       -----------------------------------------------------
!||    spmd_comm_world_mod   ../engine/source/mpi/spmd_comm_world.F90
!||====================================================================
      SUBROUTINE spmd_r4get_partn(SIZE,NBF_L,NBPART,IADG,WAL,BUF)
C gather sur p0 du tableau wa en fonction des parts (IADG)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
        USE spmd_comm_world_mod, ONLY : spmd_comm_world
#include      "implicit_f.inc"
C-----------------------------------------------
C   M e s s a g e   P a s s i n g
C-----------------------------------------------
#include "spmd.inc"
 
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "task_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NBF_L, NBPART, SIZE, IFLAG, IADG(NSPMD,*),BUF
      REAL WAL(*)
      REAL, DIMENSION(:), ALLOCATABLE :: WAR
C-----------------------------------------------
C   L o c a l  V a r i a b l e s
C-----------------------------------------------
#ifdef MPI
      INTEGER MSGOFF,MSGTYP,INFO,IDEB,K,N,NB_TMP,LEN,IADP(NSPMD)
      REAL AUX
      INTEGER STATUS(MPI_STATUS_SIZE),IERROR
      DATA msgoff/7002/
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
      ALLOCATE(war(buf+1))
 
      IF (ispmd/=0) THEN
        msgtyp=msgoff
        CALL mpi_send(wal,nbf_l,mpi_real4,it_spmd(1),msgtyp,
     .                spmd_comm_world,ierror)
 
      ELSE
C  
        DO k=1,nbf_l
          war(k) = wal(k)
        END DO
 
        ideb = nbf_l + 1
        iadp(1) = 1
C
        DO k=2,nspmd
          iadp(k) = ideb
          msgtyp=msgoff
 
          CALL mpi_probe(it_spmd(k),msgtyp,
     .                   spmd_comm_world,status,ierror)
          CALL mpi_get_count(status,mpi_real4,nb_tmp,ierror)
          CALL mpi_recv(war(ideb),nb_tmp,mpi_real4,it_spmd(k),msgtyp,
     .                  spmd_comm_world,status,ierror)
 
          ideb = ideb + nb_tmp
        END DO
        DO n = 1, nbpart
          DO k = 1, nspmd
            IF (n>1) THEN
              len = (iadg(k,n) - iadg(k,n-1))*SIZE
            ELSE
              len = iadg(k,n)*SIZE
            ENDIF
            IF(len>0)CALL write_r_c(war(iadp(k)),len)
            iadp(k) = iadp(k) + len
          ENDDO
        ENDDO
      ENDIF
C
      DEALLOCATE(war)
#endif
      RETURN
      END