spmd_rnum25_edge.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    spmd_rnum25_edge   ../engine/source/mpi/interfaces/spmd_rnum25_edge.F
!||--- called by ------------------------------------------------------
!||    i25main_tri        ../engine/source/interfaces/intsort/i25main_tri.F
!||--- uses       -----------------------------------------------------
!||    tri25ebox          ../engine/share/modules/tri25ebox.F
!||    tri7box            ../engine/share/modules/tri7box.F
!||====================================================================
      SUBROUTINE spmd_rnum25_edge(NIN,NEDGE,CAND_E2E,ISTOK_E2E, CAND_E2S,ISTOK_E2S)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE tri25ebox
      USE tri7box
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
#include      "i25edge_c.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) ::  NIN, NEDGE,ISTOK_E2E,ISTOK_E2S
      INTEGER, INTENT(INOUT) ::  CAND_E2E(ISTOK_E2E),CAND_E2S(ISTOK_E2S)
C-----------------------------------------------
C   L o c a l  V a r i a b l e s
C-----------------------------------------------
      INTEGER I, J, P, I_STOK, IDEB, JDEB, NI
      INTEGER EID,N_REMOTE_OLD
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
      n_remote_old = 0
      DO p = 1, nspmd
        n_remote_old = n_remote_old + nsnfieold(p)
      ENDDO
 
      ALLOCATE(renum_edge(n_remote_old))
      DO i = 1, n_remote_old
        renum_edge(i) = -1
      END DO
 
 
      ALLOCATE(oldnum_edge(nedge_remote))
      DO i = 1, nedge_remote
        oldnum_edge(i) = 0 
!       OLDNUM_EDGE(NEW) = OLD or 0
      END DO
 
      ideb = 0
      jdeb = 0
 
 
      DO p = 1, nspmd
        i = 1
        j = 1
        DO WHILE (j<=nsnfie(nin)%P(p).AND.i<=nsnfieold(p))
 
          IF(irem_edge(e_local_id,j+jdeb)==
     +       nsvfie(nin)%P(i+ideb)) THEN
C           RENUM_EDGE(OLD) = NEW
            renum_edge(i+ideb) = j+jdeb
C debug
C           WRITE(6,"(I10,A,I10,A,I10,I10)") IREM_EDGE(E_GLOBAL_ID,J+JDEB),
C    .                 " RENUM(",J+JDEB,")= ",I+IDEB,NEDGE_REMOTE
C
            i = i + 1
            j = j + 1
          ELSEIF(irem_edge(e_local_id,j+jdeb)<
     +           nsvfie(nin)%P(i+ideb)) THEN
           j = j + 1
 
          ELSEIF(irem_edge(e_local_id,j+jdeb)>
     +           nsvfie(nin)%P(i+ideb)) THEN
Cas candidat non penetre et non retenu
            i = i + 1
          END IF
        END DO
        jdeb = jdeb + nsnfie(nin)%P(p)  
        ideb = ideb + nsnfieold(p)
      END DO
C
 
      DO i = 1, n_remote_old
        IF(renum_edge(i)>0)  THEN
!          OLDNUM_EDGE(NEW) = OLD
           oldnum_edge(renum_edge(i)) = i
        ENDIF
      END DO
 
      DO i = 1, istok_e2e
        ni = cand_e2e(i)
        IF(ni>nedge) THEN
          ni = ni - nedge 
          cand_e2e(i) = renum_edge(ni) + nedge
        END IF        
      END DO
 
      DO i = 1, istok_e2s
        ni = cand_e2s(i)
        IF(ni>nedge) THEN
          ni = ni - nedge 
          cand_e2s(i) = renum_edge(ni) + nedge
        END IF        
      END DO
 
 
      RETURN
      END