spmd_velvec2.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    spmd_velvec2          ../engine/source/mpi/anim/spmd_velvec2.F
!||--- called by ------------------------------------------------------
!||    velvec2               ../engine/source/output/anim/generate/velvec.F
!||--- calls      -----------------------------------------------------
!||    write_r_c             ../common_source/tools/input_output/write_routines.c
!||--- uses       -----------------------------------------------------
!||    spmd_comm_world_mod   ../engine/source/mpi/spmd_comm_world.F90
!||====================================================================
      SUBROUTINE spmd_velvec2(V,NODGLOB,RBUF,NUMPOG)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
        USE spmd_comm_world_mod, ONLY : spmd_comm_world
#include      "implicit_f.inc"
#include "spmd.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "task_c.inc"
#include      "spmd_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NODGLOB(*),RBUF,NUMPOG
 
      my_real 
     .   v(3,*)
 
C-----------------------------------------------
C   L O C A L   V A R I A B L E S
C-----------------------------------------------
#ifdef MPI
      INTEGER STATUS(MPI_STATUS_SIZE),IERROR,MSGOFF
      INTEGER SIZ, MSGTYP, I, J, K, MSGOFF2
      INTEGER, DIMENSION(:), ALLOCATABLE ::  NGLOBI
      my_real,
     *    DIMENSION(:,:),ALLOCATABLE :: vrecv
      REAL, DIMENSION(:,:),ALLOCATABLE :: VTOTAL
 
 
      DATA msgoff/7024/
      DATA msgoff2/7025/
C-----------------------------------------------
       ALLOCATE(nglobi(rbuf))
       ALLOCATE(vrecv(3,rbuf))
       ALLOCATE(vtotal(3,numpog))
 
       IF (ispmd/=0) THEN
C   sending the nodglob
         msgtyp = msgoff
 
         CALL mpi_send(nodglob,numnod,mpi_integer,it_spmd(1),msgtyp,
     .     spmd_comm_world,ierror)
 
         msgtyp = msgoff2
         CALL mpi_send(v,3*numnod,real,it_spmd(1),msgtyp,
     .     spmd_comm_world,ierror)
 
       ELSE
          DO i=1,numnodg
            vtotal(1,i) = zero
            vtotal(2,i) = zero
            vtotal(3,i) = zero
          ENDDO
 
          DO i=1,numnod
            k = nodglob(i)
            vtotal(1,k)= vtotal(1,k) + v(1,i)
            vtotal(2,k)= vtotal(2,k) + v(2,i)
            vtotal(3,k)= vtotal(3,k) + v(3,i)
          ENDDO
          DO i=2,nspmd
 
C   reception of the entire buffer of NODGLOB addresses
            msgtyp = msgoff 
 
            CALL mpi_probe(it_spmd(i),msgtyp,
     .                    spmd_comm_world,status,ierror)
              CALL mpi_get_count(status,mpi_integer,siz,ierror)
 
            CALL mpi_recv(nglobi,siz,mpi_integer,it_spmd(i),msgtyp,
     .                  spmd_comm_world,status,ierror)
         
            msgtyp = msgoff2
            CALL mpi_recv(vrecv,3*siz,real,it_spmd(i),msgtyp,
     .                  spmd_comm_world,status,ierror)
 
            DO j = 1, siz
              k = nglobi(j)
              vtotal(1,k)= vtotal(1,k) + vrecv(1,j)
              vtotal(2,k)= vtotal(2,k) + vrecv(2,j)
              vtotal(3,k)= vtotal(3,k) + vrecv(3,j)
            ENDDO
          ENDDO
          CALL write_r_c(vtotal,3*numnodg)
 
       ENDIF
 
       DEALLOCATE(nglobi)
       DEALLOCATE(vrecv)
       
#endif
       RETURN
       END