spmd_sd_cj_2.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
C
!||====================================================================
!||    spmd_sd_cj_2          ../engine/source/mpi/kinematic_conditions/spmd_sd_cj_2.F
!||--- called by ------------------------------------------------------
!||    sms_build_diag        ../engine/source/ams/sms_build_diag.F
!||    sms_ini_kin_1         ../engine/source/ams/sms_init.f
!||--- calls      -----------------------------------------------------
!||--- uses       -----------------------------------------------------
!||    spmd_comm_world_mod   ../engine/source/mpi/spmd_comm_world.F90
!||====================================================================
      SUBROUTINE spmd_sd_cj_2(NOD2ADD,LJOINT,FR_CJ,IADCJ,ICSIZE,
     2                      TAG_LNK_SMS,NODNX_SMS,INDX1_SMS)
C envoi de p0 vers les autres procs de A, AR, V, VR
C apres traitement des joints cylindriques
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
        USE spmd_comm_world_mod, ONLY : spmd_comm_world
#include      "implicit_f.inc"
C-----------------------------------------------------------------
C   M e s s a g e   P a s s i n g
C-----------------------------------------------
#include "spmd.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "task_c.inc"
#include      "sms_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER ICSIZE, NOD2ADD(*),LJOINT(*),FR_CJ(*),
     .        iadcj(nspmd+1,*), tag_lnk_sms(*), nodnx_sms(*),
     .        indx1_sms(*)
C-----------------------------------------------
C   L o c a l  V a r i a b l e s
C-----------------------------------------------
#ifdef MPI
      INTEGER MSGTYP,MSGOFF,IERROR,LOC_PROC,NOD,L,I,J,N,
     .        ideb,iad,siz,a_ar,nbindex,
     .        indexi(nspmd),req_s(nspmd),status(mpi_status_size),
     .        len(nspmd),ibuf(icsize)
      DATA msgoff/104/
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
      loc_proc = ispmd + 1
      IF (loc_proc==1) THEN
        l = 0
        ideb = 1
 
        DO i = 2, nspmd
          len(i)=0
          DO n=1,njoint
           IF(tag_lnk_sms(n)/=0)
     .       len(i) = len(i)+iadcj(i+1,n)-iadcj(i,n)
          END DO
          IF(len(i)>0) THEN
            l=l+1
            indexi(l)=i
            DO n=1,njoint
              IF(tag_lnk_sms(n)==0)cycle
              DO j = iadcj(i,n), iadcj(i+1,n)-1
                nod = fr_cj(j)
                ibuf(ideb  )  = nod2add(nod)
                ideb = ideb + 1
              END DO
            END DO
          END IF
        END DO
        nbindex = l
C
        ideb = 1
 
        DO l=1,nbindex
         i = indexi(l)
         siz = len(i)
         msgtyp = msgoff
         CALL mpi_isend(
     s     ibuf(ideb),siz,mpi_integer,it_spmd(i),msgtyp,
     g     spmd_comm_world,req_s(l),ierror)
         ideb = ideb + siz
        END DO
C
        DO l=1,nbindex
          CALL mpi_waitany(nbindex,req_s,i,status,ierror)
        ENDDO
      ELSEIF(icsize>0) THEN
C proc <> 0
        ideb = 1
        siz = icsize
        msgtyp = msgoff
        CALL mpi_recv(
     s    ibuf,siz,mpi_integer,it_spmd(1),msgtyp,
     g    spmd_comm_world,status,ierror)
        DO n = 1, njoint
          IF(tag_lnk_sms(n)==0)cycle
          DO j = iadcj(1,n),iadcj(nspmd+1,n)-1
            nod = fr_cj(j)
            IF(nodnx_sms(nod)==0.AND.nod2add(nod)==0.AND.
     .         ibuf(ideb)/=0)THEN
              nindx1_sms=nindx1_sms+1
              indx1_sms(nindx1_sms)=nod
              nodnx_sms(nod)=nindx1_sms
              nod2add(nod)=1
            END IF
            ideb = ideb + 1
          END DO
        END DO
      END IF
C
#endif
      RETURN
      END