spmd_sync_mmxg.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
C
!||====================================================================
!||    spmd_sync_mmxg        ../engine/source/mpi/interfaces/spmd_sync_mmxg.F
!||--- calls      -----------------------------------------------------
!||====================================================================
      SUBROUTINE spmd_sync_mmxg(
     1    ISENDTO,IRCVFROM,NEWFRONT,XSLV_L,XMSR_L,
     2    VSLV_L ,VMSR_L  ,INTLIST ,NINTC ,TZINF ,
     3    SIZE_T ,IPARI   , DELTA_PMAX_GAP,MAXDGAP       )
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------------------------
C   M e s s a g e   P a s s i n g
C-----------------------------------------------
#include "spmd.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
#include      "param_c.inc"
#include      "task_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER ISENDTO(NINTER+1,*) ,IRCVFROM(NINTER+1,*),
     .        NEWFRONT(*), NINTC, INTLIST(*), IPARI(NPARI,*)
      my_real
     .        xslv_l(18,*), xmsr_l(12,*), vslv_l(6,*),
     .        vmsr_l(6,*), tzinf(*), size_t(*),delta_pmax_gap(*),
     .        maxdgap(ninter)
C-----------------------------------------------
C   L o c a l  V a r i a b l e s
C-----------------------------------------------
#ifdef MPI
      INTEGER LOC_PROC,IERROR,I_LEN,myop,
     .        KK, L, J, NIN, REQ,
     .        STATUS(MPI_STATUS_SIZE),type_reduc
      parameter(i_len = 46)
      my_real
     .        sbuf(nintc*i_len), rbuf(nintc*i_len)
      INTEGER REDUCE_MMX
      EXTERNAL reduce_mmx
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
C
      loc_proc = ispmd+1
      IF(ircvfrom(ninter+1,loc_proc)>0.OR.
     +   isendto(ninter+1,loc_proc)>0) THEN
 
!      need to define I_LEN contiguous blocks to avoid that intel mpi splits
!      the buffers
       call mpi_type_contiguous(i_len,real,type_reduc,ierror)
!      need to validate the Type_contiguous
       call mpi_type_commit(type_reduc,ierror)
 
       call mpi_op_create(reduce_mmx, .true., myop, ierror)
 
C Pack original data      
       l = 0
       DO kk=1,nintc
        nin = intlist(kk)
C X MIN/MAX
        DO j=1,18
          sbuf(l+j) = xslv_l(j,nin)
        END DO
        l = l + 18
C
        DO j=1,12
          sbuf(l+j) = xmsr_l(j,nin)
        END DO
        l = l + 12
C V MIN/MAX
        DO j=1,6
          sbuf(l+j) = vslv_l(j,nin)
        END DO
        l = l + 6
C
        DO j=1,6
          sbuf(l+j) = vmsr_l(j,nin)
        END DO
        l = l + 6
        IF(ipari(7,nin)/=17)THEN
C NEWFRONT
          sbuf(l+1) = newfront(nin)
        ELSE     ! interface 17 avec courbure
C SIZE
          sbuf(l+1) = size_t(nin)
        END IF
        l = l + 1
C TZINF
        sbuf(l+1) = tzinf(kk)
        l = l + 1
C DELTA_PMAX_GAP
        sbuf(l+1) = delta_pmax_gap(nin)
        l = l + 1
C T25 main gap changes with thickness change
        sbuf(l+1) = maxdgap(nin)
        l = l + 1
       END DO
C
!     -+-+-+-+-+-+-+-+-+-
!     OLD FORMULATION : bug with intel MPI 
!      call MPI_AllReduce(SBUF, RBUF, NINTC*I_LEN, real, myop,
!     &                   COMM_CONT, ierror)
!     -+-+-+-+-+-+-+-+-+-
 
!     NEW FORMULATION
      call mpi_allreduce(sbuf, rbuf, nintc, type_reduc, myop,
     &                   comm_cont, ierror)
 
 
cc       call MPI_IAllReduce(SBUF, RBUF, NINTC*I_LEN, real, myop,
cc     &                     COMM_CONT, REQ, IERROR)
cc       call MPI_WAIT(req,status,ierror)   
C Unpack results
 
       l = 0
       DO kk=1,nintc
         nin = intlist(kk)
         IF(ircvfrom(nin,loc_proc)/=0.OR.
     +        isendto(nin,loc_proc)/=0)THEN
           DO j=1,18
            xslv_l(j,nin) = rbuf(l+j)
           END DO
           l = l + 18
           DO j=1,12
            xmsr_l(j,nin) = rbuf(l+j)
           END DO
           l = l + 12
           DO j=1,6
            vslv_l(j,nin) = rbuf(l+j)
           END DO
           l = l + 6
           DO j=1,6
            vmsr_l(j,nin) = rbuf(l+j)
           END DO
           l = l + 6
           IF(ipari(7,nin)/=17)THEN
             newfront(nin) = nint(rbuf(l+1))
           ELSE     ! interface 17 avec courbure
             size_t(nin) = rbuf(l+1)
           END IF
           l = l + 1
           tzinf(kk) = rbuf(l+1)
           l = l + 1
           delta_pmax_gap(nin) = rbuf(l+1)
           l = l + 1
C T25 main gap changes with thickness change
           maxdgap(nin) = rbuf(l+1)
           l = l + 1
         ELSE
           l = l + 46
         END IF
       END DO
 
C      
       call mpi_type_free(type_reduc,ierror)
       call mpi_op_free(myop, ierror)
      END IF
 
 
#endif
      RETURN
      END