spmd_vgath.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
 
!||====================================================================
!||    spmd_vgath            ../engine/source/mpi/anim/spmd_vgath.F
!||--- called by ------------------------------------------------------
!||    velvec                ../engine/source/output/anim/generate/velvec.F
!||    velvec3               ../engine/source/output/anim/generate/velvec.F
!||--- calls      -----------------------------------------------------
!||    write_r_c             ../common_source/tools/input_output/write_routtines.c
!||--- uses       -----------------------------------------------------
!||    spmd_comm_world_mod   ../engine/source/mpi/spmd_comm_world.F90
!||====================================================================
       SUBROUTINE spmd_vgath(X,NODGLOB,WEIGHT,NUM)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
        USE spmd_comm_world_mod, ONLY : spmd_comm_world
#include      "implicit_f.inc"
#include "spmd.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "task_c.inc"
#include      "spmd_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
       my_real
     .   x(3,*)
       INTEGER WEIGHT(*),NODGLOB(*),NUM,SRECBUF
C-----------------------------------------------
C   L O C A L   V A R I A B L E S
C-----------------------------------------------
#ifdef MPI
      INTEGER STATUS(MPI_STATUS_SIZE),IERROR,MSGOFF
      INTEGER SIZ,MSGTYP,I,K,NG,NREC,MSGOFF2
 
      DATA msgoff/7003/
      DATA msgoff2/7004/
      REAL, DIMENSION(:,:) , ALLOCATABLE :: BUFSR
      INTEGER, DIMENSION(:), ALLOCATABLE :: IBUF
C   Tableau utilise par proc 0
       REAL, DIMENSION(:,:), ALLOCATABLE :: XGLOB
C=======================================================================
       ALLOCATE(bufsr(3,numnodm), ibuf(numnodm))
       ALLOCATE(xglob(3,num))
        
       IF (ispmd/=0) THEN
 
         siz = 0
         DO i=1,numnod
           IF (weight(i)==1) THEN
             siz = siz + 1
             ibuf(siz) = nodglob(i)
             bufsr(1,siz) = x(1,i)
             bufsr(2,siz) = x(2,i) 
             bufsr(3,siz) = x(3,i) 
           END IF
         END DO
 
C   a cause de la version simple precision, on ne peux pas metre l'entier
C   dans le buffer flottant car on n a que 2puiss 24 bits dispo ~ 16 Million
C   de noeuds au max
 
         msgtyp = msgoff2 
         CALL mpi_send(ibuf,siz,mpi_integer,it_spmd(1),msgtyp,
     .     spmd_comm_world,ierror)
 
         msgtyp = msgoff
         CALL mpi_send(bufsr,3*siz,mpi_real,it_spmd(1),msgtyp,
     .     spmd_comm_world,ierror)
 
       ELSE
          DO i=1,numnod
            IF (weight(i)==1) THEN
              ng = nodglob(i)
              xglob(1,ng) = x(1,i)
              xglob(2,ng) = x(2,i)
              xglob(3,ng) = x(3,i)
            ENDIF
          ENDDO
 
          DO i=2,nspmd
 
C   Reception du buffer entier des adresses NODGLOB
            msgtyp = msgoff2
 
            CALL mpi_probe(it_spmd(i),msgtyp,
     .                    spmd_comm_world,status,ierror)
              CALL mpi_get_count(status,mpi_integer,siz,ierror)
 
            CALL mpi_recv(ibuf,siz,mpi_integer,it_spmd(i),msgtyp,
     .                  spmd_comm_world,status,ierror)
 
C   Reception du buffer flottant des adresses NODGLOB
 
            msgtyp = msgoff
            CALL mpi_recv(bufsr,3*siz,mpi_real,it_spmd(i),msgtyp,
     .                  spmd_comm_world,status,ierror)
         
            nrec = siz
 
            DO k = 1, nrec
              ng = ibuf(k)
              xglob(1,ng) = bufsr(1,k)
              xglob(2,ng) = bufsr(2,k)
              xglob(3,ng) = bufsr(3,k)
            ENDDO
          ENDDO
          CALL write_r_c(xglob,3*numnodg)
 
       ENDIF
       DEALLOCATE (bufsr,ibuf,xglob)
       
#endif
       RETURN
       END