spmd_wrt_xyznor.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    spmd_wrt_xyznor       ../engine/source/mpi/anim/spmd_wrt_xyznor.F
!||--- called by ------------------------------------------------------
!||    xyznor                ../engine/source/output/anim/generate/xyznor.F
!||--- calls      -----------------------------------------------------
!||    write_s_c             ../common_source/tools/input_output/write_routines.c
!||--- uses       -----------------------------------------------------
!||    spmd_comm_world_mod   ../engine/source/mpi/spmd_comm_world.F90
!||====================================================================
      SUBROUTINE spmd_wrt_xyznor(XNORM,WEIGHT,NODGLOB,NUM)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
        USE spmd_comm_world_mod, ONLY : spmd_comm_world
#include      "implicit_f.inc"
#include "spmd.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "scr14_c.inc"
#include      "task_c.inc"
#include      "spmd_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
       my_real
     .   xnorm(3,*)
       INTEGER WEIGHT(*),NODGLOB(*),NUM
C-----------------------------------------------
C   L O C A L   V A R I A B L E S
C-----------------------------------------------
#ifdef MPI
      INTEGER STATUS(MPI_STATUS_SIZE),IERROR,MSGOFF
      INTEGER SIZ,MSGTYP,I,K,NG,NREC,MSGOFF2
 
      INTEGER, DIMENSION(:,:), ALLOCATABLE :: IBUF,RNGLOB
      DATA msgoff/7030/
      DATA msgoff2/7031/
       
C   Table used by Pro 0
       my_real
     . s3000,s,xn1,xn2,xn3,ixnn
C-----------------------------------------------
       ALLOCATE(ibuf(4,numnodm))
       ALLOCATE(rnglob(3,num))
 
       s3000 = three1000         
 
 
       ixnn = s3000
       IF(fmt_ani==4)ixnn=0
 
       IF (ispmd/=0) THEN
 
         siz = 0
         DO i=1,numnod
           IF (weight(i)==1) THEN
             siz = siz + 1
             ibuf(1,siz) = nodglob(i)
             s = sqrt(xnorm(1,i)**2 + xnorm(2,i)**2 + xnorm(3,i)**2)
             IF(s/=zero)THEN
               s = s3000 / s
               xn1 = xnorm(1,i) * s
               xn2 = xnorm(2,i) * s
               xn3 = xnorm(3,i) * s
               ibuf(2,siz) = xn1
               ibuf(3,siz) = xn2
               ibuf(4,siz) = xn3
             ELSE
               ibuf(2,siz) = 0
               ibuf(3,siz) = 0
               ibuf(4,siz) = ixnn
             END IF
           END IF
         END DO
 
C   Because of the simple precision version, we cannot put the integer
C   In the floating buffer because there are only 2 24 bits available ~ 16 million
C   maximum number of nodes
 
        msgtyp = msgoff2 
        CALL mpi_send(ibuf,4*siz,mpi_integer,it_spmd(1),msgtyp,
     .     spmd_comm_world,ierror)
 
       ELSE
          DO i=1,numnod
            IF (weight(i)==1) THEN
              ng = nodglob(i)
              s = sqrt(xnorm(1,i)**2 + xnorm(2,i)**2 + xnorm(3,i)**2)
              IF(s/=zero)THEN
               s = s3000 / s
               xn1 = xnorm(1,i) * s
               xn2 = xnorm(2,i) * s
               xn3 = xnorm(3,i) * s
               rnglob(1,ng) = xn1
               rnglob(2,ng) = xn2
               rnglob(3,ng) = xn3
              ELSE
               rnglob(1,ng) = 0
               rnglob(2,ng) = 0
               rnglob(3,ng) = ixnn
              END IF 
            END IF
          ENDDO
 
          DO i=2,nspmd
 
            msgtyp = msgoff2
 
            CALL mpi_probe(it_spmd(i),msgtyp,
     .                    spmd_comm_world,status,ierror)
            CALL mpi_get_count(status,mpi_integer,siz,ierror)
 
            CALL mpi_recv(ibuf,siz,mpi_integer,it_spmd(i),msgtyp,
     .                  spmd_comm_world,status,ierror)
 
         
            nrec = siz/4
 
            DO k = 1, nrec
              ng = ibuf(1,k)
              rnglob(1,ng) = ibuf(2,k)
              rnglob(2,ng) = ibuf(3,k)
              rnglob(3,ng) = ibuf(4,k)
            ENDDO
          ENDDO
 
          CALL write_s_c(rnglob,3*numnodg)
 
       ENDIF
 
       DEALLOCATE(ibuf)
       DEALLOCATE(rnglob)
 
#endif
       RETURN
       END