spmd_vfi_sms.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    spmd_vfi_sms   ../engine/source/mpi/ams/spmd_vfi_sms.F
!||--- called by ------------------------------------------------------
!||    sms_mav_lt     ../engine/source/ams/sms_pcg.F
!||--- calls      -----------------------------------------------------
!||--- uses       -----------------------------------------------------
!||    spmd_mod       ../engine/source/mpi/spmd_mod.f90
!||====================================================================
      SUBROUTINE spmd_vfi_sms(V     ,SIZE,VFI,FR_RMS,
     .                       FR_SMS ,LIST_RMS ,LIST_SMS,IFLAG,
     .                       IAD_SEND,IAD_RECV,REQ_R,REQ_S,RBUF,SBUF)
        USE spmd_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------------------------
C   M e s s a g e   P a s s i n g
C-----------------------------------------------
#include "spmd.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "task_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER SIZE, IFLAG,
     .        FR_RMS(NSPMD+1), FR_SMS(NSPMD+1),LIST_RMS(*), LIST_SMS(*),
     .        iad_send(nspmd+1),iad_recv(nspmd+1),
     .        req_r(nspmd),req_s(nspmd)
      my_real
     .        v(SIZE,*), vfi(SIZE,*)
      my_real
     .        rbuf(size*(fr_rms(nspmd+1)+fr_sms(nspmd+1))),
     .        sbuf(size*(fr_rms(nspmd+1)+fr_sms(nspmd+1)))
C-----------------------------------------------
C   L o c a l  V a r i a b l e s
C-----------------------------------------------
#ifdef MPI
      INTEGER MSGTYP,I,NOD,LOC_PROC,IERROR,MSGOFF,
     .        SIZ,J,L,NB_NOD,K,M,KK,
     .        status(mpi_status_size)
      DATA msgoff/217/
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
      loc_proc = ispmd + 1
 
      IF(iflag==1)THEN
        l = 1
        iad_recv(1) = 1
        DO i=1,nspmd
 
          siz = fr_rms(i+1) - fr_rms(i)
          IF(i/=loc_proc)THEN
            siz = siz + fr_sms(i+1) - fr_sms(i)
          ENDIF
          siz = size*siz
 
          IF(siz/=0)THEN
            msgtyp = msgoff 
            CALL mpi_irecv(
     s        rbuf(l),siz,real,it_spmd(i),msgtyp,
     g        spmd_comm_world,req_r(i),ierror)
          ENDIF
          l = l + siz
          iad_recv(i+1) = l
 
        END DO
 
        l = 1
        iad_send(1) = 1
        m = 1
        DO i=1,nspmd
          IF(i/=loc_proc)THEN
#include      "vectorize.inc"
            DO j=fr_sms(i),fr_sms(i+1)-1
              nod = list_sms(m)
              IF(nod/=0)THEN
                DO k=1,SIZE
                  sbuf(l+k-1) =  v(k,nod)
                END DO
              ELSE
                DO k=1,SIZE
                  sbuf(l+k-1) =  zero
                END DO
              END IF
              l = l + SIZE
              m = m + 1
            END DO
          END IF
#include      "vectorize.inc"
          DO j=fr_rms(i),fr_rms(i+1)-1
            nod = list_rms(j)
            IF(nod/=0)THEN
              DO k=1,SIZE
                sbuf(l+k-1) =  v(k,nod)
              END DO
            ELSE
              DO k=1,SIZE
                sbuf(l+k-1) =  zero
              END DO
            END IF
            l = l + SIZE
          END DO
          iad_send(i+1) = l
        ENDDO
C
C   echange messages
C
        DO i=1,nspmd
C--------------------------------------------------------------------
          IF(iad_send(i+1)-iad_send(i)>0)THEN
             msgtyp = msgoff 
             siz = iad_send(i+1)-iad_send(i)
             l = iad_send(i)
             CALL mpi_isend(
     s         sbuf(l),siz,real,it_spmd(i),msgtyp,
     g         spmd_comm_world,req_s(i),ierror)
          ENDIF
C--------------------------------------------------------------------
        ENDDO
C
      ELSE ! IFLAG==1
C
        m = 1
        kk= 1
        DO i = 1, nspmd
          IF(iad_recv(i+1)-iad_recv(i)>0)THEN
            CALL mpi_wait(req_r(i),status,ierror)
            l = iad_recv(i)
#include      "vectorize.inc"
            DO j=fr_rms(i),fr_rms(i+1)-1
              IF(list_rms(j)/=0)THEN
                DO k=1,SIZE
                  vfi(k,kk) = rbuf(l+k-1)
                END DO
              END IF
              l = l + SIZE
              kk= kk + 1
            END DO
            IF(i/=loc_proc)THEN
#include      "vectorize.inc"
              DO j=fr_sms(i),fr_sms(i+1)-1
                IF(list_sms(m)/=0)THEN
                  DO k=1,SIZE
                    vfi(k,kk) = rbuf(l+k-1)
                  END DO
                END IF
                l = l + SIZE
                m = m + 1
                kk= kk + 1
              END DO
            END IF
          ENDIF
        END DO
C
        DO i = 1, nspmd
          IF(iad_send(i+1)-iad_send(i)>0)THEN
            CALL mpi_wait(req_s(i),status,ierror)
          ENDIF
        ENDDO
C
      END IF
#endif
      RETURN
      END